perm filename TTYSER[KA,SYS] blob sn#472061 filedate 1976-08-07 generic text, type C, neo UTF8
COMMENT ⊗   VALID 00089 PAGES
C REC  PAGE   DESCRIPTION
C00001 00001
C00008 00002	BEGIN TTYSER - SCANNER, KEYBOARD AND CONSOLE TELETYPE SERVICE ROUTINE
C00010 00003	DATA STRUCTURES AND PARAMETERS
C00013 00004	IOS BITS
C00016 00005	LINE BITS, LINE # DEFS
C00020 00006	AC'S, BYTE POINTERS
C00022 00007	LINBIT
C00024 00008	TTYINI
C00031 00009	TTYCOM, TTYCM, CNTCOM, COMBCK
C00038 00010	TTYATI
C00040 00011	TTYSUB - "TTY" COMMAND (HERE AT CLOCK LEVEL)
C00044 00012	FILL ECHO FULL TABS TIME WHO TTYARR (ARROW) WIDTH TTYSWD TTWID0 TTWID1 TTBEEP
C00051 00013	TTSENB, "TTY ENB" COMMAND
C00054 00014	TTYATT
C00059 00015	TTYDET, TRESCN, TRESCU
C00062 00016	TBYTEP
C00063 00017	TTYGET, TTYFNU, TTYFND, TTYFUW, TTYERP, TTYERR
C00066 00018	TTYSTR, TTYUSR, TTYSET, TTYSTC
C00069 00019	TTYTLK
C00073 00020	TTYSRC, STLNAC
C00076 00021	GETDDB LOG2LN GETDBA GETDB1 SIX2LN LOG2LL
C00078 00022	STDTBL, DDBSRC
C00084 00023	TTYSKL TTYREL TTYKIL TTYKL5 TTYKL6 NOTYPA
C00090 00024	MORE TTYKIL	TTYKL2 TTYKL3 TTYKL8 LINCLR TTYKL1 TTYKL4 TTYKL9 TTYK91 TTYK92
C00094 00025	OUTCH6, OUTCHS, OUTCHR
C00099 00026	MORE OUTCHR--ADJHP ARROUT OUTCH1 OUTC1A OUTC1Y OUTC1Z OUTC1C OUTC1B ADJHP2 ADJHP1
C00103 00027	PUTCHI PUTCHO PUTCHA PUTCI1 TTIOUT PUTCRX FILNCR PUTNLC PUTCRS PUTCO1
C00107 00028	GETCHR, GETCHY
C00109 00029	GETCHA GETCHO PUTCI0 GETCO1 GETCO2 GETCHX GETCH2 GETCH1
C00113 00030	TSETBF, SETBFI, SETBF3, SETBFO
C00115 00031	SPCHEK, SPCACT
C00119 00032	SPCTAB
C00122 00033	CTLV1, TTYUUO, CLRBUF, INSKIP
C00126 00034	INCHSL, INCHRS, INCHWL, IWAIT, INCHGT, INCHGB
C00130 00035	INCHRW, ONEOUT, GETLIN, SETLIN, SYNCHK, SYNCHA, SETACT
C00137 00036	OUTFIV, FIVOUT
C00140 00037	TTYMES	NULMES
C00149 00038	TTREAD, TTYJNO, TTYJOB
C00152 00039	SNEAKS, SNEAKW, ACTCHR
C00155 00040	DDTIN
C00158 00041	DDTOUT, DDTWAT, OUTSTR
C00160 00042	SCNDSP TTYIN TWSYNC TTYSKP
C00164 00043	MONUSR
C00168 00044	TTYOUT	- OUTPUT UUO
C00170 00045	USRMON, TTOUWS
C00173 00046	OLD III KEYBOARD STUFF  -  KBDINT, SHFTBL, CONVTB
C00177 00047	DKBINT - MICROSWITCH KEYBOARD SCANNER INTERRUPT SERVICE.
C00180 00048	DKBTBL
C00183 00049	TK KBD
C00187 00050	SCNINT, SCNIN1, CTYINT, DTXMT1, DTRCV1
C00189 00051	RECINT RECINA RECINB RECINC RECIM3 NOESC ESCRET SCNBU2 SCNBU4
C00201 00052	RECIN3 RECIN4 UTYPET TYPTST TYPGO TTINT STXTIM STXTM2 STXTM3 RWARN TYPT2
C00206 00053	ESCAPE BITS
C00207 00054	SETESC STDESC ESCOCS ESCOCT DMESC DMMETA DMBONG
C00211 00055	DOESC
C00213 00056	SPESC, VDESCM, VDESCL
C00218 00057	ESCAPES VDESCN VDESCA TVSTRB TVSTR VDESAD VDESCD VDESCS VDESCT VDESTV
C00223 00058	MORE ESCAPES	VDESET	VDECHK	VDVCHK
C00226 00059	ASSCN, ASESC, ESCB  AUDIO SWITCH SERVICE
C00234 00060	PKINT	PAGING INTERRUPT SERVICE ROUTINE
C00238 00061	ADSMAP BEEP BEEPTK BEEPJB BEEPND BEEPU BEEPDX BEEPX ADSMRD ADSMWT ADSMT ADSRES BEEPDM
C00252 00062	RECIML
C00253 00063	TYPX, COMSET
C00255 00064	TTEDIT TTIPUT DUPLEX DUPLX1 INBFUL AOJDPX TTPT2
C00262 00065	CONTC, CONTOB, CONTO, CONTB, ALTMOD, TTYUNH
C00266 00066	RUBOUT RUBOU1 RUBOU2 CONTK CONTL SIMFF SIMFF1 CONTI1 
C00269 00067	CONTI, CONTP
C00272 00068	CRLFEC, CRLF, CNTLEC
C00274 00069	CNCTST, CNCMOD
C00276 00070	BSECHO, DCPUTR, DELETL
C00278 00071	DOTALK, NOTALK
C00285 00072	XMTINT XMTIN1 DPYSTR DPYDON XMTI1A NODPY2 XMTI1B
C00289 00073	XMTIN4 XMTIN2 LINDON TTYPE XMTIN5 XMTIN6
C00293 00074	TYPL PAUCHK SCNTYP TYPDM PAUCH2 PAUCH3
C00296 00075	PTYGET PTOCK PTICHK PTYCLR POPJJ
C00300 00076	PTYUUO, LINMAP, PTOCNT, PTIFRE
C00304 00077	PTYREL, PTRD1S, PTRD1W, PTWAIT
C00307 00078	PTWR1S, PTLL3, PTWR1W, PTRDS, PTWRS7, PTWRS9
C00311 00079	PTJOBX
C00313 00080	PTJHLT, PTJCON, PTIWTS, PTCLRB
C00316 00081	PTDON, PTDOFF,PTLOGN,IMLOAD
C00319 00082	PHONE DIALER LIVES HERE
C00321 00083	DIAL UUO
C00327 00084	DIALER INTERRUPTS COME HERE
C00330 00085	TTYDDL (TTYSET) TTESC TTWID LINCLE LINSET NOCCR TTYSTO GETHP GETWID STIOS CLIOS GTIOS
C00337 00086	DATAMEDIA INTERRUPT LEVEL (CH5) CODE: COMMENTS AND DEFS
C00342 00087	DMTABL dispatch table for quoted DM control characters
C00347 00088	DMXMT DMXDEQ DMXDUN DMXMG2 DMXMGO DMXMT1 DMXMT2 DMXMT8 DMNOXY NODPYH
C00354 00089	XYGET DMXMTO DMXMT6 DMHOME DMPREP DMSETQ DMCURS IGNORE DMBETW DM175 DMXM5D DMHOME DMTAB DMSPAC DMCURS DMBACK DMXMTL DMLEDE
C00378 ENDMK
C⊗;
BEGIN TTYSER - SCANNER, KEYBOARD AND CONSOLE TELETYPE SERVICE ROUTINE
SUBTTL TTYSER - -DEC MOD D. POOLE MOD R. HELLIWELL




;SCNSER IS ORGANIZED(?) INTO THE FOLLOWING SECTIONS

;	I.	COMMENTARY ON OPERATION AND DATA STRUCTURES
;      II.	SYSTEM INITIALIZATION ROUTINE - SCNINI
;      III.	COMMAND LEVEL ROUTINES
;			A. TTYATT
;			B. TTYCOM
;			C. TTYDCM
;			D. TTYDET
;			E. TTYFND,TTYFNU
;			F. TTYKIL
;			G. TTYSET
;			H. TTYSRC
;			I. TTYSTR
;			J. TTYTLK
;			K. TTYUSR
;     IV.	UUO LEVEL ROUTINES
;			A. DDTIN
;			B. DDTOUT
;			C. TTYUUO
;			D. TTYIN
;			E. TTYOUT
;	V.	INTERRUPT SERVICE ROUTINES
;			A. CTYINT
;			B. SCNINT
;			C. RECINT - ALL LINES RECEIVER INTERRUPT
;				1. TTEDIT - EDITS AND ECHOS
;			D. XMTINT -  TRANSMIT INTERRUPT
;				1. GETCHR
;				2. TYP
;	VI.	PSUEDO-TELETYPE SERVICE ROUTINES
;			A. PTYGET
;			B. PTYCLR
;			C. PTYUUO
;DATA STRUCTURES AND PARAMETERS

;	DEFINED ON CONFIGURATION TAPE
;		SCNLIN=OCTAL NO. OF SCANNER LINES (0 THRU SCNLIN-1)

;	DEFINED BELOW
;		TRANSLATOR TABLE PARAMETERS
;		TTYLEN=SCNLIN+DPYNUM+1	LENGTH OF TTY TRANSLATOR TABLE (INCLUDING CTY)
;		TTYTAB:	BLOCK TTYLEN	TTY TRANSLATOR TABLE
;			SIGN BIT=1 IF COMMAND JUST TYPED
;			BIT 1 = 1  IF DELAYED COMMAND
;			BITS 3-10 = UNUSED
;			BITS 11-17=TALK RING LINE # (PTALK)
;			BITS 18-35=ADDR. OF DEVICE DATA BLOCK 
;				FOR THIS LINE.
;		DEVOPR:	0	SIXBIT PHYSICAL NAME OF OPERATORS
;				CONSOLE SET BY SCNIN0 TO FIRST
;				ACTIVE TTY.

;	DEFINED BELOW
;		LINE NUMBER PARAMETERS
;		TCONLN=SCNLIN	CTY LINE NUMBER
;		MTTYLN=-TTYLEN	-LENGTH OF TRANSLATOR TABLE
;		FSNCHN=SCNCHN*101	CHANNEL ASSIGNMENT FOR
;				FULL DUPLEX SCANNER
;		TTYLST=TTY0DB	FIRST TTY DEVICE DATA BLOCK

;TTY DEVICE DATA BLOCK FORMAT

;THE FOLLOWING ARE DEFINITIONS OF THE RELATIVE LOCATIONS OF THE
;BUFFER PARAMETER WORDS OF THE DEVICE DATA BLOCK FOR EACH BUFFER, WITH
;TTX'BUF AS THE BASE (DETAILED DESCRIPTIN IN SCNDDB COMMENTS):

	XP	BUF,0		;BUF(DAT) CONTAINS POINTER TO BEG. OF CURRENT BUFFER
	XP	↑PUTR,1		;PUTR(DAT)-PUTS CHARCTERS INTO BUFFER
	XP	PCTR,2		;NUMBER OF TIMES TO INCR. PUTR BEFORE REINITING
	XP	↑TAKR,3		;TAKER POINTER TO PICK UP CHARACTERS
	XP	TCTR,4		;COUNT OF NUMBER OF TIMES TAKR CAN BE INCREMENTED
	XP	↑FCTR,5		;COUNT OF FREE SPACES LEFT IN BUFFER
	XP	TSYNC,6		;LOCATION OF TISYNC RELATIVE TO DAT


;		DEVNAM:	PHYSICAL DEVICE NAME SET UP DYNAMICALLY
;			VIA SCNIN0.
;		DEVCHR:	LEFT HALF IS STANDARD
;			BITS 18-24=LINE NUMBER(BYTE POINTER=PUNIT)
;			BITS 25-35=MONITOR BUFFER SIZE + 1(BYTE POINTER=PDVBLN)
;IOS BITS
;		DEVIOS:	LEFT HALF
;			1,2,4,20,40 ARE STANDARD
			↑USRB←←100	;SET TTY TO USER MODE
					;WHEN OUTPUT FINISHES
					;TILL NEXT INPUT OR INIT (↑O).
			↑TPMON←←400	;TTY IS IN MONITOR
					;COMMAND MODE.
			↑DDTM←←1000	;DDT MODE
			↑↑TTYDTC←←2000	;TTY DDB IS DETACHED FROM LINE
			↑PTLIP←←4000	;PTLOAD IN PROGRESS, BUFFER USER TYPEIN
			↑TOIP←←10000	;TYPE-OUT IN PROGRESS
					;TAKER IS BEHIND PUTR
			SYNC←←20000	;BREAK CHARACTER SEEN
					;SIGNAL TO INCREMENT SYNC COUNT
					;FOR BUFFER INVOLVED
			IMLTTY←←40000	;IMLAC IS IN TTY MODE FOR NEXT CHARACTER
			↑TTYHLD←←100000	;TYPEOUT HOLD (BO)
			SNKWAT←←200000	;SNEAK PREVIEW WAIT FLAG!
			TTYIOW←←400000	;TTY INPUT WAIT BIT

;		RIGHT HALF BITS (USER MODE)
			↑↑IOSUPR←←1000	;SUPPRESS ALL OUTPUT
			BKSP←←100	;FULL CHARACTER SET. PASS
					;ON ALL CHARACTERS EXCEPT ↑C
					;NO SPECIAL CHARACTER PROCESSING
			NOECHO←←200	;ECHO SUPPRESSION REQ BY PROG
			NOECHB←←400	;SUPPRESS ECHO OF CTRL BITS
			MERTP1←←2000	;DURING ERROR TYPEOUT THIS MEANS
					;THE INPUT BUFFER IS IN USE.
			MERTPO←←IOIMPM	;MONITOR ERROR TYPE-OUT
;		DEVSER:	STANDARD
;		DEVBUF:	STANDARD
;		DEVIAD:	BITS 6-12=HORIZONTAL POSITION (BYTE
;				POINTER = PHPOS).
;			BITS 13-35 ARE STANDARD.
;		DEVOAD:	BITS 0-8=NUMBER OF CHARACTERS TO FIT
;				;INTO OUTPUT BUFFER
;				(POINTER= PFITCH)
;			BITS 13-35 ARE STANDARD
IFNDEF FTDDTM,<FTDDTM←←-1>	;NON-ZERO TO INCLUDE CALLI DDTIN,OUT
;LINE BITS, LINE # DEFS
;DEFINITION OF LINE CHARACTERISTICS TABLE BITS
;LINTAB MADE BY SYSTEM BUILDER
;FOLLOWING IS FORMAT AS SET UP BY SCNINI
;	XWD BITS,LOGICAL LINE#

↑DISLIN←←400000		;THIS LINE IS TO A DISPLAY KEYBOARD
↑CTYLIN←←200000		;THIS "LINE" IS CONSOLE DEVICE "TTY"
TTYFIL←←100000		;THIS LINE IS IN "FILL" MODE
↑DMLIN←←40000		;DATAMEDIA ON THIS LINE (Temporarily a permanent bit)
IFN FTDM <↑DMDLIN←←DMLIN;> ↑DMDLIN←←0 ;Define DMDLIN non-zero when DMs are displays
↑DDDLIN←←20000		;DATA DISK DISPLAY LINE
↑PTYLIN←←4000		;PSEUDO-TTY.
IMLIN←←2000		;THIS IS AN IMLAC

APLINE←←12		;LINE # OF AP LINE
NYLINE←←13		;LINE # OF NY LINE
IMSSS←←7		;SUPPES

;The following bit is not in the line characteristics word, but must be
;different from the bits representing display lines.  It is used in DPLED in
;DPYSER to avoid erasing non-initialized line editor under certain conditions.
↑SUPER2←←100000		;Must be different from DISLIN, DMLIN, DDDLIN, IMLIN.

	;ABOVE ARE "PERMANENT" CHARACTERISTICS

↑TLKRNG←←1		;THIS LINE CURRENTLY IN A TALK RING
XON←←2			;↑Q TYPED, PAPER TAPE INPUT
FULTWX←←4		;ON FOR SELF ECHOING FULL DUPLEX (UNUSUAL)
↑TBXPND←←10		;EXPAND TABS (SOMETIMES PERMANENT SOMTIMES CHANGEABLE)
FCS←←20			;FULL CHAR SET MODE
ROBTPD←←40		;RUBOUT TYPED LAST (ECHO \ BEFORE NEXT CHAR.)
SPCBRK←←100	;SPECIAL ACTIVATION MODE... EVERYTHING EXCEPT LETTERS AND NUMBERS IS A  BREAK CHAR.
PTYUSE←←200		;PTY LINE IN USE... DO NOT KILL DDB AT TTYKIL.
PTYWAK←←400		;SAYS PTY INPUT WAIT MAY BE TERMINATED BY TTY INPUT.
↑IMPBIT←←1000		;THE GUY ON THE OTHER END OF THIS PTY IS AN IMP
ECHARR←←10000		;BH 4/27/75 ECHO UPARROW MUMBLE FOR LESS THAN 40

;ABOVE ARE TEMPORARY BITS, TURNED ON AND OFF BY VARIOUS MEANS
;(BY MONITOR, TYPE-IN COMMANDS, OR PROGRAM)

		;BITS BELOW CAN BE SET OR ZEROED BY PROGRAM
LGLSET←←TBXPND!TTYFIL!FCS!XON!SPCBRK!PTYWAK!IMPBIT!FULTWX!ECHARR
KILMSK←←ROBTPD!TLKRNG!XON!SPCBRK!PTYLIN!PTYWAK!IMPBIT	;CLEARED AT TTYKIL

; THESE ARE INSERTED HERE BECAUSE THEY AREN'T DEFINED ANYWHERE ELSE
; IN THIS SYSTEM

GLOBAL TTPLEN	;STUPID FAIL
MTTYLN←←-TTPLEN		; MINUS NUMBER OF TELETYPES, TOTAL
↑TCONLN←←SCNNUM+DPYNUM+DDNUM	;THE CTY
↑PTYL0←←TCONLN+1		;FIRST PTY LINE NO.
↑DPYL0←←SCNNUM			;FIRST III LINE
↑DDL0←←DPYL0+DPYNUM		;FIRST DD LINE
FSNCHN←←SCNCHN*101		; SCANNER PI CHANNEL ASSIGNMENTS

;AC'S, BYTE POINTERS
;ACCUMULATOR ASSIGNMENTS

	CHR←TEM			;AC FOR CHARACTER
	LINE←TAC1		;SCANNER LINE NUMBER
	HPOS←J			;HORIZONTAL POSITION OF TTY.(0-71)


	;SPECIAL SYMBOLS

;	SCNON←←1B25!1⊗(7-SCNCHN)
;	SCNOFF←←1B26!1⊗(7-SCNCHN)

	IDLECH←←1		;DELAY CHAR FOR TABS, ETC.
				; SHOULD BE ↑V, BUT FOR 37'S


;BYTE POINTERS

PFITCH:	POINT 9,DEVOAD(DDB),8		;NR OF CHARACTERS TO FIT
PHPOS:	POINT 7,DEVIAD(DDB),12		;HORIZONTAL POSITION
PTTYWD:	POINT 8,IMLHAC(DDB),33		;TTY CARRIAGE WIDTH

IFN FTTALK,<
↑PTALK:	POINT PUNITS,TTYTAB(LINE),17	;POINTER TO ANOTHER TTY IN TALK RING
					;(SAME SIZE BYTE AS SYS UNIT #)
>


↑PLASTC:
	POINT 7,TTYPTR(DDB),35	; FOR ECHO CHECKING ON HDX LINES
↑PCOMIC:
	POINT 9,TTYPTR(DDB),19	; FOR RESCANNING COMMAND INPUT LINE
				;"COMMAND INPUT COUNTER" SAVES TITCTR
PLSTLC:	POINT 9,TTYPTR(DDB),28	;FOR ↑U DELETION

;TTYPTR CONTAINS THE FOLLOWING BYTES:
;
;	0-3	SPARE
;	4-10	PTYJOB, FOR NO. OF JOB OWNING THE PTY (IF ANY) USING THE DDB.
;	11-19	PCOMIC, FOR COMMAND RESCAN
;	20-28	PLSTLC, FOR ↑U
;	29-35	PLASTC, FOR ECHO CHECKING HALF DUPLEX LINES

;LINBIT
DEFINE BITS(X),<XWD X,.-LINBIT>

LINBIT:	
IFE FTDM,<
REPEAT 3,<BITS	TBXPND!FCS!ECHARR	>	;0-2 ARE DM SPLIT SPEED LINES
>;¬FTDM
IFN FTDM,<
REPEAT 3,<BITS	DMLIN!FCS		>	;0-2 ARE DM SPLIT SPEED LINES
>;FTDM
REPEAT 5,<BITS	TBXPND!FCS!ECHARR	>	;3-7 ARE RANDOM
REPEAT 2,<BITS	TBXPND!FCS!ECHARR	>	;10,11 DATAPHONES
REPEAT 3,<BITS	TBXPND!FCS		>	;12 IS AP, 13 IS NYT, 14 IS PONY
REPEAT 3,<BITS	IMLIN!FCS		>	;15-17 ARE IMLACS
REPEAT DPYNUM,<BITS DISLIN!FCS		>	;20-25 ARE III
REPEAT DDNUM, <BITS DDDLIN!FCS		>	;26-117 ARE DD
NOKL10,<BITS	CTYLIN			>	;NOKL10 CTY IS MODEL 35
IFKL10,<BITS	CTYLIN!FCS!TBXPND	>	;IFKL10 CTY IS DEC LA36
REPEAT PTYNUM,<BITS 0>				;JUST IN CASE SOMEONE LOOKS HERE
;END OF BIT TABLE

;TTYINI

;TTYINI IS CALLED AT SYSTEM INITIALIZATION TIME FROM SYSINI (IOGO) VIA UUO DISPATCH
;1. CLEARS ALL RECEIVER FLAGS,
;2. CLEARS THE PHYSICAL NAME (DEVNAM) OF ALL UNUSED (TTYUSE=0) TTY DDBS,
;3. SETS DEVIOS TO <TPMON+IOFST,,0> IN ALL TTY DDBS,
;4. SETS TTYUSE=1 IN ALL TTY DDBS IN THE TRANSLATOR TABLE.

↑TTYINI:PUSHJ	P,DWPINI		;LET JAM THROW AWAY THE DPY FREE STORAGE
					;BEFORE WE DO OUR BUGEY!
IFN DILNUM,<PUSHJ P,DILINI>		;INITIALIZE DIALER STUFF
	MOVSI	LINE,-TCONLN-1		;REAL TTY'S ONLY
SCN0:	MOVE	TAC,LINBIT(LINE)	;GET PERMANENT LINE CHARACTERISTICS
	HRRM	TAC,LINTAB(LINE)	;SET LOG. LINE NUMBERS
	IORB	TAC,LINTAB(LINE)	;SET SIGNIFICANT BITS
	TLZ	TAC,KILMSK		;ZAP INSIGNIFICANT BITS
	HLLM	TAC,LINTAB(LINE)	;LEAVING REST OF BITS AS THEY WERE
	AOBJN	LINE,SCN0
PRINTX TTYs 2,26,27 are enabled by default.
	MOVE	TAC,[100000,,30000]	;ENABLE TTYS 2,26,27
	MOVEM 	TAC,TTYENB
	SETZM	TTYENB+1		;CLEAR REMAINING TTYLOK ENABLES

NOKL10,<	CONO	CTY,3600!CTYCHN	;CLEAR	CTY, ASSIGN CHANNEL >;NOKL10

IFKL10,<	PUSHJ	P,DTEINI	;INIT DTE20 FOR MONITOR TTY I/O >;IFKL10

	CONO	DKB,10!SCNCHN		; CLEAR DDD TTY SCANNER AND ASSIGN CHANNEL
	PUSHJ	P,SCNINI		;DEVICE DEPENDENT SCANNER INIT
	SETZM	TTYTAB
	SETZM	COMCNT			;NO COMMANDS TO PROCESS
	SETOM	SCNCNT			;CELL TO COUNT LEVEL OF SCNOFFs and SCNONs
	MOVE	TAC,[XWD TTYTAB,TTYTAB+1]
	BLT	TAC,TTYTAB+TTPLEN-1	;CLEAR ALL DDB ADDRESSES
	MOVE	TAC,[TCONLN,,TTYLST]	;INIT CTY TO USE DDB IN ALLDAT
	MOVEM	TAC,TTYTAB+TCONLN	;  BH 5/6/74
	SETZM	PAGNOW
	SETZM	ASBTAB			;CLEAR ALL BEEP DURATIONS
	MOVE	TAC,[ASBTAB,,ASBTAB+1]
	BLT	TAC,ASBTAB+DPYNUM+DDNUM-1
	SKIPL	TTYLOK
	SKIPE	MAINTM
	JRST	NOASIN			;DON'T INIT AUDIO SW IF SYS NOT FOR REAL
	SETZM	ASTAB
	MOVE	TAC,[ASTAB,,ASTAB+1]
 	BLT	TAC,ASTAB+DPYNUM+DDNUM-1
NOASIN:	HRRZS 	TTYLST+DEVSER		;CLEAR DDB CHAIN
	SETZB	IOS,TTYLST+DEVIOS	;SO DDB WILL GET FLUSHED
	MOVEI	J,JOBN-1		;REGENERATE DDB'S FOR ALL LIVE JOBS
SCNC1:	MOVE	TAC,JBTSTS(J)
	TLNN	TAC,JNA			;IS THIS A JOB
	JRST	SCNC3			;NO, IGNORE HIM.
	HRRE	LINE,JBTLIN(J)		;GET LINE HE IS USING
	JUMPL	LINE,SCNC2		;DETACHED LINE
	PUSHJ	P,DDBSRC		;GET HIM A DDB
	JRST	SCNC3			;IF NO DDB AVAILABLE OR NO LINE OR DETACHED
	PUSHJ	P,TTYATI		;ATTACH JOB
	TLNE	LINE,PTYLIN
	SKIPE	PTYJOB-PTYL0(LINE)	;IS THIS PTY REALLY ATTACHED TO SOMEONE?
	JRST	SCNC3			;YES
	PUSHJ	P,TTYDET		;NO, DETACH HIM.
	JRST	SCNC3			;NEXT PLEASE
SCNC2:	TLNE	TAC,JSEG		;IS IT AN UPPER SEGMENT?
	JRST	SCNC3			;YES, NO DDB FOR HIM
	MOVNI	LINE,1			;YES, GET A DETACHED LINE
	PUSHJ	P,DDBSRC		;GET DDB
	JRST	SCNC3
	DPB	J,PJOBN
SCNC3:	SOJG	J,SCNC1
;GET THE DDB'S FOR THE REST OF THE TTY'S (I.E.,THE ONES NOT ATTATCHED TO JOBS ALREADY).

	MOVSI	LINE,-TTPLEN+PTYNUM	;SET DDB USE BITS FROM TRANSLATOR TABLE
SCN2:	MOVSI	IOS,600000
	ANDCAM	IOS,TTYTAB(LINE)	;NO COMMAND WAITING, NONE DELAYED
	HRRZ	TAC,LINE
	CAIGE	TAC,PTYL0		;PTY LINE?
	JRST	NOTPTY
	SKIPN	TTYTAB(LINE)		;DOES HE HAVE A DDB
	JRST	SCN6
	HRLI	TAC,PTYLIN!PTYUSE!XON	;MAGIC PTY BITS
	MOVEM	TAC,LINTAB(LINE)	;INITIALIZE THIS PTY
	JRST	SCN3			;STUFF IN 0'S

SCN6:	SETZM	PTYJOB-PTYL0(LINE)
	SETZM	LINTAB(LINE)		;CLEAR PTY BITS
	JRST	SCN3

NOTPTY:	SKIPE	TTYTAB(LINE)		;IS THERE A DDB ADDRESS THERE?
	JRST	SCN3
	SKIPE	TTYLOK
	CAIN	TAC,TCONLN
	CAIA
	JRST	SCN3
	PUSH	P,LINE
	ANDI	LINE,-1			;LINE NUMBER ONLY
	CAIL	LINE,DPYL0
	CAIL	LINE,DDL0+DDNUM
	CAIA
	JRST	SCN3A			;DON'T DO THIS FOR DPYS
	CAIE	LINE,IMSSS
	CAIN	LINE,APLINE
	JRST	SCN3A			;DON'T TYPE OUT ON THESE LINES
	CAIN	LINE,NYLINE
	JRST	SCN3A
	PUSHJ	P,DDBSRC		;MAKE TTY DDB AND SET UP TTYTAB
	JFCL
SCN3A:	POP	P,LINE
SCN3:	AOBJN	LINE,SCN2
	SETZM	LINSAV			;SO INIT. MESSAGE WILL GET TO EVERYONE.
	MOVEI	DDB,SCNDDB
	PUSHJ	P,DDBSR2		;CLEAN UP THE CTY DDB
	JFCL				;ALWAYS SKIPS.
	MOVEI	TAC,=72
	DPB	TAC,PTTYWD		;TTY WIDTH FOR CTY ONLY
	POPJ	P,			;ALL DONE

;DEVICE DEPENDENT PORTION OF INITIALIZATION CODE
;CALL:	MOVEI	TAC,CHANNEL NUMBER
;	PUSHJ	P,SCNINI

SCNINI:	MOVEI	TAC,100000
	CONO	DCSA,4010	;RELEASE XMITTER, RECEIVER
	CONSZ	DCSA,1000
	CONO	DCSA,4000
	CONSZ	DCSA,10
	DATAI	DCSB,LINE
	SOJG	TAC,.-4
	CONO	DCSA,FSNCHN	;ASSIGN INTERRUPT CHANNELS
	POPJ	P,
;TTYCOM, TTYCM, CNTCOM, COMBCK
;ROUTINE TO SETUP AC DDB TO ADDRESS OF TTY WHICH HAS TYPED A COMMAND
;AC DAT TO BYTE POINTER TO OUTPUT BUFFER FOR COMMAND MESSAGES
;AC J TO JOB NUMBER TTY IS ATTACHED TO
;CALL:	PUSHJ P,TTYCOM
;	NONE FOUND
;	AC'S SETUP
;CALLED FROM COMMAND

↑TTYCOM:SKIPGE	LINE,LINSAV
	JRST	TTYCM1			;GIVE SOMEONE ELSE A CHANCE
	MOVSI	LINE,MTTYLN
	SKIPL	TAC,TTYTAB(LINE)
TTYCM1:	AOBJN	LINE,.-1
	MOVEM	LINE,LINSAV
	JUMPG	LINE,CPOPJ
	HRRZ	DDB,TTYTAB(LINE)
	JUMPE	DDB,TTYCM2		;IT HAPPENS!!!!
	MOVE	DAT,DEVMOD(DDB)
	TLNN	DAT,TTYATC		;IS HE ATTACHED TO IT BY JOB?
	TRNN	DAT,ASSCON!ASSPRG	;NO, ASSIGNED OR INITED TTY'S CAN'T TYPE COMMANDS
	JRST	.+2
	JRST	TTYCM2			;(THIS CAN'T HAPPEN (IT SAYS SO IN COMSET))
	MOVEI	DAT,TTIBUF(DDB)		;SO GETCHR CAN BE CALLED FROM COMCON
	MOVE	LINE,TITCTR(DDB)
	DPB	LINE,PCOMIC		;SAVE COMMAND INPUT COUNTER
	LDB	LINE,PUNIT		;LINE NO.
	LDB	J,PJOBN			;JOB NO. TTY ATTACHED TO
	MOVSI	CHR,TTYATC
	TDNN	CHR,DEVMOD(DDB)
	MOVEI	J,0			;NO JOB ATTACHED TO THIS TTY
	TLNN	TAC,DLYBIT!PAUSEB	;IS THIS A DELAYED COMMAND?
	JRST	CPOPJ1			;NO, RETURN TO SCAN IT
	MOVSI	TAC,DLYBIT!PAUSEB	;INDICATE NO LONGER DELAYED COMMAND
	ANDCAM	TAC,TTYTAB(LINE)
	JRST	CPOPJ1			;RETURN TO COMMAND SCAN

;HERE FROM DLYCM1 IN CLKSER TO DELAY A COMMAND.  DDB SHOULD CONTAIN DLYBIT OR PAUSEB
↑TTYCM:	MOVE	LINE,LINSAV		;HERE WHEN COMMAND MUST BE DELAYED
	IORB	DDB,TTYTAB(LINE)
	PUSHJ	P,TRESCA		;RESCAN TO START OF COMMAND. FIX TISYNC
	MOVE	LINE,LINSAV		;TRESCN HAS CALLED STLNAC
	JRST	TTYCM1			;LOOK FOR OTHER COMMAND TO PROCESS

TTYCM2:	PUSHACS
	PUSH	P,DDB
	PUSH	P,LINE
	PUSHJ	P,DISMES
	ASCIZ	/COMMAND BIT SET AND NO DDB, OR TTY ASSIGNED: TTY /
	POP	P,TAC
	PUSHJ	P,DISLOC
	PUSHJ	P,DISMES
	ASCIZ	/, DDB= /
	POP	P,TAC	
	PUSHJ	P,DISLOC
	PUSHJ	P,DISCRLF
	POPACS
	MOVSI	DDB,COMBIT!DLYBIT!PAUSEB  ;CLEAR THESE BITS!
	SOS	COMCNT			  ;FIX COMCNT
	ANDCAM	DDB,TTYTAB(LINE)
IFN FTTTYBUG,<
	PUSHJ	P,COMBCK
	PUSHJ	P,CNTCOM	;MAKE SURE ALL IS OK
>
	JRST TTYCM1		;LET COMMAND FIGURE OUT THAT COMCNT IS MAYBE NOW ZERO

IFN FTTTYBUG,<
;WELL, WE FIXED THIS PROBLEM, I THINK. 12/1/73 

;THIS AWFUL KLUDGE IS TO HELP SOLVE THE COMCNT MYSTERY
;IF IT STAYS FOR MORE THAN TWO WEEKS, I SHOULD BE SHOT.  REG 10/5/73
↑CNTCOM:
	PUSH	P,TAC
	PUSH	P,TAC1
	CONI	PI,TAC1
	ANDI	TAC1,SCNOFF-1000	;SCANNER CHANNEL ACTIVE BIT
	PUSH	P,TAC1
	CONO	PI,SCNOFF		;TURN OFF THE SCANNER
	MOVEI	TAC1,0
	MOVSI	TAC,MTTYLN
	SKIPGE	TTYTAB(TAC)
	ADDI	TAC1,1
	AOBJN	TAC,.-2
	CAMN	TAC1,COMCNT
	JRST	CNTCM1
	PUSHACS
	PUSHJ	P,DISMES
	ASCIZ	/COMCNT & TTYTAB DISAGREE.  CALLER = /
	MOVE	TAC,-23(P)
	PUSHJ	P,DISLOC
	PUSHJ	P,DISMES
	ASCIZ	/ COMCNT= /
	MOVE	TAC,COMCNT
	PUSHJ	P,DISLOC
	PUSHJ	P,DISTAB
	MOVE	TAC,TAC1-17(P)
	PUSHJ	P,DISLOC
	PUSHJ	P,DISCRLF
	MOVE	TAC,TTCBCK
	PUSHJ	P,DISOCT
	PUSHJ	P,DISTAB
	MOVE	TAC,TTCBCK+1
	PUSHJ	P,DISOCT
	PUSHJ	P,DISTAB
	MOVE	TAC,TTCBCK+2
	PUSHJ	P,DISOCT
	PUSHJ	P,DISCRLF
↑COMBUG:	JRST	.+3			;PATCH HERE TO STOP THE WORLD
	PUSHJ	P,DISFLUSH
	PUSHJ	P,DDTCALL
	POPACS
	MOVEM	TAC1,COMCNT		;FIX IT!
CNTCM1:	POP	P,TAC1
	CONO	PI,2000(TAC1)
	POP	P,TAC1
	POP	P,TAC
	POPJ	P,

;THE 23% OVERKILL, CALL IMMED AFTER IORM OR ANDCAM OF TTYTAB
↑COMBCK:	PUSH P,IOS
	PUSH P,TAC
	MOVE TAC,-2(P)
	MOVE IOS,-2(TAC)	;FETCH IORM OR ANDCAM
	POP P,TAC
	HRRI IOS,@IOS
	TLZ IOS,37
	PUSH P,IOS
	LDB IOS,[270400,,IOS]	;AC FIELD
	SKIPN IOS
	SKIPA IOS,-1(P)
	MOVE IOS,@IOS
	JUMPGE IOS,[	POP P,IOS	;NOT COM BIT
			POP P,IOS
			POPJ P,]
	POP P,IOS		;GET INSTRUCTION BACK
	PUSH P,TAC
	PUSH P,TAC1
	PUSH P,AC1
	TLNN IOS,020000		;IORM=436, ANDCAM=412 (SKIP IF IORM)
	TLZ IOS,400000		;INDICATE ANDCAM
	HRRZ TAC,IOS
	SUBI TAC,TTYTAB		;LINE NUMBER
	JUMPL	TAC,COMBCX
	CAIL	TAC,TTPLEN
	JRST	COMBCX
	IDIVI TAC,=36		;TAC←INDEX INTO TTCBCK, TAC1←SHIFT CNT
	MOVEI AC1,1
	LSH AC1,(TAC1)
	SKIPL IOS
	ANDCAM AC1,TTCBCK(TAC)
	SKIPGE IOS
	IORM AC1,TTCBCK(TAC)
COMBCY:	POP P,AC1
	POP P,TAC1
	POP P,TAC
	POP P,IOS
	POPJ P,
COMBCX:	PUSHACS
	PUSHJ	P,DISMES
	ASCIZ	/AT COMBCK WITH INVALID INDEX = /
	MOVE	TAC,TAC-17(P)
	PUSHJ	P,DISLOC
	PUSHJ	P,DISCRLF
	JRST	COMBCY
>;END FTTTYBUG
;TTYATI
;ROUTINE TO ATTACH TTY TO A JOB
;CALL:	MOVE DDB,ADDRESS OF TTY DEVICE DATA BLOCK
;	MOVE J,JOB NUMBER
;	PUSHJ P,TTYATT
;	OK RETURN	;DDB, DAT AND TRANSLATOR TABLE SET

;CALLED FROM COMCON (ATTACH) AND COMCSS (JOBINI).
;ON OK RETURN	1)SETS TTYATC
;		3)PUTS ADDRESS OF ATTACHED DDB INTO DDB.
;		4)SETS PHYSICAL NAME TO SIXBIT /TTY LINE #/
;		  OR SIXBIT /CTY/,
;		5)SETS DEVOPR IF IT IS NON-ZERO.


IFE FTATTACH,<
↑TTYATT:
	>
;COME HERE TO ATTACH TTY IN DDB TO JOB IN J.
↑TTYATI:
	PUSHJ	P,STLNAC		;SETUP LINE
	MOVEM	LINE,JBTLIN(J)		;SET LINE # FOR JOB
	DPB	J,PJOBN			;SET JOB NUMBER OF OWNER
	MOVSI	TAC,TTYATC		;MAKE IT ATTACHED TO JOB
	IORM	TAC,DEVMOD(DDB)
	MOVSI	IOS,TTYDTC		;MAKE DDB ATTACHED TO TTY
	ANDCAB	IOS,DEVIOS(DDB)
	POPJ	P,

;TTYSUB - "TTY" COMMAND (HERE AT CLOCK LEVEL)

↑TTYSUB:HRRZS	(P)			;USE STACK AS FLAG.  NO "NO" OR "-" SEEN
	JRST	TTYSB1

TTYSB2:	CAIE	TEM,"-"			;ALLOW - ALSO
	JRST	NOTENF			;NOPE
	PUSHJ	P,GETLCCHR		;GOBBLE TO NEXT CHAR SO WE DON'T LOOP
TTYSB0:	HRROS	(P)			;FLAG "NO" OR "-" HAS BEEN SEEN.
TTYSB1:	PUSHJ	P,CTEXT1		;READ TTY COMMAND
	JUMPE	TAC1,TTYSB2
	CAMN	TAC1,['NO    ']
	JRST	TTYSB0			;FLAG "NO" SEEN
	MOVE	AC1,TAC1		;COPY COMMAND WORD
	MOVNI	AC2,1			;SET MASK ALL ONES
	LSH	AC2,-6			;CLEAR OUT ONE MORE CHAR.
	LSH	AC1,6			;SHIFT 1 COMMAND CHAR OFF
	JUMPN	AC1,.-2			;IF NOT END OF COMMAND, GO AROUND
	MOVEI	DSER,0			;CLEAR FLAG REGISTER
	MOVSI	TAC,-TCOMLN		;SEARCH TTY COMMAND TABLE FOR MATCH
TCOMLP:	CAMN	TAC1,TCOMND(TAC)	;EXACT MATCH?
	JRST	TCMGOT			;YES, THIS IS IT. (TAC SET WITH INDEX)
	MOVE	UUO,TCOMND(TAC)		;GET FULL ENTRY NAME FROM COMMAND TABLE
	TDZ	UUO,AC2			;MASK OFF UNSPECIFIED CHARACTERS
	CAME	TAC1,UUO		;MATCH UNDER MASK?
	JRST	TCMNEQ			;NO. NOT EVEN GOOD MATCH
	TLOE	DSER,1			;SKIP IF THIS IS FIRST PARTIAL MATCH.
	TLOA	DSER,400000		;DENOTE AMBIGUOUS PARTIAL MATCHES
	HRRI	DSER,(TAC)		;DSER ← INDEX OF FIRST MATCH UNDER MASK
TCMNEQ:	AOBJN	TAC,TCOMLP		;KEEP LOOKING.
	JUMPLE	DSER,COMERA		;JUMP IF NO MATCHES OR AMBIG. MASKED MATCH
	MOVEI	TAC,(DSER)		;GET INDEX TO UNIQUE PARTIAL MATCH
TCMGOT:	PUSHJ	P,STLNAC
	TLNN	LINE,CTYLIN		;SKIP IF THIS IS CTY.
	SKIPL	TCOMDS(TAC)		;NOT CTY.  SKIP IF LEGAL ON CTY ONLY
	JRST	@TCOMDS(TAC)
	JRST	COMERA

DEFINE TNAMES <
.TMAC	ARROW,TTYARR
.TMAC	BEEP,TTBEEP
.TMAC	ECHO,TTECHO
.TMAC	(ENB,1B0+TTSENB)		;ONLY ON CTY
.TMAC	FILL,FILTTY
.TMAC	FULL,TTFULL
.TMAC	TABS,TTTAB
.TMAC	TIME,TTYTIM
.TMAC	UPDATE,TTYUPD
.TMAC	W,TTYWHO
.TMAC	WHO,TTYWHO
.TMAC	WIDTH,TTYSWD
>

DEFINE .TMAC(A,B)
<	SIXBIT/A/
>

TCOMND:	XLIST
	TNAMES
	LIST
TCOMLN←←.-TCOMND

DEFINE .TMAC(A,B)
<	B
>

TCOMDS:	XLIST
	TNAMES
	LIST

	PURGE	TNAMES		;RECLAIM SOME SPACE FOR THE ASSEMBLER
;FILL ECHO FULL TABS TIME WHO TTYARR (ARROW) WIDTH TTYSWD TTWID0 TTWID1 TTBEEP

TTBEEP:	MOVE AC1,(P)			;GET PROPER SENSE OF FLAG
	JRST ESCZ			;LET LINED DO THE WORK

FILTTY:	TLNE LINE,DISLIN!DDDLIN!DMLIN	;THESE GUYS MAY SCREW UP
	POPJ P,
	SKIPGE (P)			;'NO' TYPED?
	TLZA LINE,TTYFIL		;YES, DO NOFILL
	TLO LINE,TTYFIL			;FILL CR'S
STOLIN:	HLLM LINE,LINTAB(LINE)
	POPJ P,

TTECHO:	SKIPGE (P)			;'NO' TYPED?
	TLOA LINE,FULTWX		;YES, SET AS SELF ECHOING FULL DUPLEX
	TLZ LINE,FULTWX			;CLEAR SELF-ECHO.  (I.E., WE ECHO)
	JRST STOLIN

TTFULL:	SKIPGE (P)
	TLZA LINE,FCS
	TLO LINE,FCS
	JRST STOLIN

TTTAB:	SKIPGE (P)
	TLOA LINE,TBXPND		;EXPAND
	TLZ LINE,TBXPND			;DON'T EXPAND
	JRST STOLIN

TTYARR:	SKIPGE (P)
	TLZA LINE,ECHARR
	TLO LINE,ECHARR
	JRST STOLIN


TTYSWD:	PUSHJ	P,DECIN			;TTY WIDTH COMMAND.   REG 11/75
TTWID0:	SKIPA	TAC1,[=72]		;NO ARG, USE OLD DEFAULT
	JRST	COMERA			;LOSE
TTWID1:	CAIGE	TAC1,=256
	CAIG	TAC1,=16		;SOME VALUES ARE NOT REASONABLE.
	MOVEI	TAC1,=84
	DPB	TAC1,PTTYWD
	POPJ	P,

TTYUPD:	JUMPE	J,CPOPJ			;IF NO JOB, NO XTIME
	MOVSI	TAC,400000		;THIS IS THE NO-UPDATE BIT IN XTIME
	SKIPGE	TAC1,(P)		;'NO' TYPED?
	ORM	TAC,XTIME(J)		;YES.  SET NO-UPDATE BIT.
	JUMPL	TAC1,.+2		;'NO' TYPED?
	ANDCAM	TAC,XTIME(J)		;NO.  CLEAR NO-UPDATE BIT.
	POPJ	P,

TTYTIM:	JUMPE	J,CPOPJ			;NO JOB, NO XTIME
	MOVSI	TAC,400000		;THE NO-UPDATE BIT IN XTIME
	SKIPL	TAC1,(P)		;'NO' TYPED?
	ADD	TAC,TTIME(J)		;NO.  UPDATE XTIME AND SET NO-UPDATE BIT
	MOVEM	TAC,XTIME(J)		;IF 'NO' TYPED, CLEAR XTIME AND SET NO-UPDATE.
	HRRZS	DSKOPS(J)		;MAKE ALL DISK OPERATIONS "RECENT"
	SETZ	TAC,			;ASSUME NO WAIT TIME
	JUMPL	TAC1,TTYTI1		;'NO' TYPED?
	HRLS	DSKOPS(J)		;NO.  MAKE NO DISK OPS RECENT
	SKIPGE	TAC,JBTWAT(J)		;GET WAIT TIME
	ADD	TAC,UPTIME		;MAKE IT HONEST
TTYTI1:	MOVEM	TAC,JB2WAT(J)		;SAVE CURRENT WAIT TIME
	POPJ	P,

TTYWHO:	SKIPL	(P)			;'NO' TYPED?
	JRST	UWHO			;NO NO.
TTWHSY:	MOVEI	AC3,COMWHO+1		;TYPE OUT SYSTEM WHO LINE
	JRST	UWHO1

UWHO:	PUSHJ	P,DECIN
	SKIPA	TAC1,J			;NO ARG, USE OUR JOB #
	JRST	COMERA			;LOSE
	JUMPE	TAC1,TTWHSY		;0 ARG, OR NO ARG & NOT LOGGED IN
	CAIL	TAC1,JOBN		;TOO BIG?
	JRST	NOTLOG			;YES
	MOVE	TAC,JBTSTS(TAC1)
	TLNN	TAC,JNA			;IS IT A JOB?
	JRST	NOTLOG			;NO
	PUSH	P,J			;SAVE J
	PUSH	P,DDB			;AND DDB ON STACK
	MOVE	J,TAC1
	MOVEI	AC1,TITLE		;USE WHO LINE MODEL
	SETZ	DDB,			;FLAG THAT IT IS TTY CALLING
	PUSHJ	P,WHOLIN
	POP	P,DDB			;RESTORE DDB
	POP	P,J			;AND J
	MOVEI	AC3,WTTYS		;START HERE
UWHO1:	SKIPN	AC2,(AC3)		;PICKUP WORD AND CHECK FOR END
	POPJ	P,			;DONE
	TRZN	AC2,1			;TEXT WORD?
	AOJA	AC3,UWHO1		;NO
	MOVE	AC1,[POINT 7,AC2]	;YES, MAKE BYTE POINTER
UWHO2:	TLNN	AC1,760000
	AOJA	AC3,UWHO1
	ILDB	TEM,AC1			;UNPACK THE CHARACTERS
	JUMPE	TEM,UWHO2
	PUSH	P,AC1
	PUSH	P,AC2
	PUSH	P,AC3
	XCT	TYO			;OUTPUT THE CHAR.
	POP	P,AC3
	POP	P,AC2
	POP	P,AC1
	JRST	UWHO2

↑WHOUUO:XCTR XR,[HRRZ UUO,(UCHN)]	;POINTER TO WHERE USER WANTS STRING
	CAIG UUO,JOBPFI			;MAKE SURE IO DOESN'T CLOBBER JOB VARIABLES
	JRST UADRER			;ADDRESS ERROR. OTHER SAFETY INSURED BY XCTR
	HRLI UUO,(<POINT 7,0>)		;MAKE IT BYTE POINTER
	MOVEI AC3,COMWHO+2		;SKIP SOME SPACES
	XCTR XR,[HLRE TAC,(UCHN)]	;GET JOB NUMBER FIELD
	JUMPL TAC,WHOUU1		;IF -, JUST REPORT SYSTEM WHO LINE
	JUMPE TAC,.+2
	CAIL TAC,JOBN
	MOVE TAC,J			;ZERO OR >JOBN IS US
	HLLZ AC2,JBTSTS(TAC)
	TLNN AC2,JNA			;JOB THERE?
	JRST WHOUU2			;NO, ZERO STRING
	PUSH P,J
	MOVE J,TAC
	MOVEI AC1,TITLE			;USE PROTOTYPE
	SETZ DDB,			;FLAG WHOSER NO TTY HERE
	PUSHJ P,WHOLIN
	POP P,J
	MOVEI AC3,WTTYS			;WHERE TO PICKUP STRING FROM
WHOUU1:	SKIPN AC2,(AC3)
	JRST WHOUU2			;FINISH OUT WORD WITH NULLS
	TRZN AC2,1			;TEXT WORD?
	AOJA AC3,WHOUU1			;NO, CHECK NEXT WORD
	MOVE AC1,[POINT 7,AC2]
WHOUU0:	TLNN AC1,760000
	AOJA AC3,WHOUU1
	ILDB TEM,AC1
	JUMPE TEM,WHOUU0
	XCTR XDB,[IDPB TEM,UUO]
	JRST WHOUU0

WHOUU2:	XCTR XDB,[IDPB AC2,UUO]
	TLNE UUO,760000
	JRST WHOUU2
	POPJ P,
;TTSENB, "TTY ENB" COMMAND
;FORMS ARE:  TTY  {-}ENB <NUMLIST>|ALL|NONE|ε
;<NUMLIST>→NUM|NUM,<NUMLIST>

TTSNB3:	XCT	CONTYI			;FLUSH THE COMMA
TTSENB:	PUSHJ	P,OCTIN			;TTY SET ENABLES FOR TTYLOK
	JRST	TTSNBT			;NO ARG.
	JRST	TTSNBA			;NOT A NUMBER.
	MOVN	TAC1,TAC1		;NEGATE FOR USE IN SHIFTING
	MOVSI	AC2,400000
	MOVEI	AC3,0
	LSHC	AC2,(TAC1)
	SKIPGE	(P)			;SKIP UNLESS -ENB
	JRST	TTSNB1
	IORM	AC2,TTYENB		;TURN ON BITS IN TTY ENABLES
	IORM	AC3,TTYENB+1
	JRST	TTSNB2

TTSNB1:	ANDCAM	AC2,TTYENB
	ANDCAM	AC3,TTYENB+1
TTSNB2:	CAIN	TEM,","			;WAS OCTAL NUMBER TERMINATED BY COMMA?
	JRST	TTSNB3			;YES.  LOOK FOR ANOTHER NUMBER
	POPJ	P,

TTSNBA:	PUSHJ	P,CTEXT1
	MOVE	AC3,[SETZM TTYLOK]	;"TTY ENB ALL" CLEARS TTY LOK
	CAMN	TAC1,['ALL   ']
	JRST	TTSNBB
	CAME	TAC1,['NONE  ']		;"TTY ENB NONE" SETS TTYLOK
	JRST	COMERA
	TLC	AC3,(<SETZM>≠<SETOM>)	;SO AC3←"SETOM TTYLOK"
TTSNBB:	SKIPGE	(P)			;SKIP UNLESS "TTY -ENB ALL"
	TLC	AC3,(<SETZM>≠<SETOM>)
	XCT	AC3
	SETZM	TTYENB
	SETZM	TTYENB+1
	JRST	TTSNB2			;LOOK FOR OTHER ARGUMENTS

TTSNBT:	SKIPE	TTYLOK			;TTYLOK SET?
	JRST	TTSNBU			;YES
	JSP	TAC,CONMES
	ASCIZ	/All
/

TTSNBU:	SKIPN	TTYENB
	SKIPE	TTYENB+1
	JRST	TTSNBV			;SOME ARE ENABLED
	JSP	TAC,CONMES
	ASCIZ	/None
/

TTSNBV:	MOVE	AC2,TTYENB
	MOVE	AC3,TTYENB+1
	MOVEI	TAC,0
TTSNBW:	JUMPGE	AC2,TTSNBY
	PUSH	P,TAC
	TLZ	AC2,400000
	PUSH	P,AC2
	PUSH	P,AC3
	PUSHJ	P,OCTPNT
	SKIPG	(P)			;SKIP IF ANY BITS ARE LEFT
	SKIPE	-1(P)
	JRST	TTSNBZ			;THERE'S MORE TO PRINT
	SUB	P,[3,,3]
	JSP	TAC,CONMES
	ASCIZ	/
/

TTSNBZ:	MOVEI	TEM,","
	XCT	TYO
	POP	P,AC3
	POP	P,AC2
	POP	P,TAC
TTSNBY:	LSHC	AC2,1
	AOJA	TAC,TTSNBW
;TTYATT

;ATTACH TTY (I.E., LINE) TO THE DDB THAT THE JOB IS ALREADY ATTACHED TO.
;THEN, FLUSH THE LINE'S OLD DDB IF NECESSARY.

IFN FTATTACH,<
↑TTYATT:
	PUSHJ	P,STLNAC		; GET LINE CHARACTERISTICS
	SKIPA	DDB,[TTYLST]		;SEARCH FOR DDB THAT IS ATTACHED
TTYAT2:	HLRZ	DDB,DEVSER(DDB)
	JUMPE	DDB,CPOPJ		;HAVE ALL TTY DDB'S BEEN LOOKED AT?
	LDB	TAC,PJOBN		;NO, GET JOB NUMBER.
	HLL	TAC,DEVMOD(DDB)		;ATTACH AND USE BITS
	TLNN	TAC,DVTTY		;IS THIS STILL A TTY DDB?
	JRST	TTYAT2			;NO, THIS MUST BE IJOB.
	MOVE	IOS,DEVIOS(DDB)
	CAIN	J,(TAC)			;JOB NUMBER THE ONE TO ATTACH?
	TLNN	TAC,TTYATC		;YES, IS DDB ATTACHED TO JOB?
	JRST	TTYAT2			;NO, KEEP LOOKING.
	TLNN	IOS,TTYDTC		;YES.  IS DDB DETACHED FROM LINE?
	POPJ	P,			;NO - DDB SET FOR ERROR (TTYn ALREADY ATT.)
	PUSH	P,DDB			;SAVE ADDRESS OF THE DDB BELONGING TO JOB.
	MOVE	DDB,TTYTAB(LINE)	;DDB OF LINE THAT TYPED ATT COMMAND.
	LDB	TAC,PJOBN		;GET JOB # OF OLD DDB
	OFFSCN				;TURN OFF SCANNER CHANNEL
	PUSH	P,DEVIOS(DDB)		;SAVE TOIP OF DDB BEING DETACHED FROM LINE
	JUMPN	TAC,TTYAT3		;IF NON-ZERO, OLD JOB IS BEING DETACHED.
	MOVSI	TAC,IO!TOIP		;NO JOB THERE.  CLEAR THESE BITS
	ANDCAM	TAC,DEVIOS(DDB)		;SO DDB GETS KILLED BY TTYDET
TTYAT3:	PUSHJ	P,TTYDET		;DO YOUR STUFF
	POP	P,IOS			;FROM OLD DDB
	POP	P,DDB			;GET BACK NEW GUY
	MOVSI	TAC,IO!TOIP
	ANDCAM	TAC,DEVIOS(DDB)		;TURN OFF OLD BITS IN OLD DDB
	AND	IOS,TAC			;GET NEW BITS FROM OTHER DDB
	HLL	LINE,LINTAB(LINE)
	TLNN	LINE,DISLIN!DDDLIN!PTYLIN
	IORM	IOS,DEVIOS(DDB)		;COPY IO!TOIP TO NEW DDB (ONLY IF REAL TTY)
	MOVEM	DDB,TTYTAB(LINE)	;TTYDET CLOBBERS THIS.
IFN FTTTYBUG,<	PUSHJ	P,CNTCOM	>;MAKE SURE THAT ALL IS WELL?
	DPB	LINE,PUNIT		;SET THIS LINE IN DDB
	PUSHJ	P,TTYATI		;SET UP NEW DDB
				;NOW, GO TO INTERUPT LEVEL TO SET DAT
				;AND CHECK IF TYPING NEEDS TO BE STARTED.
	PUSH	P,J			;SAVE THIS
	PUSHJ	P,TYPT2			;START TYPING IF NEEDED
	ONSCN
	POP	P,J
	DPB	LINE,PUNIT		;SET LINE NUMBER (UNIT NO.) IN DDB.

IFN FTTALK,<	DPB	LINE,PTALK	;TALK RING TO CONTAINS ONLY THIS TTY >

	MOVEI	TAC,0
	ANDI	LINE,-1
TTYAT4:	ROTC	TAC,-3			;LOW 3-BITS OF LINE INTO 3 HIGH BITS OF TAC
	HRRI	TAC,2			;CONVERT TO SIXBIT
	ROT	TAC,-3			;BY SHIFTING +20 INTO TAC
	JUMPN	LINE,TTYAT4		;LOOP WHILE THERE'S ANYTHING LEFT.
	HRRI	TAC,'TTY'
	MOVSM	TAC,DEVNAM(DDB)
	PUSHJ	P,STLNAC
	MOVSI	TAC,'CTY'
	TLNE	LINE,CTYLIN		;IS THIS CONSOLE TTY?
	MOVEM	TAC,DEVNAM(DDB)		;YES, CHANGE NAME TO CTY.
	JRST	CPOPJ1			;SUCCESSFUL RETURN.
>;FTATTACH
;TTYDET, TRESCN, TRESCU
IFN FTATTACH,<
;ROUTINE TO DETACH TTY FROM JOB
;CALL:	MOVE DDB,ADDRESS OF TTY DDB TO BE DETACHED
;	PUSHJ P,TTYDET

;CALLED FROM TTYATT AND COMCON (DETACH).
;CLEARS TTYATC AND TRANSLATOR TABLE ENTRY.
;SETS TTYDTC IN DEVIOS(DDB)


↑TTYDET:LDB	TAC,PJOBN	;GET JOB NO.
	SETOM	JBTLIN(TAC)	;FLAG LINE AS DETACHED.
	MOVSI	IOS,TTYDTC
	MOVE	TAC,DEVMOD(DDB)		;SET TTY DETACHED BIT
	TLNE	TAC,TTYATC		;WAS TTY ALREADY DETACHED?
	TDNE	IOS,DEVIOS(DDB)
	JRST	TTYKIL			;YES, MAKE TTY AVAIL. EXTRA DETACH COMMAND
	IORB	IOS,DEVIOS(DDB)
	OFFSCN				;TURN OFF SCANNER CHANNEL
	PUSHJ	P,TTYSKL
	ONSCN				;TURN ON SCANNER CHANNEL
	JRST	TTYKL1			;GO CLEAR TRANSLATOR TABLE
>

; ROUTINE TO RESET COUNTS AND BYTE POINTERS TO RESCAN THE LAST COMMAND LINE

↑TRESCN:
	LDB	TAC,PCOMIC		; GET OLD TITCTR
TRESC2:					;HERE TO SCAN BACK TO CURRENT INPUT.
	MOVEM	TAC,TITCTR(DDB)		;RESTORE IT
	PUSHJ	P,TBYTEP
	MOVEM	TAC,TITAKR(DDB)
TRESC1:	MOVE	TAC,TIPCTR(DDB)		;CALLED HERE FROM ↑U CODE
	OFFSCN				;TURN OFF SCANNER CHANNEL
	SUB	TAC,TITCTR(DDB)		; THIS IS NOW THE NEW CHR. COUNT TO END OF BUFFER
	SKIPG	TAC
	ADDI	TAC,TTICHR
	MOVEM	TAC,TIFCTR(DDB)
	ONSCN				;TURN ON SCANNER CHANNEL
	JRST	STLNAC

; ROUTINE TO RESCAN ALL COMMAND LINES IN BUFFER. CALLS TRESCN, THEN
; COUNTS NUMBER OF COMMAND LINES IN BUFFER, THEN CALLS TRESCN AGAIN

↑TRESCU:
	TLNE	IOS,TPMON		;MONITOR MODE?
	POPJ	P,			;OH WELL, LOSERS LOSE
	TRNN	UUO,-1
	JRST	TRESCA
	LDB	TAC,PCOMIC
	SUB	TAC,TITCTR(DDB)
	SKIPG	TAC
	ADDI	TAC,TTICHR
	XCTR	XW,[MOVEM TAC,(UUO)]
TRESCA:	PUSHJ	P,TRESCN		;RESCAN LINE
	JRST	SYNCHK			;RE-CALCULATE ACTIVATED CHAR. COUNT.
;TBYTEP
; ROUTINE TO MAKE A POINTER TO THE BUFFER OUT OF A COUNT OF CHARACTERS
; FROM THE START OF THE BUFFER.

	XWD 	441100,0
TLHBYT:	XWD	331100,0
	XWD	221100,0
	XWD	111100,0
	XWD	001100,0

TBYTEP:	PUSH	P,LINE		;SAVE LINE
	MOVNS	TAC
	ADDI	TAC,TTICHR
	IDIVI	TAC,4
	ADD	TAC,TTIBUF(DDB)
	HLL	TAC,TLHBYT(LINE)
	POP	P,LINE		;RESTORE LINE
	AOJA	TAC,CPOPJ
;TTYGET, TTYFNU, TTYFND, TTYFUW, TTYERP, TTYERR
;ROUTINE TO FIND TTY FOR A JOB
;CALL:	MOVE J,JOB NUMBER
;	PUSHJ P, TTYFND
;	RETURN WITH DDB SET TO ADR OF DDB
;	AND DAT SET TO BYTE POINTER TO MONITOR OUTPUT BUFFER

TTYGET:		

↑TTYFNU:
	MOVE	J,JOB(PID)
↑TTYFND:
	PUSHJ	P,TTYSRC
TTYDAT:	MOVEI	DAT,TTOBUF(DDB)
	POPJ	P,


;PUT JOB IN IO WAIT IF TTY BUFFER NOT EMPTY
;CALLED BY NON ERROR MESSAGE ROUTINES AT UUO LEVEL

↑TTYFUW:JUMPE	PID,TTYFU1
	PUSHACS
	SKIPP1
	JRST	TTYFU2
	PUSHJ	P,DISMES
	ASCIZ	/ππPID CLOBBERED AT TTYFUW
/
	POPACS
	SETZ	PID,
	JRST	TTYFU1

TTYFU2:	PUSHJ	P,DISMES
	ASCIZ	/P2 AT TTYFUW
/
	POPACS
	POPJ	P,

TTYFU1:	PUSHJ	P,TTYFNU
	LDB	TAC,PJOBN		;GET JOB # OF DDB
	CAME	TAC,JOB			;IS THIS OURS?
	POPJ	P,			;NO, FORGET IT.
TTYFU3:	MOVE	TAC,TOPUTR(DDB)
	CAMN	TAC,TOTAKR(DDB)
	POPJ	P,
	MOVEI	IOS,IOACT		;DDB HAS SOME OUTPUT ALREADY
	IORB	IOS,DEVIOS(DDB)
	PUSHJ	P,WSYNC
	JRST	TTYFU3

;ROUTINE TO INDICATE MONITOR ERROR MESSAGE TO BE FORCED OUT
;WHEN NO MORE ROOM IN TTO BUFFER, TTI BUFFER WILL BE USED


LOSYS

↑TTYERP:JUMPN	PID,CPOPJ	;HERE TO START ERROR TYPEOUT AND CLEAR INPUT
	PUSH	P,[SETBFI]	;RETURN VIA SETBFI
	JRST	TTYER1

↑TTYERR:JUMPN	PID,CPOPJ	;HERE IF YOU NEED SPACE BUT 
				;DON'T NECESSARILY NEED TO FLUSH INPUT
	JRST	TTYER1		;JUMP TO HISYS

HISYS


TTYER1:	PUSHJ	P,TTYSRC	;FIND TTY DDB
	MOVEI	IOS,MERTPO	;SET MONITOR ERROR PRINT OUT BIT
	IORB	IOS,DEVIOS(DDB)
	TLNE	IOS,TTYDTC	;LEAVE IF DETACHED LINE
	POPJ	P,
	PUSHJ	P,STLNAC
	TLNN	LINE,DISLIN!DDDLIN!DMLIN
	POPJ	P,
	PUSHACS
	HRRZ	DDB,LETAB(LINE)	;GET THE RIGHT SIDE ONLY
	JUMPE	DDB,TTYDX1	;NO DPY HEADER
	HLRZ	DAT,PPCALL(DDB)
	HLL	DDB,LINE	;SET DISPLAY-TYPE BIT
	HLL	DAT,DDB		;AND COPY IT HERE
	PUSHJ	P,PPCLR
TTYDX1:	POPACS
	POPJ P,

;TTYSTR, TTYUSR, TTYSET, TTYSTC

;SET TTY INTO USER MODE NOW. (CALLED FROM RUNCSS - USTART/MSTAR2)
;CLEARS DDTM,IOSUPR,USRB,TTYIOW AND IOW
;CALL:	MOVE	DDB,ADDRESS OF DEVICE DATA BLOCK
;	PUSHJ	P,TTYSET

↑TTYSET:MOVE	IOS,[DDTM+USRB+TTYIOW+IOW,,IOSUPR]
	ANDCAB	IOS,DEVIOS(DDB)
	POPJ	P,

;START TTY OUTPUT
;CALL:	MOVE DAT,BYTE POINTER TO LAST OUTPUT ITEM
;	MOVE DDB,ADDRESS OF TTY DDB
;	MOVE J,JOB NUMBER		;(MUST BE PRESERVED)
;	PUSHJ P,TTYSTR

;CALLED FROM COMINI (LOTS OF PLACES)
;INITIALIZES TTY FOR MONITOR OUTPUT AND STARTS OUTPUT


;TTYSTC - SAME AS TTYSTR, BUT CLEARS USRB FIRST.
↑TTYSTC:MOVSI	TAC,USRB		;START TTY OUTPUT AFTER CLEARING USRB
	ANDCAM	TAC,DEVIOS(DDB)
↑TTYSTR:MOVE	IOS,[DDTM!IOBEG!IO!TPMON,,IOSUPR!IOBKTL!IOACT]
	ANDCAB	IOS,DEVIOS(DDB)
	TLNE	IOS,TTYDTC		;DON'T START DETACHED LINES
	POPJ	P,
	PUSHJ	P,STLNAC		;GET LINE CHARACTERISTICS
	MOVSI	TAC,IO!TPMON
	TLNE	IOS,USRB		;GOING OUT OF MONITOR MODE?
	TLZ	TAC,TPMON		;YES, DON'T DIDLE THESE
	IORM	TAC,DEVIOS(DDB)
	MOVSI	TAC,USRB+TPMON
	TLNE	IOS,USRB
	ANDCAM	TAC,DEVIOS(DDB)
	MOVE	IOS,DEVIOS(DDB)		;GET CORRECT IOS
	SKIPLE	TISYNC(DDB)		;ANY TYPE AHEAD?
	PUSHJ	P,COMSET		;YES.
	JRST	UTYPET			;GO TYPE FIRST CHAR.

;SET SCANNER TO START UP JOB WHEN OUTPUT FINISHES
;CALL:	MOVE DDB,TTY DDB ADR.
;	PUSHJ P,TTYUSR
;	TTY WILL GO TO USER MODE WHEN TYPING OUT STOPS

↑TTYUSR:MOVSI	IOS,USRB		;SET BIT TO SWITCH TTY TO USER MODE
	IORM	IOS,DEVIOS(DDB)		;WHEN MONITOR OUTPUT FINISHES
	JRST	SETRUN			;GO FLAG JOB AS RUNABLE IMMEDIATELY
;TTYTLK
;ROUTINE TO ADD TTY TO TALK RING
;CALL:	ADR. OF DDB TO BE ADDED TO RING AT -3(P)
;	MOVE TAC,SIXBIT /TTYN/
;	PUSHJ P,TTYTLK
;	TTY IS BUSY RETURN OR NOT A TTY OR TOO BIG A LINE NO.
;	OK RETURN, TTY ADDED TO TALK RING

IFN FTTALK,<

↑TTYTLK:
	PUSHJ	P,GETDDB		; IN CASE NOT SET UP
	POPJ	P,			;NONE AVAIL. GIVE UP
IFN FTTKBG,<
	LDB	CHR,PUNIT		;BH 3/15/74 FOR BUG TRAP BELOW
>;FTTKBG
	MOVE	TAC,DEVMOD(DDB)
	TLNN	TAC,DVTTY
	POPJ	P,
	MOVE	IOS,DEVIOS(DDB)	;IS TTY IN MONITOR MODE AND LEFT HAND MARGIN?
	TLNE	IOS,TTYHLD	;EVIL THINGS MIGHT HAPPEN IF WE TRY TALKING
	POPJ	P,		;TO A LINE THAT'S HOLDING.
	MOVE	LINE,-3(P)		;TTY GIVING TALK COMMAND
	MOVE	LINE,DEVNAM(LINE)	;ITS NAME
	MOVE	TAC,DEVNAM(DDB)	;OPR IS NEVER TOO BUSY...
	CAMN	LINE,TAC		;IF THE SAME,
	POPJ	P,			;  NO SOAP
	CAME	LINE,DEVOPR		;EITHER ONE OPR?
	CAMN	TAC,DEVOPR
	JRST	TTYTK1
	MOVSI	TAC,TLKPRV
	TDNE	TAC,JBTPRV(J)	;CHECK PRIVILEGE
	JUMPN	J,TTYTK1	;JUMP IF PRIV SET
	TLNE	IOS,TPMON
	TLNN	IOS,IOFST
	POPJ	P,			;NO, HE IS BUSY.
TTYTK1:	OFFSCN				;TURN OFF SCANNER CHANNEL
IFN FTTKBG,<
	HRRZ	TAC,TTYTAB(CHR)		;BH 3/15/74
	JUMPE	TAC,TTYTK2		;  BUG TRAP: MAYBE NO OBJECT DDB HERE?
>;FTTKBG
	LDB	LINE,PUNIT		;LINE NUMBER IN RING.
	MOVSI	TAC,TLKRNG
	LDB	CHR,PTALK
	TDNN	TAC,LINTAB(LINE)
	HRRZ	CHR,LINE
	IORM	TAC,LINTAB(LINE)
	EXCH	DDB,-3(P)		;GET DDB OF TALKER
	LDB	LINE,PUNIT		;LINE NO. OF TALKER
	DPB	CHR,PTALK		;SET TO POINT INTO RING
	MOVSI	TAC,TLKRNG
	IORM	TAC,LINTAB(LINE)
	MOVEM	LINE,TAC		;SAVE LINE NO. OF TALKER
	EXCH	DDB,-3(P)		;RESTORE
	LDB	LINE,PUNIT		;LINE NO. IN RING AGAIN
	DPB	TAC,PTALK		;MAOE IT POINT TO TALKER
	ONSCN				;TURN ON SCANNER CHANNEL
	JRST	CPOPJ1			;OK RETURN

IFN FTTKBG,<
TTYTK2:	MOVE	TAC,-3(P)		;BH 3/15/74 BUG TRAP HERE TO PAGE END
	PUSHACS
	PUSH	P,DDB			;FORMER DDB OF TALKEE
	PUSH	P,CHR			;DEAD TALKEE
	PUSH	P,TAC			;TALKER'S DDB
	MOVE	DDB,TAC
	LDB	TAC,PUNIT		;TALKER
	PUSH	P,TAC
	PUSHJ	P,DISMES
	ASCIZ /ππππNO DDB FOR TALKEE AT TTYTK1!!
TALKER=/
	POP	P,TAC
	PUSHJ	P,DISOCT
	PUSHJ	P,DISMES
	ASCIZ /  DDB=/
	POP	P,TAC
	PUSHJ	P,DISOCT
	PUSHJ	P,DISMES
	ASCIZ /
TALKEE=/
	POP	P,TAC
	PUSHJ	P,DISOCT
	PUSHJ	P,DISMES
	ASCIZ /  DDB WAS AT /
	POP	P,TAC
	PUSHJ	P,DISOCT
	PUSHJ	P,DISMES
	ASCIZ /
FIND A WIZARD!  IF NONE, TYPE: POPJ 3,$X
/
	PUSHJ	P,DISFLU
	POPACS
	PUSHJ	P,DDTCAL
	ONSCN				;TURN ON SCANNER CHANNEL
	POPJ	P,
>;FTTKBG
>
;TTYSRC, STLNAC
;ROUTINE TO SEARCH TRANSLATOR TABLE FOR TTY
;CALL:	MOVE J,JOB NUMBER
;	PUSHJ P,TTYSRC
;	RETURN WITH ADDRESS OF DEVICE DATA BLOCK IN DDB.


↑↑TTYSRC:
	JUMPE	J,TTYF1			;SEARCH FOR OPER. TTY IF JOB NO. 0
	MOVSI	LINE,TTYATC
	HRRE	TAC,JBTLIN(J)		;FIRST TRY THE EASY WAY
	JUMPL	TAC,TTYFX		;JUMP IF LINE IS DETACHED
	CAILE	TAC,TTPLEN		;COMPARE WITH MAX TTY NUMBER
	JRST	TTYFX			;JBTLIN HAS SHIT
	HRRZ	DDB,TTYTAB(TAC)		;GET THE DDB ADDRESS
	JUMPE	DDB,TTYFX		;JUMP IF NOBODY HOME
	LDB	TAC,PJOBN		;TEST CREDENTIALS
	TDNE	LINE,DEVMOD(DDB)
	CAIE	TAC,(J)			;SAME AS THE ONE WE WANT?
	JRST	TTYFX			;NO.
	JRST	TTYF9

TTYFX:	MOVEI	DDB,TTYLST		;TTYDDBS START HERE
TTYSRA:	LDB	TAC,PJOBN		;JOB ATTACHED TO THIS DDB
	CAIE	TAC,(J)			;IS THIS THE ONE
	JRST	TTYF0
	TDNE	LINE,DEVMOD(DDB)	;IS HE ATTACHED TO IT?
	JRST	TTYF9			;YES.
TTYF0:	HLRZ	DDB,DEVSER(DDB)		;FOLLOW CHAIN
	JUMPN	DDB,TTYSRA		;TO ITS END
TTYF1:	SKIPE	TAC,DEVOPR
	JRST	TTYF3
	MOVEI	LINE,TCONLN		;NO USE CTY.
	SKIPE	DDB,TTYTAB(LINE)	;DOES IT HAVE A DDB?
	JRST	TTYF9
	MOVSI	TAC,'CTY'		;NO
TTYF3:	PUSHJ	P,GETDDB		;GET A DDB FOR DEVOPR
	JRST	SCREW			;OH BOY HERE WE GO
TTYF9:	MOVE	IOS,DEVIOS(DDB)		;SET UP IOS

	SETZ	LINE,
	TLNE	IOS,TTYDTC
	POPJ	P,
↑STLNAC:
	LDB	LINE,PUNIT		; GET UNIT # FROM DDB
	HLL	LINE,LINTAB(LINE)	;AND LINE BITS
	POPJ	P,			;RETURN

SCREW:	PUSHACS
	PUSHJ	P,DISDATE
	PUSHJ	P,DISMES
	ASCIZ	/GETDDB FAILED TO MAKE A NEW TTY DDB.
/]
	POPACS
	CONSZ	PI,77400	;WHERE ARE WE
	POPJ	P,		;CROSS FINGERS AND PRAY
	JSP	DAT,UERROR	;UUO LEVEL, A WAY OUT.
;GETDDB LOG2LN GETDBA GETDB1 SIX2LN LOG2LL

;FIND A DDB FOR A TTY (BY ITS SIXBIT NAME), MAKES ONE IF NEEDED.
;CALL	MOVE	TAC,[SIXBIT /TTYn/]
;	PUSHJ	P,GETDDB
;	<NONE AVAILABLE OR DEVICE NAMED IS NOT A TTY OR CTY>
;	<LINE AND DDB SETUP>

↑GETDDB:PUSHJ	P,LOG2LN		;CONVERT LOGICAL NAME TO LINE NUMBER
	POPJ	P,			;ILLEGAL LOGICAL NAME
GETDBA:	CAIL	LINE,TTPLEN		;LEGAL LINE NUMBER?
	POPJ	P,			;NO
GETDB1:	SKIPE	DDB,TTYTAB(LINE)	;DOES THIS LINE ALREADY HAVE A DDB?
	JRST	CPOPJ1			;YES
	CAIGE	LINE,PTYL0		;IF THIS IS A PTY DON'T CALL DDBSRC
	PUSHJ	P,DDBSRC		;MAKE A DDB FOR THIS TTY.
	POPJ	P,			;NONE AVAILABLE
	MOVE	TAC,DEVNAM(DDB)		;RETURNS THE DEVICE NAME
	HLLZM	IOS,DEVIOS(DDB)		;DDBSRC SETS IOS.  THIS CLEARS IOACT.
	JRST	CPOPJ1

↑LOG2LN:MOVS	TAC,TAC
	MOVEI	LINE,TCONLN
	CAIN	TAC,'CTY'
	JRST	CPOPJ1
	TRC	TAC,'TTY'
	TRNE	TAC,-1
	POPJ	P,			;NOT TTY#
↑SIX2LN:JUMPE	TAC,CPOPJ		;JUST TTY
	MOVEI	LINE,
LOG2LL:	ROT	TAC,3
	TRZE	TAC,2
	TRNE	TAC,5
	POPJ	P,			;NOT DIGIT
	ROTC	TAC,3			;DIGIT → LINE
	JUMPN	TAC,LOG2LL		;MORE?
	CAIGE	LINE,TTPLEN	;NO, CHECK LEGALITY
	AOS	(P)
	POPJ	P,
;STDTBL, DDBSRC

;DEFAULT SPECIAL ACTIVATION MODE BREAK TABLE - BREAK ON ALL BUT LETTER OR NUMBER
STDTBL:	777777777777
	777700037600
	000000374000
	000007600000


;MAKE A NEW TTY DDB FOR A GIVEN LINE

;CALL:	MOVE	LINE,<TTY LINE NO.>
;	PUSHJ	P,DDBSRC
;	<NO FREE STORAGE, OR ILLEGAL LINE NUMBER>
;	RETURN DDB,LINE AND DEVNAM SET AND BITS TPMON,IOFST,IOACT SET.
;	IF CALLED WITH LINE = -1, A DETACHED DDB IS CREATED AND GIVEN TO JOB IN J.

↑DDBSRC:HRRE	TAC,LINE		;NUMBER OF LINE ONLY
	CAILE	TAC,TTPLEN		;IS LINE NO. TOO BIG
	POPJ	P,			;YES.
	HLL	LINE,LINTAB(LINE)	;(NOTE LINTAB-1 EXISTS AND IS ZERO)
	TLNE	LINE,DDDLIN		;SKIP IF THIS IS NOT A DATA DISK
	SKIPN	DDOFF			;IS DD.  SKIP IF DD IS SHUT OFF.
	JRST	DDBSR1	
	POPJ	P,			;SORRY - NO DATA DISKS TODAY

DDBSR1:	MOVEI	AC3,TTYFS
	PUSHJ	P,SFSGET
	POPJ	P,			;ARGH.
	MOVEI	DDB,DDBSKW(AC1)
	HRLI	AC1,TTYLST-DDBSKW
	BLT	AC1,TTYPTR(DDB)		;COPY PART OF A REAL DDB INTO OUR NEW BLOCK
	SETZM	DEVNAM(DDB)
DDBSR2:	SETZM	DEVIOS(DDB)		;ENTER HERE TO INITIALIZE SCNDDB
	SETZM	DEVLOG(DDB)
	SETZM	DEVBUF(DDB)
	SETZM	PTYPTR(DDB)
	SETZM	SAVDDB(DDB)
	MOVSI	AC1,TTICHR
	HRRI	AC1,TIBF-1(DDB)
	MOVEM	AC1,TTIBUF(DDB)
	MOVSI	AC1,TTOCHR
	HRRI	AC1,TOBF-1(DDB)
	MOVEM	AC1,TTOBUF(DDB)
	PUSHJ	P,TSETBF
	MOVEI	TAC,=84
	DPB	TAC,PTTYWD		;TTY WIDTH
	MOVSI	TAC,STDTBL
	HRRI	TAC,ACTBTS(DDB)
	BLT	TAC,ACTMOD(DDB)
	MOVE	TAC,[TTYATC,,ASSCON!ASSPRG]
	ANDCAM	TAC,DEVMOD(DDB)
	SETZM	DEVIAD(DDB)		;CLEARS PHPOS
	SETZM	DEVOAD(DDB)		;CLEARS PFITCH
	MOVE	IOS,[TPMON+IOFST,,IOACT]
	MOVEM	IOS,DEVIOS(DDB)		;MAKE SURE IT LOOKS VIRGIN.
	PUSHJ	P,TSETBF		;INITIALIZE BUFFERS (AGAIN!!??)
	CAIN	DDB,SCNDDB		;SPECIAL FOR CTYDDB=SCNDDB=TTYLST
	JRST	CPOPJ1			;ALL DONE FOR CTYDDB
	MOVEI	TAC,0			;INITIALIZE DATA BLOCK.
	DPB	TAC,PJOBN		;CLEAR JOB NUMBER IN DEVCHR
	DPB	TAC,PUNIT		;UNIT NUMBER TOO  BH 5/6/74
	MOVSI	AC1,(DDB)
	HRR	AC1,DEVSER(DDB)
	OFFSCN				;TURN OFF SCANNER CHANNEL
	EXCH	AC1,TTYLST+DEVSER
	MOVEM	AC1,DEVSER(DDB)
	ONSCN				;TURN ON SCANNER CHANNEL
	CAIE	LINE,-1			;IS SOME ONE GETTING A DETACHED DDB?
	JRST	DDBSR3
	TLO	TAC,TTYATC		;YES.  ATTACH JOB TO DDB
	IORM	TAC,DEVMOD(DDB)
	SETOM	JBTLIN(J)		;YES, FLAG AS DETACHED
	DPB	J,PJOBN			;MAKE IT HIS;
	MOVSI	IOS,TTYDTC		;FLAG AS DETACHED FROM LINE
	IORB	IOS,DEVIOS(DDB)
	JRST	CPOPJ1			;SKIP RETURN

DDBSR4:	OFFSCN				;TURN OFF SCANNER CHANNEL
	JRST	TTYKL5

DDBSR3:	TLNN	LINE,DDDLIN!DISLIN!DMDLIN ;NOT DETACHED.  IS THIS A DPY?
	JRST	SCNIN			;NO, FINISH UP AND LEAVE
	PUSHJ	P,DPYMAKE		;MAKE UP A DPY HEADER
	JRST	DDBSR4			;LOSE - RELEASE THE DDB & LEAVE
SCNIN:	DPB	LINE,PUNIT		;SET LINE NUMBER (UNIT NO.) IN DDB.

IFN FTTALK,<	DPB	LINE,PTALK	;TALK RING TO CONTAINS ONLY THIS TTY >

	MOVEI	TAC,0
	ANDI	LINE,-1
SCNIN0:	ROTC	TAC,-3			;LOW 3-BITS OF LINE INTO 3 HIGH BITS OF TAC
	HRRI	TAC,2			;CONVERT TO SIXBIT
	ROT	TAC,-3			;BY SHIFTING +20 INTO TAC
	JUMPN	LINE,SCNIN0		;LOOP WHILE THERE'S ANYTHING LEFT.
	HRRI	TAC,'TTY'
	MOVS	TAC,TAC
	PUSH	P,TAC
	OFFSCN				;TURN OFF SCANNER CHANNEL
	PUSHJ	P,STLNAC
	HRRZ	TAC,TTYTAB(LINE)	;DID SOMEONE SNEAK ANOTHER DDB IN HERE?
	JUMPN	TAC,SCNINX		;JUMP IF THERE'S ANOTHER DDB THERE ALREADY.
	POP	P,DEVNAM(DDB)		;SET DEVICE NAME IN DDB
	HRRM	DDB,TTYTAB(LINE)	;AND SET DDB ADDRESS IN TTYTAB
	MOVSI	TAC,'CTY'
	TLNE	LINE,CTYLIN		;IS THIS CONSOLE TTY?
	MOVEM	TAC,DEVNAM(DDB)		;YES, CHANGE NAME TO CTY.
	ONSCN				;TURN ON SCANNER CHANNEL
	JRST	CPOPJ1			;SUCCESSFUL RETURN.

;THIS FAILURE HAPPENS AT A LOWER PRIORITY THAN THE SCANNER.
SCNINX:	SUB	P,[1,,1]		;ADJUST STACK  (TTYKL5 WANTS SCNOFF)
	JRST	TTYKL5			;RETURN THIS DDB TO FREE STORAGE. FAILURE.
;TTYSKL TTYREL TTYKIL TTYKL5 TTYKL6 NOTYPA
;CALL TO MAKE REQUEST TO DPYKIL.
;CONO PI,SCNOFF MUST HAVE BEEN DONE BEFORE THIS ROUTINE IS CALLED.
TTYSKL:	PUSHJ	P,STLNAC		;GET LINE CHARACTERISTICS.
	TLNE	LINE,DDDLIN!DISLIN!DMLIN
	SKIPN	AC1,LETAB(LINE)
	POPJ	P,			;NOT A DISPLAY, OR NO DPY HEADER
	MOVEI	TAC,(LINE)
	PUSHJ	P,DPYK9			;PLANT CLOCK REQUEST TO CALL DPYKIL
	JUMPL	AC2,CPOPJ		;JUMP IF REQ WAS ALREADY PLANTED
	SETZM	LEACT(AC1)		;CLEAR ACTIVE FLAG (WE JUST PLANTED REQ)
	POPJ	P,

↑TTYREL:
IFN DILNUM,<
	LDB	LINE,PUNIT		;SETUP LINE
	PUSHJ	P,DILTRL		;CHECK FOR DIALER RELEASE
>;DILNUM
	HLLZS	TAC1,DEVIOS(DDB)	;CLEAR INITTED BITS IN IOS.
	MOVE	TAC,DEVMOD(DDB)
	TLNE	TAC,TTYATC		;THAT'S ALL IF IT'S HIS CONSOLE
	POPJ	P,
	MOVSI	IOS,TPMON		;NO, PUT HIM BACK IN MONITOR MODE
	IORB	IOS,DEVIOS(DDB)
	TRNE	TAC,ASSCON		;DON'T KILL IF ASSIGNED BY CONSOLE
	POPJ	P,
			;FALL INTO TTYKIL

;ROUTINE TO SET SCNSER TO RETURN TTY TO VIRGIN STATE
;CALL:	MOVE	DDB, ADDRESS OF DEVICE DATA BLOCK
;	PUSHJ	P,TTYKIL

;CALLED FROM COMCSS (JOBKIL).
;IF NOT OPERATOR CONSOLE, THEN
; 1)CLEAR PHYSICAL AND LOGICAL	NAMES,
; 2)CLEAR JOB NUMBER ASSIGNMENT
;	3)CLEAR	TTYUSE,TTYATC,ASSCON,ASSPRG,
;	4)CLEAR ENTRY IN TRANSLATOR TABLE.

↑TTYKIL:
	OFFSCN				;TURN OFF SCANNER CHANNEL
	TLNE	IOS,TTYDTC
	JRST	TTYKL5			;TAKE 3 GIANT STEPS IF YOU'RE DETACHED.
	PUSHJ	P,TTYSKL		;IF A DPY, MAKE IT AVAIL. (SETS LINE)
	SKIPN	DDB,TTYTAB(LINE)	;DID SOMEONE ELSE KILL IT?
	JRST	SCNONJ			;YES.
	TRNN	DDB,-1			;IS THERE REALLY ONE HERE?
	JRST	[PUSHJ P,TTYKL9		;NO DDB, NO NOTHING!
IFN FTTTYBUG,<	PUSHJ P,CNTCOM		>
		JRST SCNONJ]		;AND THEY'RE OFF
	MOVSI	IOS,TTYIOW!IOW!TTYDTC!DDTM	; CLEAR TTY INPUT AND OUTPUT
	ANDCAM	IOS,DEVIOS(DDB)		;WAIT BITS SO TTY WILL BE KILLED
					;PROPERLY AT INTER. LEVEL IF STILL OUTPUTING
	MOVE	TAC,[TTYATC,,ASSCON!ASSPRG]
	ANDCAM	TAC,DEVMOD(DDB)		;TTY IS NO LONGER A JOB'S CONSOLE.
	MOVSI	IOS,TPMON		;CLEAR JOB NUMBER
	DPB	IOS,PJOBN
	IORB	IOS,DEVIOS(DDB)		;TURN TPMON ON IN CASE TTY IS
					;STILL OUTPUTTING
	SKIPG	TTYTAB(LINE)		;COMMAND IN ALREADY?
	JRST	SCNONJ			;YES, LEAVE NOW!
	MOVE	TAC,TITCTR(DDB)		;TAKR COUNT
	CAMN	TAC,TIPCTR(DDB)		;COMPARE WITH PUTR
	JRST	NOTYPA			;NO TYPE AHEAD
	SKIPLE	TISYNC(DDB)		;ANY LINES TO TELL MONITOR ABOUT?
	PUSHJ	P,COMSET		;WAKE COMMAND DECODER
	JRST	SCNONJ

NOTYPA:
	TLNN	LINE,PTYUSE		;DON'T KILL DDB FOR USED PTY'S.
	TLOE	IOS,IO+TOIP		;IS IT OUTPUTTING OR TALKING?
	JRST	TTYKL6
IFN FTDM,<
;;	TLNE	LINE,DMLIN
	SKIPN	TAC,LETAB(LINE)
	JRST	TTYKL5
;;	TLZ	IOS,TOIP		;Don't turn on TOIP if going to TTYKL6
;;	HRRZ	AC1,DMPPPT(TAC)
;	HRRZ	AC2,DMLEPT(TAC)		; (Not needed, since anything in LE queue
;	CAIN	AC2,DMLEPT-QLINK(TAC)	;  will keep TOIP on until done.)
;;	CAIE	AC1,DMPPPT-QLINK(TAC)	;Is PP queue empty?
;;	JRST	TTYKL6			;Must be holding output, wait till done
	MOVSI	AC1,KILTTY		;Tell DPYKIL to flush DDB when
	IORM	AC1,TTYTAB(LINE)	;  flushing dpy header
	JRST	SCNONJ
>;FTDM

↑TTYKL5:
	MOVEI	TAC,TTYLST		;DON'T KILL THIS GUY
	CAIE	TAC,(DDB)		;IS THIS THE FIRST DDB
	JRST	TTYKL2			;BLAST THE MOTHER
	HLLZS	DEVIOS(DDB)		;CLEAR INITTED STUFF IN IOS
	PUSHJ	P,LINCLR		;CLEAR LINE TABLE.
	SETZM	DEVLOG(DDB)		;CLEAR LOGICAL NAME
	JRST	SCNONJ			;ON CLYDE.

TTYKL6:	TLZ	IOS,TOIP
	IORB	IOS,DEVIOS(DDB)		;MAKE SURE IT GETS KILLED AT INTERUPT LEVEL.
	JRST	SCNONJ
;MORE TTYKIL	TTYKL2 TTYKL3 TTYKL8 LINCLR TTYKL1 TTYKL4 TTYKL9 TTYK91 TTYK92
;THIS RETURNS A DDB TO FREE STORAGE.

TTYKL2:	MOVEI	AC1,TTYLST		;SEARCH CHAIN FOR POINTER TO DDB.
TTYKL3:	MOVE	TAC,AC1
	HLRZ	AC1,DEVSER(AC1)		;LINK
	CAIE	AC1,(DDB)		;IS THIS THE GUY THAT POINTS TO OURS
	JUMPN	AC1,TTYKL3
	JUMPE	AC1,TTYKL4
	MOVE	AC1,DEVSER(DDB)
	MOVEM	AC1,DEVSER(TAC)		;LINK HIM OUT
TTYKL8:	PUSHJ	P,LINCLR		;CLEAR LINTAB BITS
	TLNN	IOS,TTYDTC
	PUSHJ	P,TTYKL9
IFN FTTTYBUG,<	PUSHJ	P,CNTCOM	>
	ONSCN				;TURN ON SCANNER CHANNEL
	MOVEI	AC1,-DDBSKW(DDB)
	PUSHJ	P,FSGIVE
	MOVEI	DDB,0
	POPJ	P,

LINCLR:	TLNE	IOS,TTYDTC		;NO LINE IF DETACHED
	POPJ	P,
	TLNN	LINE,PTYLIN		;PTY'S AREN'T IN THIS TABLE
	IOR	LINE,LINBIT(LINE)	;OR IN INITIALIZE BITS
	TLZ	LINE,KILMSK		;CLEAR BITS IN LINE TABLE
	HLLM	LINE,LINTAB(LINE)
	POPJ	P,

TTYKL1:	LDB	LINE,PUNIT		;LINE NO.
	SKIPGE	TTYTAB(LINE)
	SOS	COMCNT
	PUSHJ	P,TTYKL9		;CLEAR TRANSLATOR TABLE
IFN FTTTYBUG,<	PUSHJ	P,CNTCOM>
	SETZM	DEVNAM(DDB)
	JRST	TSETBF			;BLAST TYPE AHEAD AND OUTPUT.

TTYKL4:
	PUSHACS
	PUSH P,TAC
	PUSH P,DDB
	PUSHJ P,DISMES
	ASCIZ /πππDDB NOT FOUND IN LIST AT TTYKIL
DDB=/
	POP P,TAC
	PUSHJ P,DISOCT
	PUSHJ P,DISMES
	ASCIZ /
LAST LINK=/
	POP P,TAC
	PUSHJ P,DISOCT
	PUSHJ P,DISMES
	ASCIZ /
/
	POPACS
	JRST TTYKL8		;GIVE IT BACK ANYWAY

;ALL THE "PUSHJ P,TTYKL9"S ABOVE USED TO BE "SETZM TTYTAB(LINE)"
;IF LH OF TTYTAB ENTRY ≠ LINE THEN WE WERE IN A TALK RING AND
;THIS ROUTINE PATCHES THE RING UP TO LEAVE US OUT

TTYKL9:	LDB AC2,PTALK		;MY TALKRING POINTER
	MOVEI AC3,0
	EXCH AC3,TTYTAB(LINE)	;DON'T NEED TTYTAB ANYMORE
	JUMPE AC3,CPOPJ		;GRUMBLE, SOMEBODY CLOBBERED IT ALREADY
	CAIN AC2,(LINE)		;POINTS TO ME?
	POPJ P,			;YES, NO PROBLEM
	PUSH P,AC2		;SAVE NEXT GUY
	MOVE AC3,LINE		;MY LINE NUMBER
TTYK91:	MOVE LINE,AC2		;LOOP THROUGH TILL YOU FIND ME
	LDB AC2,PTALK
	CAIE AC2,(AC3)
	JRST TTYK91		;NOT ME YET
	POP P,AC2		;RETRIEVE MY POINTEE
	DPB AC2,PTALK		;MAKE PREV POINT TO NEXT
	CAIE AC2,(LINE)
	JRST TTYK92
	MOVSI AC2,TLKRNG
	ANDCAM AC2,LINTAB(LINE)	;TURN OFF THE FLAG IF ONLY ONE LEFT
TTYK92:	MOVE LINE,AC3		;FIX LINE
	POPJ P,
;OUTCH6, OUTCHS, OUTCHR
;MORE CHARACTER AND BUFFER HANDLING ROUTINES

;OUTCHR CALLED AT UUO LEVEL TO OUTPUT A CHARACTER
;DAT AND DDB MUST BE SET UP
;CHECK IS MADE FOR WHETHER SPECIAL ECHO IS REQUIRED
;RIGHT THINGS ARE DONE WITH PHPOS & HPOS(NEEDNT BE SET)
;CALL	MOVE	CHR,CHAR TO BE OUTPUT
;	PUSHJ	P,OUTCHR
;	ONLY RETURN, WITH CHAR. OR ITS SPECIAL ECHO PLACED IN OUT BUFFER

LOSYS

↑OUTCH6:
	ADDI CHR,40		;TYPE OUT SIXBIT.

↑OUTCHS:
	JUMPE	PID,OUTC1S
	SKIPP1			;ARE WE REALLY P1 DESPITE PID?
	JRST	CTYTYO		;NO, JUST TYPE ON THE SIX'S CTY (DISASTER TYO)
	PUSHACS
	PUSHJ	P,DISMES
	ASCIZ	/PID CLOBBERED AT OUTCHS. PID=/
	MOVE	TAC,PID
	PUSHJ	P,DISOCT
	PUSHJ	P,DISCRLF
	POPACS
	SETZ	PID,		;MAKE IT RIGHT!!
	JRST	OUTC1S
HISYS


OUTC1S:	PUSH	P,TAC
	PUSH	P,HPOS		;CALL OUTCHR ROUTINE (SAVE J≡HPOS AND TAC)
	PUSHJ	P,OUTCH5
	POP	P,HPOS
	JRST	TPOPJ

OUTCHR:	MOVE	TAC,DEVIOS(DDB)	;GET IOS
	TLNE	TAC,TTYDTC
	POPJ	P,
	ANDI	TAC,16
	CAIN	TAC,10		;MODE 10 OR 11?
	JRST	OUTCH2		;YES, NO CONVERSION
	MOVEI	AC3,20		;CHECK FREE SPACE
	CAML	AC3,TOFCTR(DDB)	; FOR EXPANDING CHARS
	JRST	GETCH1		;NOT ENOUGH ROOM
OUTCH5:	MOVE	TAC,DEVIOS(DDB)
	TLNE	TAC,TTYDTC		;NO OUTPUT IF DETACHED
	POPJ	P,
	ANDI	TAC,16
	CAIN	TAC,10			;MODE 10 OR 11?
	JRST	OUTCH2			;YES, NO CONVERSION
	ANDI	CHR,177			;MASK ANY JUNK
	PUSH	P,LINE
	PUSHJ	P,STLNAC		;SET UP LINE
	LDB	HPOS,PHPOS		;GET HORIZONTAL POSITION
	JRST	OUTCA1

OUTCA2:	PUSH	P,CHR			;LINE OVERFLOW AND TTY. SAVE CHR
	MOVEI	CHR,15			;INSERT CRLF
	PUSHJ	P,OUTCH2		;(REG) DON'T CALL CRLFEC - IT DOESN'T
	MOVEI	CHR,12			;  CONO PI,SCNOFF BEFORE CALLING PUTCHO
	PUSHJ	P,OUTCH2
	POP	P,CHR
	MOVEI	HPOS,0			;RESET HORIZONTAL POSITION.  RECOMPUTE HPOS.
OUTCA1:	MOVE	AC3,HPOS		;SAVE FOR TAB (OUTCH1)
	PUSHJ	P,ADJHP			;NEW HPOS AFTER CHAR OUTPUT.  SET UP TAC.
	JFCL
	MOVEM	TAC,1(P)		;SAVE TAC.  BEWARE!
	LDB	TAC,PTTYWD		;GET THE WIDTH
	CAIL	TAC,=16
	JRST	OUTCA3
	MOVEI	TAC,=84
	DPB	TAC,PTTYWD		;AVOID NASTY LOOPS!
OUTCA3:	CAIG	HPOS,(TAC)		;IS TTY CARRIAGE TOO FAR RIGHT?
	JRST	OUTCHA			;NO OVERFLOW.
	TLNN	LINE,IMPBIT			;ARPA-PTYS AND REAL TTYS GET THIS
	TLNN	LINE,DMLIN!DISLIN!IMLIN!DDDLIN!PTYLIN	;SKIP IF NOT REALLY A TTY.
	JRST	OUTCA2				;ARPA OR TTY. (OLD TAC IRRELEVANT)
OUTCHA:	MOVE	TAC,1(P)	;RESTORE TAC.
	DPB	HPOS,PHPOS	;UPDATE IN CORE
	TLNE	TAC,ARRBIT	;BH 4/27/75
	TLNN	LINE,ECHARR	;IF THIS IS AN UPARROW CHAR
	JRST	.+2		;  AND WE'RE IN THE RIGHT MODE,
	JRST	ARROUT		;  GO DO IT
	TLNN	TAC,SPOUT	;VT,FF,HT?
	JRST	OUTC1X		;NO.
	TLNE	LINE,PTYLIN	;IS THIS A PTY?
	TLNE	LINE,IMPBIT	;YES. IS IT AN IMP?
	JRST	OUTCH1		;NOT A PTY, OR AN ARPA-PTY. - EXPAND TABS, ETC.
OUTC1X:	POP	P,LINE
OUTCH2:	OFFSCN				;TURN OFF SCANNER CHANNEL
	PUSHJ	P,PUTCHO	;PUT OUT THE CHAR.
	ONSCN				;TURN ON SCANNER CHANNEL
	POPJ	P,
;MORE OUTCHR--ADJHP ARROUT OUTCH1 OUTC1A OUTC1Y OUTC1Z OUTC1C OUTC1B ADJHP2 ADJHP1
;HERE ON UUO OUTPUT OF HT,FF,VT

OUTCH1:	MOVE	HPOS,AC3	;POS BEFORE THE TAB
	MOVE	TAC,CHR		;COPY THE CHARACTER
	CAIN	CHR,11		;IS IT A TAB?
	TLNE	LINE,TBXPND	;YES. SHOULD WE EXPAND IT?
	JRST	OUTC1Y		;EXPAND FF,VT, OR HT IF TBXPND IS SET.
	TLNE	LINE,IMLIN!PTYLIN!DISLIN!DDDLIN!DMLIN ;NEED IDLE CHARS.?
	JRST	OUTC1X		;NO
OUTC1A:	POP	P,LINE		;HERE ON OUTPUT OF TAB TO SMART TTY
	ANDI	HPOS,7		;JUST LOW PART FOR INDEX
	XCT	(HPOS)[	MOVEI HPOS,6	;8 SPACES-2 IDLES
			MOVEI HPOS,6	;7 SPACES-2 IDLES
			MOVEI HPOS,6	;6 SPACES-2 IDLES
			MOVEI HPOS,7	;5 SPACES-1 IDLE
			MOVEI HPOS,7	;4 SPACES-1 IDLE
			MOVEI HPOS,7	;3 SPACES-1 IDLE
			JRST OUTCH2	;2 SPACES-0 IDLES
			JRST OUTC1Z]	;1 SPACE -CONVERT TO SPACE (OR CTY WILL MISS TAB STOP)
	PUSHJ	P,OUTCH2	;SEND THE REAL CHAR
	MOVEI	CHR,IDLECH	;A DELAY CHARACTER
	JRST	OUTC1C		;OUTPUT SLUFFS. COUNT WILL BE MODIFIED ON VT,FF

OUTC1Y:	POP	P,LINE		;HERE TO EXPAND CHARACTER.
OUTC1Z:	MOVEI	CHR,40		;HERE FOR A STUPID TTY.  CHANGE TAB TO SPACE
	CAIE	TAC,11		;H TAB?
	MOVEI	CHR,12		;BUT IT WASN'T A TAB.  CHANGE IT TO LF.
OUTC1C:	CAIN	TAC,14		;FF?
	MOVEI	HPOS,0		;YES. 8 LF'S.
	CAIN	TAC,13		;VT?
	MOVEI	HPOS,4		;YES. 4 LF'S.
OUTC1B:	PUSHJ	P,OUTCH2	;OUTPUT THE PHONY CHAR
	ADDI	HPOS,1		;COUNT THE OUTPUTS
	TRNE	HPOS,7		;ENOUGH?
	JRST	OUTC1B		;NO. MORE.
	POPJ	P,		;NO MORE


;CALLED AT UUO AND INT LEVEL TO ADJUST HPOS FOR OUTPUT OF CHR
;SKIPS IF SPCHECK SAYS SPECIAL CHAR.

ADJHP:	PUSHJ	P,SPCHEK	;GET BITS FROM SPCTAB
	AOJA	HPOS,CPOPJ	;ORDINARY CHAR.
	TLNE	TAC,ARRBIT	;BH 4/27/75
	TLNN	LINE,ECHARR	;IF THIS IS AN UPARROW CHAR
	JRST	ADJHP2		;  AND WE'RE IN THAT MODE,
	AOJA	HPOS,ADJHP1	;  IT TAKES 2 SLOTS

ADJHP2:	CAIL	CHR,40		;WHICH SPECIALS?
	JRST	CPOPJ1		;HIGH ONES
	CAIN	CHR,15		;CARRIAGE RETURN?
	MOVEI	HPOS,0		;YES.
	CAIE	CHR,11		;TAB?
	JRST	CPOPJ1		;NO. NO HP MOD
	TRO	HPOS,7		;TAB. TO NEXT 8
ADJHP1:	AOJA	HPOS,CPOPJ1

ARROUT:	PUSH	P,CHR		;OUTPUT UPARROW MUMBLE
	MOVEI	CHR,"↑"
	PUSHJ	P,OUTCH2
	POP	P,CHR
	ADDI	CHR,100		;TURN INTO DECENT CHARACTER
	JRST	OUTC1X
;PUTCHI PUTCHO PUTCHA PUTCI1 TTIOUT PUTCRX FILNCR PUTNLC PUTCRS PUTCO1
;ROUTINE TO PUT A CHARACTER INTO A BUFFER (FOR INPUT,MERTPO, AND ONCE)
;CALL	MOVEI	DAT,TTXBUF(DDB)		;TO SPECIFY BUFFER
;	PUSHJ	P,PUTCHI
;	ERROR RETURN, BUFFER "FULL"
;	SUCCESSFUL RETURN

PUTCHI:	SOSG	FCTR(DAT)		; ANY FREE SPACES LEFT?
	JRST	PUTCI0			;NO
PUTCHA:	SOSLE	PCTR(DAT)		;LAST BYTE IN BUFFER FILLED?
	JRST	PUTCI1			;NO. GO AHEAD
	PUSH	P,TAC
	MOVE	TAC,BUF(DAT)		;GET ADR AND SIZE OF BUFFER
	HLRZM	TAC,PCTR(DAT)		;INITIAL COUNTER
	HRRM	TAC,PUTR(DAT)		;BYTE POINTER.
	POP	P,TAC			;RESTORE TAC
PUTCI1:	IDPB	CHR,PUTR(DAT)
	JRST	CPOPJ1

;ROUTINE TO STUFF MONITOR ERROR MESSAGE IN TTI BUFFER
;CALLED IN LINE FROM PUTCHO

TTIOUT:	MOVE	IOS,DEVIOS(DDB)
	AOS	TOFCTR(DDB)		;RE-ADJUST FREE CHAR COUNT
	TRNN	IOS,MERTPO		;MONITOR ERROR MESSAGE?
	JRST	GETCH1			;NO.  CHR←0 TO INDICATE
	TRON	IOS,MERTP1		;TEST FLAG AND SET IF NOT ON
	PUSHJ	P,SETBFI		;CLEAR INPUT
	MOVEM	IOS,DEVIOS(DDB)		;AND MAKE SURE FLAG GETS ON
	MOVEI	DAT,TTIBUF(DDB)		;YES, PUT REST IN TTI BUFFER
	PUSHJ	P,PUTCHI
	POPJ	P,			;ERROR RETURN
	POPJ	P,

;ROUTINE TO PLACE A CHARACTER INTO THE OUTPUT BUFFER
;CALLED AT INTERRUPT LEVEL  (OR WITH THE SCANNER OFF)
;CALL	MOVE	CHR,CHARACTER TO PLACE INTO BUFFER
;	PUSHJ	P,PUTCHO
;	ONLY RETURN, WHETHER OR NOT CHARACTER WAS PLACED

PUTCHO:	PUSH	P,TAC
	LDB	TAC,PIOMOD		;GET IO MODE
	CAIE	TAC,10
	CAIN	TAC,11
	JRST	PUTNLC			;DON'T OR CONVERT IN IMAGE MODE.
	LDB	TAC,PUNIT
	HLL	TAC,LINTAB(TAC)
	TLC	TAC,TTYFIL		;MAKE OFF MEAN FILLING
	CAIN	CHR,15			;IS THIS A CR?
	TLNE	TAC,TTYFIL!DMLIN	;YES, ARE WE FILLING ON A NON-DATAMEDIA?
	JRST	FILNCR			;NOT CR OR NOT FILLING OR ON DM
	MOVEI	TAC,10
	EXCH	TAC,(P)			;(RESTORE OLD TAC)
PUTCRX:	PUSHJ	P,PUTCRS
	SOSLE	(P)			;DONE YET?
	JUMPN	CHR,PUTCRX		;NO.  JUMP UNLESS BUFFER FULL (CHR=0)
	SUB	P,[1,,1]
	POPJ	P,

FILNCR:	TLNE	TAC,FCS
	JRST	PUTNLC			;NOT FULL CHAR SET - CONVERT LOWER TO UPPER
	CAIL	CHR,"a"
	CAILE	CHR,"z"
	JRST	PUTNLC
	ANDCMI	CHR,40			;CONVERT TO UPPER CASE
PUTNLC:	POP	P,TAC
PUTCRS:	SOSG	TOFCTR(DDB)		;RETURN IMMEDIATELY IF NO ROOM
	JRST	TTIOUT			;UNLESS MONITOR ERROR MESSAGE
	SOSLE	TOPCTR(DDB)		;LAST BYTE IN BUFFER?
	JRST	PUTCO1			;NO. GO ON.
	PUSH	P,TAC			;SAVE AN AC
	MOVE	TAC,TTOBUF(DDB)		;GET COUNT AND ADDRESS
	HLRZM	TAC,TOPCTR(DDB)		;INITIAL COUNTER
	HRRM	TAC,TOPUTR(DDB)		;INITIAL POINTER
	POP	P,TAC			;RESTORE AC
PUTCO1:	IDPB	CHR,TOPUTR(DDB)		;PUT CHARACTER INTO BUFFER
	POPJ	P,
;GETCHR, GETCHY
;CHARACTER AND BUFFER HANDLING ROUTINES

;ROUTINE TO PICK UP A CHARACTER FROM ANY BUFFER
;CALL	MOVEI	DAT,TTXBUF(DDB)		;TO SPECIFY BUFFER
;	PUSHJ	P,GETCHR
;	ONLY RETURN			;CHARACTER OR ZERO IN CHR
;					;ZERO INDICATES BUFFER "EMPTY"(TAKR=PUTR)

↑GETCHR:PUSHJ P,GETCHY
	ANDI CHR,177		;THROW OUT CONTROL BITS.
	POPJ P,

GETCHY:	
	HLRZ CHR,BUF(DAT)		;CHARS IN BUFFER (THIS IS A BUG TRAP!!)
	CAIN CHR,TTICHR			;TTICHR FOR INPUT.
	JRST GETCHA
	PUSHACS
	PUSH P,LINE
	PUSHJ P,DISMES
	ASCIZ /TTY/
	POP P,TAC
	PUSHJ P,DISLOC
	PUSHJ P,DISMES
	ASCIZ / AT GETCHY FOR OUTPUT
/
	POPACS
	DEBCHECK
	JRST GETCHO
;GETCHA GETCHO PUTCI0 GETCO1 GETCO2 GETCHX GETCH2 GETCH1
; ROUTINE TO GET CHARACTER

GETCHA:	SOSGE	TSYNC(DAT)		;ALWAYS COME HERE FOR INPUT.
	SETZM	TSYNC(DAT)		;DON'T LET IT GET NEGATIVE
	LDB	CHR,[POINT PUNITS,-TTIBUF+DEVCHR(DAT),35-PUNITP]
	HLL	CHR,LINTAB(CHR)		;GET LINE CHARACTERISTICS
	TLNN	CHR,DISLIN!DDDLIN!DMLIN	;IS IT A DISPLAY?
	JRST	GETCO1			;NO
	HLRZ	CHR,LETAB(CHR)
	TRNN	CHR,WTFLAG		;IF LINED IS NOT WAITING,
	JRST	GETCO1			; THEN JUST LEAVE WITH THE GOODS
	PUSHJ	P,GETCO1		;GET CHARACTER
	PUSHACS
	LDB	DAT,[POINT PUNITS,-TTIBUF+DEVCHR(DAT),35-PUNITP]
	PUSHJ	P,ACTIV3		;CALL LINED TO XFER CHARS TO INPUT BUF
	POPACS
	POPJ	P,

GETCO1:	LDB	CHR,PLSTLC	;BH 7/7/75 FIXING BUG WHEREBY INCHRS OF RUBOUT
	CAMN	CHR,TCTR(DAT)	;WHERE CHARS HAVE BEEN TYPED AND EATEN SINCE
	CAMN	CHR,PCTR(DAT)	;   (DON'T DO IT IF NOT GOBBLING ANYTHING NOW)
	JRST	GETCHO		;LAST ACTIVATOR TRIES TO DELETE ALREADY EATEN
	SOSG	CHR		;CHAR BECAUSE PLSTLC IS ONLY UPDATED AT ACTIVATOR
	HLRZ	CHR,BUF(DAT)
	DPB	CHR,PLSTLC
GETCO2:	PUSHJ	P,GETCHO
	CAIE	CHR,400		;SPECIAL TESTS FOR 400 IN INPUT BUFFER
	POPJ	P,
	MOVSI	CHR,TPMON		;MUST BE USER MODE
	TDNE	CHR,DEVIOS-TTIBUF(DAT)
	JRST	GETCO2
	MOVEI	CHR,EMODE		;AND EMODE
	TDNN	CHR,ACTMOD-TTIBUF(DAT)
	JRST	GETCO2			;SORRY, YOU CAN'T HAVE IT--GET ANOTHER.
	MOVEI	CHR,400
	POPJ	P,

↑GETCHO:		;7 BIT BYTES ALREADY (OUTPUT)
GETCHX:	MOVE	CHR,TCTR(DAT)		; GET TAKR BUFFER
	CAMN	CHR,PCTR(DAT)		;IS IT SAME AS PUTR(BUFFER EMPTY)?
	JRST	GETCH1			;YES, LOAD CHR WITH ZERO AND EXIT
	SOSLE	TCTR(DAT)		;NO, ARE WE AT END OF BUFFER?
	JRST	GETCH2			;NO. GO ON.
	MOVE	CHR,BUF(DAT)		;YES. START AT TOP AGAIN
	HLRZM	CHR,TCTR(DAT)		;INITIAL COUNTER
	HRRM	CHR,TAKR(DAT)		;INITIAL POINTER
GETCH2:	ILDB	CHR,TAKR(DAT)		;GET CHARACTER
	AOS	FCTR(DAT)		;INCREMENT FREE CHAR. COUNT
	JUMPE	CHR,GETCHX		;SKIP NULLS
	POPJ	P,

GETCH1:	TDZA	CHR,CHR			;RETURN 0 INDICATING END OF BUFFER
PUTCI0:	AOS	FCTR(DAT)		;FIX FREE COUNTER
	POPJ	P,
;TSETBF, SETBFI, SETBF3, SETBFO
;ROUTINES TO SET UP BUFFERS

↑TSETBF:PUSHJ	P,SETBF2		;INIT TTO BUFFER
↑SETBFI:MOVE	DAT,J			;SAVE J
	LDB	J,PJOBN			;GET JOB #
	JUMPE	J,SETBF4
	CONSZ	PI,77000		;IN CH 1-6?
	JRST	SETBF9			;YES, CAN'T CLRSIN NOW
	MOVSI	TAC,COMSNB
	PUSHJ	P,CLRSIN		;CLEAR FROM SWAPIN LIST FOR COMMAND
SETBF4:	MOVE	J,DAT			;RESTORE J
	MOVEI	DAT,1
	DPB	DAT,PCOMIC
	DPB	DAT,PLSTLC
	MOVEI	DAT,TTIBUF(DDB)		;SPECIFY USER MODE INPUT BUFFER
	SETZM	TISYNC(DDB)		;NO LINES IN BUFFER
	HRLI	TAC,1100		;9 BIT BYTES IN INPUT BUFFER !!
	JRST	SETBF0			;INIT BUFFER

↑SETBF3:PUSHJ	P,XMTIN5		;MAKE SURE GUY ISN'T HUNG ON OUTPUT.
SETBF2:	MOVEI	DAT,TTOBUF(DDB)		;SPECIFY OUTPUT BUFFER
↑SETBFO:HRLI	TAC,700			;7 BIT BYTES IN OUTPUT BUFFER.
SETBF0:	HRR	TAC,BUF(DAT)
	MOVEM	TAC,TAKR(DAT)
	MOVEM	TAC,PUTR(DAT)
	MOVEI	TAC,1
	MOVEM	TAC,TCTR(DAT)		;SO FIRST SOSG DOESNT SKIP
	MOVEM	TAC,PCTR(DAT)
	HLRZ	TAC,BUF(DAT)		;CHARACTER COUNT
	MOVEM	TAC,FCTR(DAT)		;UPDATE FREE CHARACTER COUNT
	POPJ	P,

SETBF9:	HRLI	J,SETBF8		;SET UP CLOCK RQ TO CALL CLRSIN
	CONO	PI,PIOFF
	IDPB	J,CLKQ
	CONO	PI,PION
	JRST	SETBF4

SETBF8:	HRRZ	J,DAT
	MOVSI	TAC,COMSNB
	JRST	CLRSIN
;SPCHEK, SPCACT
;ROUTINE TO CHECK IF A CHARACTER IS SPECIAL(ASCII 0-37, 175-177)
;CALL	MOVE	CHR,CHAR. TO BE CHECKED
;	PUSHJ	P,SPCHEK
;	RETURN1 IF REGULAR ASCII CHAR (40-174), C(TAC)=0
;	RETURN2 IF SPECIAL CHAR., TAC LOADED WITH WORD FROM SPCTAB

↑SPCHEK:LDB	TAC,[POINT 7,CHR,35]	;GET CODE WITHOUT CTRL BITS.
	SKIPN	TAC,SPCTAB(TAC)
	POPJ	P,
	TLNE	LINE,DISLIN!DDDLIN!DMDLIN
	TLZ	TAC,ARRBIT		;NO UPARROWS ON DPYS
	TLNN	TAC,SPCBTS		;MAYBE A SPECIAL
	POPJ	P,			;NOT SPECIAL, AFTER ALL.
	JRST	CPOPJ1

;SPECIAL CHARACTER TABLE
;FORMAT	XWD BITS+CHAR,ADDRESS OF ROUTINE
;HIGH ORDER BITS IN LH:

SPACTN←←400000		;SPECIAL ACTION TO BE TAKEN
ALLSPA←←200000		;ALWAYS CONTROL FUNCTIONS, NEVER BREAK CHARACTERS.
SPOUT←←100000		;SPECIAL HANDLING ON UUO OUTPUT
IMLCHR←←40000		;NOT SPECIAL ON IMLACS EVEN IF ALLSPA IS ON.
↑BREAKB←←20000		;BREAK CHARACTER
SPHPOS←←10000		;CHARACTER AFFECTS HORIZONTAL POSITION
FCSBRK←←4000		;BREAK CHARACTER IN FCS(100) MODE
ECHSUP←←2000		;SUPPRESS ECHO OF CHAR ITSELF
SPBKDS←←1000		;PERFORM SPECIAL ACTION EVEN WITH CTRL. BITS.
LETTER←←400
NUMBER←←200
ARRBIT←←100		;CHAR ECHOES AS UPARROW MUMBLE IF LINTAB BIT SET
LNUMBT←←LETTER!NUMBER	;A LETTER OR DIGIT.

SPCBTS←←SPACTN!SPOUT!BREAKB!SPHPOS!FCSBRK

DEFINE SPC(U,L,X){FOR Z←U,L {X
			      }
		  }

;BITS FROM LOW-ORDER PART OF FOURTH WORD OF SPECIAL ACTIVATION TABLE
SUPBTS←←1	;SUPPRESS ACTIVATION ON CONTROL BITS.
SUPCCR←←2	;SUPPRESS EFFECT OF CONTROL CR TO LINE EDITOR
SUPSCM←←4	;SUPPRESS SUPBTS (ACTIVATE ANYWAY) IF CTRL-META
↑EMODE←←10	;INSERT 400 AFTER LAST CHARACTER ACTIVATED
↑BSACT←←20	;ACTIVATE ON BS WHEN LINE IS EMPTY
↑ALLACT←←40	;ACTIVATE ON ANYTHING W/ BUCKY BITS, OR BS, UNLESS REEDITING
↑SUPERS←←100	;SUPPRESS ERASURE OF NON-INITED LINE EDITOR WHEN LEYPOS GIVEN

SPCACT:	LDB TAC,[POINT 7,CHR,35]
	JUMPE TAC,CPOPJ		;ALWAYS ACTIVATE ON ↑C
	PUSH P,LINE
	IDIVI TAC,=36		;FIND CORRESPONDING WORD OF SPCL ACT TABLE FOR CHAR
	ADDI TAC,(DDB)
	MOVE TAC,ACTBTS(TAC)
	LSH TAC,(LINE)		;FIND CORRESPONDING BIT IN SPCL ACT TABLE
	TLNE TAC,400000
	JRST TTPOP		;BIT ON IN TABLE--ACTIVATE ON THIS CHAR
	MOVE LINE,ACTMOD(DDB)	;GET SPECIAL BITS IN FOURTH WORD
	TRNE LINE,SUPSCM
	CAIE UCHN,3
	TRNN LINE,SUPBTS
	JUMPG UCHN,TTPOP
	AOS -1(P)		;DON'T ACTIVATE ON THIS CHAR
TTPOP:	POP P,LINE
	POPJ P,
;SPCTAB
SPCTAB:	XWD	ALLSPA+SPACTN+ECHSUP+BREAKB+SPBKDS,CONTC	;↑C
	XWD SPHPOS+ARRBIT,0			;↑A
	XWD	ALLSPA+SPACTN+ECHSUP+IMLCHR+ARRBIT,CONTB	;↑B FULTWX&HOLD SW
	XWD SPHPOS+ARRBIT,0			; β
	XWD SPHPOS+ARRBIT,0			;↑D EOT
	XWD SPHPOS+ARRBIT,0			;↑E WRU
	XWD SPHPOS+ARRBIT,0			;↑F
;	XWD	SPACTN+ECHSUP,CONTF		OLD ↑F FCS SW
	0					;↑G (BELL)
	XWD SPHPOS+ARRBIT,0			;↑H OR BACKSPACE KEY
	XWD	ALLSPA+SPACTN+SPHPOS+SPOUT+SPBKDS,CONTI	;↑I OR TAB
	XWD	BREAKB+SPBKDS,0			;↑J OR LINE FEED
	XWD	ALLSPA+SPACTN+SPOUT,CONTK	;↑K OR VERT TAB
	XWD	ALLSPA+SPACTN+SPOUT,CONTL	;↑L OR FORM FEED
	XWD	ALLSPA+SPACTN+SPHPOS+SPBKDS,CRLF;↑M OR CARRIAGE RETURN
	XWD	SPHPOS+ARRBIT,0			;↑N
	XWD	SPACTN+SPHPOS+ARRBIT,CONTO	;↑O SUPP OUTPUT
	XWD	SPHPOS+ARRBIT,0			;↑P
	XWD	SPHPOS+ARRBIT,0			;↑Q 
	XWD	SPHPOS+ARRBIT,0			;↑R
	XWD	SPHPOS+ARRBIT,0			;↑S
	XWD	SPHPOS+ARRBIT,0			;↑T
	XWD	SPACTN+ARRBIT,CONTU		;↑U DELETE LINE
	XWD	SPHPOS+ARRBIT,0			;↑V
	XWD	SPHPOS+ARRBIT,0			;↑W
	XWD	SPHPOS+ARRBIT,0			;↑X
	XWD	SPHPOS+ARRBIT,0			;↑Y
	XWD	ALLSPA+SPACTN+ECHSUP+IMLCHR+ARRBIT,CONTZ	;↑Z TTY EOF
	XWD	SPHPOS+ARRBIT,0			;ASCII 33 (OLD ALT-MODE)
	XWD	SPHPOS+ARRBIT,0			;ASCII 34
	XWD	SPHPOS+ARRBIT,0			;ASCII 35
	XWD	SPHPOS+ARRBIT,0			;ASCII 36
	XWD	SPHPOS+ARRBIT,0			;ASCII 37

SPC (" ","0"-1,0)
SPC ("0","9",<XWD NUMBER,0>)
SPC ("9"+1,"A"-1,0)
SPC ("A","Z",<XWD LETTER,0>)
SPC ("Z"+1,"a"-1,0)
SPC ("a","z",<XWD LETTER,0>)
SPC ("z"+1,174,0)

	XWD	ALLSPA+SPACTN+BREAKB+ECHSUP,ALTMOD	;OLD DEC ALTMODE 175
	0						;CLOSE CURLY BRACKET
	XWD	SPACTN+ECHSUP+FCSBRK+SPBKDS,RUBOUT	;177 RUBOUT

;CTLV1, TTYUUO, CLRBUF, INSKIP

↑CTLV1:	PUSHJ	P,TTYFNU		;HERE FOR THE CTLV UUO.  COMPLEMENT ECHO
	MOVEI	IOS,NOECHO
	XORM	IOS,DEVIOS(DDB)
	POPJ	P,


;TTYUUO - THE AC FIELD DETERMINES THE ACTION OF THE UUO

↑TTYUUO:CAIL	UCHN,TTUUOL		;TOO HIGH AC FIELD?
	POPJ	P,			;YES, NO-OP
	PUSHJ	P,TTYFNU
	HLRZ	TAC,TTUUOT(UCHN)	;GET BITS
	TLNE	IOS,TTYDTC
	TRNE	TAC,200000		;DO WE CALL ROUTINE IF DETACHED?
	CAIA				;YES
	POPJ	P,			;QUIT NOW
	SKIPG	TTUUOT(UCHN)		;IS IT AN INPUT TYPE ?
	PUSHJ	P,UNSUPR		;YES. TURN OFF CTRL. O.
	JRST	@TTUUOT(UCHN)		;DISPATCH TO UUO ROUTINES

DEFINE UUOS{FOR X IN(<INCHRW,600000>,<OUTCHR,,ONEOUT>,<INCHRS,600000>,<OUTSTR>
,<INCHWL,600000>,<INCHSL,600000>,GETLIN,<SETLIN>
,<RESCAN,,TRESCU>,<CLRBFI,,CLRBUF>,<CLRBFO,,SETBF3>,<INSKIP,600000>
,<INWAIT,600000,IWAIT>,SETACT,<TTREAD,200000>,OUTFIV)}

PSHSYS
LOSYS

UUOMAC TTUUOT,TTYUUO
TTUUOL←←UUOCNT

POPSYS

CLRBUF:	TLNE	IOS,TPMON		;NOT ALLOWED IN MONITOR MODE!
	POPJ	P,			;JUST RETURN
	TLNE	LINE,IMLIN
	JRST	IMLCLR
	PUSHJ	P,SETBFI		;CLEAR INPUT BUFFER
	TLNE	LINE,DDDLIN!DISLIN!DMLIN;THAT'S ALL FOR TTY'S
	SKIPL	TAC,LETAB(LINE)		;DOES HE HAVE A LINE EDITOR?
	POPJ	P,			;NO, DONE
	MOVEI	CHR,10044		;GET A CLEAR
	SETZ	UCHN,			;WITH NO BITS
	JRST	PTLL3			;AND SEND IT DOWN THE TUBES

IMLCLR:	MOVE	CHR,[ASCID/π/]		;TELL IMLAC TO CLEAR ITS BUFFER.
	PUSHJ	P,FIVOUT
	PUSHJ	P,SETBFI		;CLEAR OURS
	MOVSI	IOS,IMLTTY
	ANDCAB	IOS,DEVIOS(DDB)		;AND THE BUCKY-BIT KLUDGE.
	POPJ	P,

INSKIP:	TRNE	UUO,1
	SKIPLE	TISYNC(DDB)		;INSKIP 1 WAITS FOR A WHOLE LINE
	TLNE	IOS,TTYDTC!TPMON
	POPJ	P,
	MOVE	TAC,TIPUTR(DDB)
	CAME	TAC,TITAKR(DDB)		;ANY CHARS. IN INPUT BUFFER ?
	JRST	CPOPJ1			;YES. SKIP RETURN.
	TLNN	LINE,DDDLIN!DISLIN!DMLIN;THAT'S ALL UNLESS HE'S A DPY
	POPJ	P,
	SKIPGE	TAC,LETAB(LINE)		;ANYTHING IN LINE EDITOR?
	SKIPG	CCPOS(TAC)		;I.E., CURSOR NOT AT LEFT?
	POPJ	P,			;NO
	JRST	CPOPJ1			;YES, SKIP RETURN
;INCHSL, INCHRS, INCHWL, IWAIT, INCHGT, INCHGB
;INPUT A CHARACTER AND SKIP---IF NONE TYPED, DON'T SKIP

INCHSL:	SKIPLE	TISYNC(DDB)		;ANY LINES IN BUFFER?
INCHRS:	TLNE	IOS,TPMON
	POPJ	P,			;NOTHING TO SPEAK OF
	PUSHJ	P,INCHGT		;GET ANY CHRS. FROM LINE EDITOR.
	MOVEI	DAT,TTIBUF(DDB)		;GET A CHARACTER
	PUSHJ	P,GETCHY		;FROM TTI BUFFER
	PUSHJ	P,PTICHK		;WAKE UP PTY WAITERS, IF ANY.
	JUMPE	CHR,CPOPJ		;RETURN IF NULL (EMPTY BUFFER)
	CAIE	CHR,600
	JRST	INCHSY			;NOT ↑C
	MOVE	CHR,DEVMOD(DDB)
	TLNN	CHR,TTYATC		;IF ATTACHED TO JOB
	TRNN	CHR,ASSCON!ASSPRG	;OR NOT ASSIGNED OR INITED
	JRST	MONUS6			;THEN PROCESS ↑C
INCHSY:	XCTR	XW,[MOVEM CHR,(UUO)]	;MOVE INTO LOC. SPECIFIED BY UUO
	JRST	CPOPJ1			;AND SKIP RETURN

;INPUT CHARACTER AND WAIT, LINE MODE

INCHWL:	PUSHJ	P,INCHSL		;SEE IF ANY CHARS.
	JRST	.+2			;NO
	POPJ	P,			;YES. GIVE IT TO USER
	TLNE	LINE,IMLIN		;IMLACS HAVE A COMMAND - BO
	TLNN	LINE,SPCBRK		;IMLAC: SPECIAL ACTIVATION MODE?
	JRST	IMCHW0			;NOT IMLAC OR NOT SPECIAL ACTIVATION
	MOVE	CHR,[ASCID/α/]		;YES.  TELL IT WE'RE WAITING.
	PUSHJ	P,FIVOUT
IMCHW0:	MOVE	IOS,[TTYIOW,,IOACT]	;NONE. WAIT FOR IT
	IORM	IOS,DEVIOS(DDB)		;TTY TO IOW STATE
	MOVSI	IOS,DDTM		;JUST IN CASE
	ANDCAB	IOS,DEVIOS(DDB)		;CLEAR DDTMODE BREAK FLAG
	PUSHJ	P,TWSYNC		;WAIT FOR CHAR (INTPTI IF APPROPRIATE).
	PUSHJ	P,INCHSL		;REPEATED TESTING HERE SO
	JRST	IMCHW0			;IMLACS ONLY GET THE WORD-MODE
	POPJ	P,			;COMMAND ONCE.

IWAIT0:	MOVE	IOS,[TTYIOW,,IOACT]
	IORM	IOS,DEVIOS(DDB)
	MOVSI	IOS,DDTM
	ANDCAB	IOS,DEVIOS(DDB)
	PUSHJ	P,TWSYNC
IWAIT:	LDB	CHR,PLASTC		;GET LENGTH OF LAST RE-EDITED LINE.
	TRNE	UUO,-1			;IS ADDRESS OF IWAIT 0 ?
	XCTR	XW,[MOVMM CHR,(UUO)]	;NO. USER WANTS GOOD NUMBER.
	SKIPLE	TISYNC(DDB)		;IS THERE A LINE PRESENT ?
	TLNE	IOS,TPMON		;NOTHING IN MONITOR MODE
	JRST	IWAIT0
	POPJ	P,

INCHGT:	TLNN	LINE,DISLIN!DDDLIN!DMLIN	;ONLY DPY'S
	POPJ	P,
	MOVE	TAC,TITAKR(DDB)		;WILL HE GET A CHAR WITHOUT
	CAME	TAC,TIPUTR(DDB)		; ACTIVATING THE LINE EDITOR?
	POPJ	P,			;YES
INCHGB:	SKIPGE	TAC,LETAB(LINE)		;ANYTHING IN LINE EDITOR?
	SKIPG	CCPOS(TAC)		;IS POINTER INTO LINE?
	POPJ	P,			;NO
	JRST	LACTIV			;WILL TRANSFER SOME RIGHT NOW!
					;IF THERE ARE ANY!
;INCHRW, ONEOUT, GETLIN, SETLIN, SYNCHK, SYNCHA, SETACT
;MORE ROUTINES CALLED BY TTY UUO DISPATCHER

;INCHRW GOES INTO I/O WAIT IF NO CHARACTER HAS BEEN TYPED--NO SKIPS

INCHRW:	PUSHJ	P,INCHRS		;GET A CHAR IF ONE IS THERE
	JRST	.+2			;NONE THERE
	POPJ	P,			;CHAR PICKED UP AND STORED
	TLNE	LINE,IMLIN		;BY BO - IMLACS HAVE FANCY
	JRST	IMCHRW			; COMMAND FOR THIS.
IMCHR0:	MOVE	IOS,[TTYIOW+DDTM,,IOACT];SETUP FOR IOWAITM
	IORB	IOS,DEVIOS(DDB)		;SPECIFICALLY FOR INPUT WAIT
	PUSHJ	P,TWSYNC		;WAIT FOR CHAR TO BE TYPED
	JRST	INCHRW			;GO GET IT

IMCHRW:	MOVE	CHR,[ASCID/↓/]		;IMLAC COMMAND: SEND ONE CHAR
	PUSHJ	P,FIVOUT
	JRST	IMCHR0

;ONEOUT OUTPUTS ONE CHARACTER

ONEOUT:	XCTR	XR,[MOVE CHR,(UUO)]	;PICK UP CHAR FROM USER
	TRNE	IOS,IOSUPR		;IF ↑O MODE
	POPJ	P,			;RETURN
	ANDI	CHR,177			;MASK ANY JUNK
	JUMPE	CHR,CPOPJ		;DON'T STORE NULLS
	PUSHJ	P,OUTCHR		;PLACE IT IN TTO BUFFER
	JUMPN	CHR,TYPGO		;IF IT STORED, RETURN
	PUSHJ	P,TTOUWS		;BUFFER WAS FULL. TRY AGAIN LATER
	JRST	ONEOUT

;GETLIN PUTS LINE CHARACTERISTICS WORD INTO ADR. IN UUO ADR. FIELD

GETLIN:	XCTR	XR,[SKIPGE TAC,(UUO)]	;DOES USER WANT OWN LINE CHAR WD.?
	JRST	GETLN1			;YES
	MOVEI	LINE,0			;NO, CHECK SIZE OF NUMBER
	CAIL	TAC,TTPLEN		;TOO HIGH?
	SOJA	LINE,GETLN3
	MOVE	LINE,LINTAB(TAC)	;NO, GET IT
	HRRI	LINE,(TAC)
GETLN1:	MOVE	TAC,LINE		;START WITH THIS LINE
	JRST	GETLN5			;JUMP IN

GETLN2:	TLNN	TAC,PTYLIN		;IS THIS A PTY?
	JRST	GETLN4			;NO
	MOVE	TAC,PTYJOB-PTYL0(TAC)	;OWNER OF THIS PTY
	MOVE	TAC,JBTLIN(TAC)		;HIS LINE CHARACTERISTICS
GETLN5:	CAME	TAC,[-1]		;THAT'S ALL IF WE FIND A DETACHED LINE
	JRST	GETLN2			;DOWN THE CHAIN
	JRST	GETLN3

GETLN4:	AND	TAC,[XWD DISLIN!DDDLIN!DMDLIN,0];COPY THESE BITS INTO
	TDO	LINE,TAC			; LINE BITS, IN CASE WE ARE A PTY
GETLN3:	XCTR	XW,[MOVEM LINE,(UUO)]		;GIVE IT TO USER
	POPJ	P,

;ROUTINE TO SET LINE CHARACTERISTICS THAT ARE SETABLE

SETLIN:	MOVSI	TAC,LGLSET&¬IMPBIT	;MASK FOR ALL SETTABLE BITS
	TLNE	LINE,IMPBIT		;IS THIS AN IMP?
	JRST	SETLN1			;YES.  FOR IMPS, TBXPND MAY BE SET.
	TLNE	LINE,DISLIN!DDDLIN!DMLIN!PTYLIN!IMLIN
	TLZ	TAC,TBXPND
SETLN1:	ANDCAM	TAC,LINTAB(LINE)	;SHUT OFF ALL SETABLE BITS
	TLO	TAC,IMPBIT		;THIS CAN BE TURNED ON BUT NOT OFF
	XCTR	XR,[AND TAC,(UUO)]	;SET ONLY THOSE BITS USER WANTS SET
	IORB	TAC,LINTAB(LINE)	;SET RESULTANT
	HLL	LINE,TAC		;NEW BITS TO LINE
SYNCHK:	MOVE	AC1,TITCTR(DDB)		;PREPARE TO SIMULATE GETCHY
	MOVE	AC2,TITAKR(DDB)	
	MOVEI	AC3,1			;ONE FOR FIRST CHAR
	SETZM	TISYNC(DDB)		;IN CASE BUFFER EMPTY
SYNCH2:	CAMN	AC1,TIPCTR(DDB)		;IS THIS THE END?
	POPJ	P,			;YES, LEAVE
	SOJG	AC1,SYNCH3		;TEST FOR WRAP AROUND
	HRR	AC2,TTIBUF(DDB)		;RESET BYTE POINTER
	HLRZ	AC1,TTIBUF(DDB)		;AND TAKR COUNTER
SYNCH3:	ILDB	CHR,AC2			;PICK UP CHAR!
	TLNE	IOS,TPMON		;MONITOR DOESN'T GET ANY OF THIS
	JRST	SYNCH5
	TLNN	LINE,SPCBRK		;ARE WE SPECIALLY ACTIVATING
	JRST	SYNCH1			;NO
	LDB	UCHN,[POINT 2,CHR,28]
	PUSHJ	P,SPCACT
	JRST	SYNCH4
	AOJA	AC3,SYNCH2

SYNCH1:	TRNE	CHR,600			;CONTROL BITS?
	JRST	SYNCH4			;YES, ACTIVATE THESE SO FAR
SYNCH5:	PUSHJ	P,SPCHEK
	AOJA	AC3,SYNCH2
	TLNE	TAC,BREAKB!FCSBRK	;BREAK CHARACTER?
SYNCH4:	MOVEM	AC3,TISYNC(DDB)		;UPDATE TISYNC WITH # OF CHARS SCANNED SO FAR
	AOJA	AC3,SYNCH2

SYNCHA:	MOVN	AC1,FCTR(DAT)		;UNUSED SPACE IN BUFFER.
	ADDI	AC1,TTICHR		;SIZE OF BUFFER
	MOVEM	AC1,TSYNC(DAT)		;SET TISYNC
	POPJ	P,


;SETACT		SET A BREAK TABLE
;CALL
;TTYUUO 15,ADDR
;RIGHT HALF CONTAINS ADDRESS OF TABLE TO BE BLT'ED IN (NO NEW TABLE IF 0)
;LEFT HALF CONTAINS ADDRESS OF WHERE TO STORE COPY OF OLD TABLE (NO STORE IF 0)

SETACT:	XCTR	XR,[MOVS TAC,(UUO)]	;GET POINTER WORD
	TRNN	TAC,-1
	JRST	STACT1			;HE DOESN'T WANT TO KNOW WHAT HE HAD
	MOVE	TAC1,ACTBTS(DDB)	;GIVE HIM A COPY OF THE TABLE
	XCTR	XW,[MOVEM TAC1,(TAC)]
	MOVE	TAC1,ACTBTS+1(DDB)
	XCTR	XW,[MOVEM TAC1,1(TAC)]
	MOVE	TAC1,ACTBTS+2(DDB)
	XCTR	XW,[MOVEM TAC1,2(TAC)]
	MOVE	TAC1,ACTMOD(DDB)
	XCTR	XW,[MOVEM TAC1,3(TAC)]
STACT1:	HLRZ	TAC1,TAC
	JUMPE	TAC1,CPOPJ
	XCTR	XR,[MOVE TAC,(TAC1)]	;GET HIS NEW TABLE
	MOVEM	TAC,ACTBTS(DDB)
	XCTR	XR,[MOVE TAC,1(TAC1)]
	MOVEM	TAC,ACTBTS+1(DDB)
	XCTR	XR,[MOVE TAC,2(TAC1)]
	MOVEM	TAC,ACTBTS+2(DDB)
	XCTR	XR,[MOVE TAC,3(TAC1)]
	MOVEM	TAC,ACTMOD(DDB)
	POPJ	P,
;OUTFIV, FIVOUT

;FIVOUT		ADDED BY BO FOR GIVING COMMANDS TO IMLACS
;	TTYUUO 17,ADR
;ADR: 5 LEFT-JUSTIFIED ASCII CHARACTERS.
;PUTS THESE CHARACTERS, UP TO THE FIRST NULL, INTO THE OUTPUT BUFFER.
;IF BIT 35 IS A ONE, PREFIXES THESE CHARS WITH A RUBOUT.
;GUARANTEES THAT THESE CHARS WILL BE SENT AS AN INDIVISIBLE BLOCK.

OUTFIV:	XCTR	XR,[MOVE CHR,(UUO)]	;TTYUUO 17 comes here,
	PUSHJ	P,FIVOUT		;other places in TTYSER go there.
	POPJ	P,

FIVOU2:	ONSCN				;TURN ON SCANNER CHANNEL
FIVOU1:	PUSHJ	P,TTOUWS		;Not enough room in buffer, so wait.
	CAIA
FIVOUT:	PUSH	P,CHR			;Make a temp cell for the data.
	MOVEI	AC3,6			;Check for enough buffer space.
	CAML	AC3,TOFCTR(DDB)
	JRST	FIVOU1
	OFFSCN				;TURN OFF SCANNER CHANNEL
	TLNE	IOS,TTYDTC		;Detached output gets flushed...
	JRST	SCNONJ			;...Ch. 5 back on.
	CAML	AC3,TOFCTR(DDB)		;Check again for room, this time with
	JRST	FIVOU2			;the interrupt disabled.
	PUSHJ	P,UNSUPR		;You can't ↑O a command by God!
	MOVSI	TAC,(<POINT 7,(P),-1>)	;Byte pointer into data.
	TRNN	CHR,1			;If bit 35 is on,
	JRST	FIVOU3
	MOVEI	CHR,177			;give out with a rubout.
	PUSHJ	P,PUTCHO
FIVOU3:	ILDB	CHR,TAC			;Fetch next char,
	JUMPE	CHR,FIVOU4		;terminate on a null.
	PUSHJ	P,PUTCHO		;Stuff into buff.
	TLNE	TAC,760000		;5th chr in wrd?
	JRST	FIVOU3			;No.  Do it again.
FIVOU4:	ONSCN				;TURN ON SCANNER CHANNEL
	POP	P,(P)			;Chan. 5 is back, so is the stack.
	JRST	TYPGO
;TTYMES	NULMES
;A UUO TO SEND A MESSAGE TO ANOTHER TTY
;NULMES VERSION ALLOWS NULLS EMBEDDED IN MESSAGE TEXT
;  COUNT MUST BE NONZERO AND INCLUDES SKIPPED ZERO BYTES
;  NULMES ALSO SETS AC TO THE UNUSED COUNT IN CASE OF FAILURE

↑NULMES:XCTR	XW,[SETOM JOBTM3]	;BH 3/12/75 NULMES UUO
	XCTR	XW,[SETOM JOBTM2]	;THIS RETURNS ZERO ON EARLY ERROR
	XCTR	XW,[MOVEM UUO,JOBTM4]	;SAVE WHICH AC, FOR RESULT
	JRST	NULME1			;JOBTM3 IS FLAG FOR WHICH UUO

↑TTYMES:XCTR	XW,[SETZM JOBTM3]
NULME1:	MOVE	UUO,TAC			;SAVE POINTER
	XCTR	XR,[MOVE TAC,(UUO)]	;PICK UP TTYNN OR LINE NUMBER
	TLNN	TAC,770000		;IS IT SIXBIT
	JRST	TTYMS1			;NO
	CAMN	TAC,['TTY   ']		;GETTING HIS OWN?
	JRST	TTYMS7			;YES
	PUSHJ	P,GETDDB		;FIND DDB FOR IT BY SIXBIT TTY NAME
	JRST	NULME5			;EARLY LOSSAGE EXIT
	JRST	TTYMS0

TTYMS7:	PUSHJ	P,TTYFND		;GET HIS TTY
	MOVE	IOS,DEVIOS(DDB)
	TDNE	IOS,[TTYDTC,,IOSUPR]	;EASY IF DETACHED OR SUPPRESSING OUTPUT
	JRST	CPOPJ1			;TELL HIM HE WON
	MOVNI	AC2,1			;FLAG TYPEOUT TO 'TTY' (DON'T USE DTYO)
	JRST	TTYMSA

TTYMS1:	MOVE	LINE,TAC		;FOR GETDBA
	PUSHJ	P,GETDBA		;FIND DDB BY TTY LINE NUMBER
	JRST	NULME5			;NO DDB OR ERROR
TTYMS0:	MOVEI	AC2,0			;FLAG TYPEOUT TO EXPLICIT TTY
TTYMSA:	XCTR	XR,[MOVE UUO,1(UUO)]	;PICK UP POINTER
	TLNN	UUO,770000		;ALREADY GOT P FIELD?
	TLO	UUO,440000		;NO, MAKE IT PICK UP FIRST BYTE OF WORD
	HLRZ	TAC,UUO
	ANDI	TAC,7777		;GET COUNT FIELD
	TLZ	UUO,7777
	TLO	UUO,700			;SET TO 7 BIT BYTES
	JUMPN	TAC,NULME2		;IS THERE A COUNT?
	XCTR	XR,[SKIPE JOBTM3]	;(BH 3/12/75 NULMES MUST HAVE COUNT)
	JRST	UUOERR
	MOVEI	TAC,777777		;NO, USE LARGE COUNT
NULME2:	XCTR	XW,[MOVEM TAC,JOBTM2]	;SAVE COUNT IN USER CORE
	MOVEI	DAT,TTOBUF(DDB)		;SET-UP DAT
	MOVE	IOS,DEVIOS(DDB)		;MAKE SURE IOS IS SET UP.
	AOS	(P)			;SKIP RETURN FROM HERE
	PUSHJ	P,STLNAC		;GET LINE CHARACTERISTICS. REG 7/20/73
	TLNE	LINE,CTYLIN		;IS THIS THE CTY THAT WE'RE TYPING ON?
	JRST	TTYMS9			;YES.  USE DISASTER SERVICE FOR CTY.
	JUMPN	AC2,TTYMS3		;DON'T USE DTYO FOR TYPEOUT TO 'TTY' (SELF)
	SKIPE	AC1,LETAB(LINE)		;;FIND DPY HEADER FOR THIS LINE (IF ANY)
	JRST	DPYMS1			;;DETERMINE IF P. OF P. 0 IS CURRENT
TTYMS3:	XCTR	XRW,[SOSL CHR,JOBTM2]	;COUNT OUT YET?
	XCTR	XLB,[ILDB CHR,UUO]	;NO. GET A CHAR.
	JUMPLE	CHR,NULME3		;QUIT ON NULL, OR COUNT EXHAUSTED.
	MOVNI	TAC,10			;TRY THIS MANY TIMES ON EACH CHAR.
	XCTR	XW,[MOVEM TAC,JOBTM1]
TTYMS4:	MOVE	IOS,DEVIOS(DDB)		;GET IOS
	TDNE	IOS,[XWD TTYDTC,IOSUPR]	;DID SOMETHING HAPPEN?
	POPJ	P,			;YES, FLUSH THE REST!
	PUSHJ	P,OUTCHR
	JUMPN	CHR,TTYMS3		;LOOP IF CHAR PLACED
	XCTR	XRW,[AOSLE JOBTM1]	;COUNT DOWN LOSSAGE
	JRST	TTYMS8			;COUNT OUT, LOSE ON THIS CHAR
	PUSHJ	P,TYPTST		;NO, TRY TO GET HIM GOING
	LDB	TAC,PJOBN		;PICK UP JOB NUMBER
	MOVE	J,JOB(PID)		;NEED THIS FOR SLEEP
	CAMN	TAC,J			;DIFFERENT?
	JRST	TTYMSW			;WAITING FOR OURSELVES IS SIMPLE
	MOVEI	TAC,20
	PUSHJ	P,SLEEPT		;SLEEP 20 TIC'S
TTYMSD:	PUSHJ	P,STLNAC		;SLEEP CLOBBERS THIS
	XCTR	XLB,[LDB CHR,UUO]	;GET CHAR. BACK
	JRST	TTYMS4			;TRY AGAIN

TTYMSW:	PUSHJ	P,DDTWAT
	JRST	TTYMSD

TTYMS8:	SOS	(P)			;HUNG TTY, GIVE LOSSAGE RETURN
NULME5:	XCTR	XR,[SKIPN JOBTM3]	;ENTER HERE FOR ERROR BEFORE AOS (P)
	POPJ	P,			;RETURN UNLESS NULMES
	XCTR	XRW,[AOS TAC,JOBTM2]	;GET UNUSED COUNT
	XCTR	XR,[MOVE UUO,JOBTM4]	;GET AC POINTER
	JRST	STOTAC			;TELL THE USER HOW BADLY HE LOST

;AT TTYMS9 FOR SPECIAL CASE OF TYPING ON CTY.

NULME4:	JUMPL	CHR,CPOPJ		;SAME AS NULME3 BUT FOR CTY OUTPUT
	XCTR	XR,[SKIPN JOBTM3]	;NULL BYTE, WHICH UUO?
	POPJ	P,			;TTYMES, QUIT
TTYMS9:	XCTR	XRW,[SOSL CHR,JOBTM2]	;COUNT OUT YET?
	XCTR	XLB,[ILDB CHR,UUO]	;NO. GET A CHAR.
	JUMPLE	CHR,NULME4		;QUIT ON NULL, OR NEGATIVE COUNT.
	PUSHJ	P,DISTYO		;SEND CHARACTERS VIA DISASTER SERVICE
	JRST	TTYMS9

NULME3:	JUMPL	CHR,TYPGO		;BH 3/12/75 ALWAYS QUIT WHEN COUNT DONE
	XCTR	XR,[SKIPN JOBTM3]	;NULL BYTE, WHICH UUO?
	JRST	TYPGO			;TTYMES, QUIT
	JRST	TTYMS3			;NULMES, SKIP THE BYTE

DPYMS1:	MOVE	AC2,CURPP(AC1)		;;GET POINTER TO CURRENT P. OF P.
	SKIPN	PPNO(AC2)		;;IF CURRENT P. OF P. IS 0
	JRST	TTYMS3			;THEN GO THRU OUTPUT BUFFER
	HLL	AC2,PPDPY(AC2)		;PICK UP DISPLAY-TYPE BIT
	SKIPE	DPHOLD(AC1)		;IF HOLDING, DON'T DO OUTPUT TO CURRENT PP
	SETZ	AC2,			;FLAG NO OUTPUT TO CURRENT PP
	PUSH	P,AC2			;SAVE POINTER TO CURRENT PP
	MOVS	DAT,PPCALL(AC1)		;GET POINTER TO P. OF P. 0
	HLL	DAT,PPDPY(DAT)		;PICK UP DISPLAY-TYPE BIT
	PUSH	P,DDB
	MOVE	DDB,AC1			;DTYO WANTS POINTER TO DPY HEADER IN DDB
	HLL	DDB,DAT			;PICK UP DISPLAY-TYPE BIT
DPYMS2:	XCTR	XRW,[SOSL CHR,JOBTM2]	;COUNT OUT YET?
	XCTR	XLB,[ILDB CHR,UUO]	;GET A CHAR
	JUMPLE	CHR,DPYNUL		;QUIT ON NULL OR COUNT EXHAUSTED
	OFFSCN				;TURN OFF SCANNER CHANNEL
	PUSHJ	P,DTYO			;OUTPUT CHR TO P. OF P. 0
	ONSCN				;TURN ON SCANNER CHANNEL
	EXCH	DAT,-1(P)
	JUMPE	DAT,DPYMS3		;NO OUTPUT TO CURRENT PP IF HOLDING
	XCTR	XLB,[LDB CHR,UUO]	;GET CHARACTER AGAIN (DTYO CLOBBERS IT)
	OFFSCN				;TURN OFF SCANNER CHANNEL
	PUSHJ	P,DTYO			;OUTPUT CHR TO CURRENT P. OF P.
	ONSCN				;TURN ON SCANNER CHANNEL
DPYMS3:	EXCH	DAT,-1(P)
	JRST	DPYMS2			;LOOP FOR ANOTHER CHR

DPYNUL:	JUMPL	CHR,DPYNU2		;ALWAYS QUIT WHEN COUNT DONE
	XCTR	XR,[SKIPE JOBTM3]	;NULL BYTE, WHICH UUO?
	JRST	DPYMS2			;NULMES, SKIP THE BYTE
DPYNU2:	POP	P,DDB			;RESTORE DDB POINTER
	POP	P,TAC			;CURRENT PP OR ZERO
	JUMPN	TAC,TYPGO		;UPDATE CURRENT PP DISPLAY IF NECESSARY
	POPJ	P,
;TTREAD, TTYJNO, TTYJOB
;READ MICROSWITCH KEYBOARD USING SPCWAR MODE FEATURE
;CALL
;	TTYUUO 16,ADDR
;WHERE ADDR CONTAINS LINE NUMBER YOU WISH TO READ
;IF LINE IS ILLEGAL YOURS IS USED
;IF IT IS NOT ON THE KEYBOARD SCANNER THIS IS A NO-OP
TTREAD:	XCTR	XR,[SKIPL TAC,(UUO)]	;PICK UP LINE HE WANTS
	CAIL	TAC,TTPLEN		;HIGHER THAN HIGHEST?
	HRRZ	TAC,LINE		;YES
	SUBI	TAC,DPYL0		;NORMALIZE IT
	JUMPL	TAC,CPOPJ		;NO-OP IF NOT ON KBD SCANNER
	CAIL	TAC,DPYNUM+DDNUM
	POPJ	P,
	TRO	TAC,100			;SET SPW BIT
	MOVEI	AC3,20			;TRY THIS MANY TIMES
TTRED1:	DATAO	DKB,TAC
	DATAI	DKB,AC1			;READ KBD
	TRNN	AC1,1B22		;SHOULD HAVE SPW BIT ON
	SOJG	AC3,TTRED1		;NO, TRY AGAIN
	HLRZ	AC2,AC1
	CAIE	AC2,-100(TAC)		;DID WE GET THE RIGHT LINE?
	SOJG	AC3,TTRED1		;NO
TTRED3:	XCTR	XW,[MOVEM AC1,(UUO)]	;STORE RESULT
	POPJ	P,

;TTYJOB
;CALL:
;	MOVEI AC,<LINE #>
;	TTYJOB AC,
;	<# OF JOB OWNING TTY IN AC>
;IF LINE # IS NOT TTY LINE, RETURN JOB CONTROLLING IF PTY
↑TTYJNO:XCTR	XR,[MOVE LINE,(UCHN)]	;GET ARG
	JUMPL	LINE,PTYJNO
	CAIGE	LINE,TTPLEN		;LEGAL TTY LINE #?
	SKIPN	DDB,TTYTAB(LINE)	;GET DDB POINTER
	JRST	TTYJN1			;NONE
	LDB	TAC,PJOBN		;GET JOB NUMBER
	JUMPE	TAC,TTYJN0		;JUMP IF TTY NOT IN USE
	MOVE	AC1,DEVMOD(DDB)		;CHECK IF CONTROLLING JOB
	TLNN	AC1,TTYATC		;JOBS CONSOLE?
	TLO	TAC,400000		;NO, SET BIT TO INDICATE JUST OWNED
	CAIA
TTYJN1:	SETZ	TAC,			;FLAG NO JOB
TTYJN0:	XCTR	XW,[MOVEM TAC,(UCHN)]	;STORE ANSWER
	POPJ	P,

PTYJNO:	MOVM	LINE,LINE
	CAIGE	LINE,TTPLEN
	CAIGE	LINE,PTYL0
	JRST	.+2
	JRST	PTYJN1
	HRRE	LINE,JBTLIN(J)		;JOBS TTY
	JUMPL	LINE,TTYJN1		;RETURN 0 IF NONE
PTYJN1:	HLL	LINE,LINTAB(LINE)	;GET LINE CHARACTERISTICS
	TLNN	LINE,PTYLIN		;IS IT A PTY?
	JRST	TTYJN1			;NO, NO CONTROLLING JOB
	MOVE	TAC,PTYJOB-PTYL0(LINE)	;CONTROLLING JOB
	JRST	TTYJN0
;SNEAKS, SNEAKW, ACTCHR
;TWO UUO'S TO SEE THE NEXT CHAR. YOU WILL INPUT.
;ONE (SNEAKS) WHICH SKIPS IF A CHAR IS WAITING
;THE OTHER (SNEAKW) WAITS FOR A CHAR.
;BOTH RETURN THE CHAR. IN THE AC.

;ENTER AT SNEAKS

SNEAKX:	PUSHJ	P,WSCHED		;WAIT ONE TIC
↑SNEAKS:PUSHJ	P,TTYFNU		;FIND USERS TTY
	TLNE	IOS,TPMON!TTYDTC	;DETACHED?
	POPJ	P,			;CAN'T GET ANYTHING IF DETACHED
	MOVE	AC2,TITAKR(DDB)
	CAME	AC2,TIPUTR(DDB)		;ANYTHING IN TTY BUFFER
	JRST	SNLOAD			;YES, RETURN IT
	TLNE	LINE,DISLIN!DDDLIN!DMLIN
	SKIPL	AC1,LETAB(LINE)
	POPJ	P,			;NOT DISPLAY, OR NOT ACTIVE
	TLNE	AC1,WTFLAG		;IF TRANSFER IN PROGRESS, LOSE
	JRST	SNEAKX			; BUT TRY AGAIN
	SKIPG	CCPOS(AC1)		;CAN WE GET ANYTHING
	POPJ	P,			;NO
	MOVE	AC2,[POINT 7,LEBUF]
	ADDI	AC2,(AC1)		;POINT TO BEGINNING OF USER EDITOR BUFFER
	ILDB	TAC,AC2
	JUMPE	TAC,.-1			;LOOP FOR CHAR.
SNLD1:	XCTR	XW,[MOVEM TAC,(UCHN)]	;STORE RESULT
	JRST	CPOPJ1			;RETURN

SNLOAD:	MOVE	TAC,TITCTR(DDB)
	CAIG	TAC,1
	HRR	AC2,TTIBUF+BUF(DDB)	;WRAP AROUND BUFFER
	ILDB	TAC,AC2
	JRST	SNLD1

;SNEAK WAIT - ENTER AT SNEAKW

SNEAKY:	MOVE	IOS,[TTYIOW!SNKWAT,,IOACT]
	IORB	IOS,DEVIOS(DDB)
	MOVSI	IOS,DDTM
	ANDCAB	IOS,DEVIOS(DDB)
	PUSHJ	P,TWSYNC		;WAIT FOR CHAR.
	PUSHJ	P,STXTM3		;CLEAR INTERACTION RUN TIME
↑SNEAKW:PUSHJ	P,SNEAKS
	JRST	SNEAKY			;WAIT FOR TYPEIN AND TRY AGAIN
	POPJ	P,			;SUCCESS

;WAITS FOR ACTIVATION AND RETURNS THE CHAR WHICH ACTIVATED IT BUT
;ONLY ON RE-EDITED LINES

↑ACTCHR:PUSHJ	P,TTYFNU		;FIND USER'S TTY
	CAME	LINE,[-1]		;DETACHED?
	TLNN	LINE,DDDLIN!DISLIN!DMDLIN;ONLY DPY'S HAVE ACT. CHAR.
	JRST	RTZERO			;RETURN 0 (UUO NOT CLOBBERED YET)
	MOVEI	UUO,0			;RPH & FW'S FAULT (NO STORE IN IWAIT)
	PUSHJ	P,IWAIT			;WAIT FOR A LINE
	MOVE	CHR,LETAB(LINE)
	LDB	CHR,[POINT 9,GWORD(CHR),35]
	XCTR	XW,[MOVEM CHR,(UCHN)]
	POPJ	P,
;DDTIN
IFN FTDDTM,<

;INPUT TO DDT
;CALL AC,[SIXBIT /DDTIN/]	AC CONTAINS POINTER TO BUFFER AREA
;BUFFER AREA MUST BE 21 WORDS LONG


↑DDTIN:	PUSHJ	P,TTYFNU		; SET UP DDB,LINE
DDTINA:	MOVE	IOS,[TTYIOW+DDTM,,IOACT]
	IORB	IOS,DEVIOS(DDB)		;PUT INTO I/O WAIT
	TLNN	IOS,TPMON		;NOTHING THERE IF TTY IS IN MONITOR MODE.
	JRST	DDTINB
	PUSHJ	P,TWSYNC		;WAIT FOR SOMETHING
	JRST	DDTINA

DDTINB:	TLNE	LINE,DDDLIN!DISLIN!DMLIN
	PUSHJ	P,INCHGB		;ACTIVATE LINE EDITOR, THEN WAIT ONE TIC IF NESCESARY.
	PUSHJ	P,PTICHK		;CHECK FOR PTY LINKAGE.
	MOVE	TAC,TIPUTR(DDB)
	CAMN	TAC,TITAKR(DDB)		;ANYTHING IN BUFFER?
	PUSHJ	P,TWSYNC		;NO, WAIT FOR SOME
DDTIW:	MOVE	IOS,[TTYIOW+DDTM,,IOACT]
	ANDCAB	IOS,DEVIOS(DDB)
	MOVSI	TAC,IOFST
	IORM	TAC,DEVIOS(DDB)		;STOP ALL IO
	MOVSI	AC2,440700
	XCTR	XR,[HRR AC2,(UUO)]	;GET CONTENTS OF USER AC = RELATIVE ADDR
	MOVE	LINE,TIPUTR(DDB)
	MOVEI	DAT,TTIBUF(DDB)
	MOVEI	AC1,<21*5>-1		;NUMBER OF CHARACTERS ALLOWED
XFRIN:	PUSHJ	P,GETCHY		;TRANSFER INTO USER'S AREA
XFRIN1:	CAIN	CHR,600			;PRESTORED CONTROL C?
	JRST	XFRIN0			;YES, GO INTO MONITOR MODE
	XCTR	XDB,[IDPB CHR,AC2]
	CAME	LINE,TITAKR(DDB)	;PICKED UP ALL CHARACTERS YET?
	SOJG	AC1,XFRIN		;LOOP TILL DONE
XFRIN2:	MOVEI	CHR,0			;TERMINATE STRING
	XCTR	XDB,[IDPB CHR,AC2]
UNSUPR:	MOVEI	IOS,IOSUPR		;MAKE SURE IO NO LONGER SUPR.
	ANDCAB	IOS,DEVIOS(DDB)
	POPJ	P,

XFRIN0:	MOVE	CHR,DEVMOD(DDB)		;GET SOME GOOD BITS
	TLNN	CHR,TTYATC
	TRNN	CHR,ASSCON!ASSPRG	;THESE GUYS CAN'T TYPE COMMANDS
	JRST	DDTCNC
	JRST	XFRIN

DDTCNC:	PUSHJ	P,STLNAC		;GET LINE CHARACTERISTICS
	PUSHJ	P,XFRIN2
	JRST	MONUS6			;GO PROCESS ↑C
>
;DDTOUT, DDTWAT, OUTSTR

IFN FTDDTM,<

;OUTPUT FROM DDT
;CALL AC,[SIXBIT /DDTOUT/]	;AC HAS POINTER TO DDT OUTPUT BUFFER

↑DDTOUT:PUSHJ	P,TTYFNU
	XCTR	XR,[MOVE UUO,(UUO)]	;UUO←CONTENTS OF USER'S AC=BUFFER ADDR.

>;IFN FTDDTM

OUTSTR:	HRLI	UUO,440700
DDT3:	MOVE	IOS,DEVIOS(DDB)		;GET IOS
	TDNE	IOS,[TTYDTC,,IOSUPR]	;DID SOMETHING HAPPEN?
	POPJ	P,			;YES, FLUSH THE REST!
	XCTR	XLB,[ILDB CHR,UUO]
	JUMPE	CHR,TYPGO		;DONE, START OUTPUT
	PUSHJ	P,OUTCHR		;PLACE CHAR IN OUTPUT BUFFER
	JUMPN	CHR,DDT3		;LOOP IF CHARACTER WAS PLACED
	ADD	UUO,[070000,,0]		;BACK UP POINTER
	PUSHJ	P,TYPGO
	PUSHJ	P,DDTWAT
	JRST	DDT3

↑DDTWAT:MOVEI	TAC,TTOCHR		;SPECIFY TO WAIT TILL BUFFER IS EMPTY
	DPB	TAC,PFITCH		;IF DDT TYPE-OUT IS TOO LONG
	MOVSI	TAC,TTYIOW
	ANDCAM	TAC,DEVIOS(DDB)		;MAKE US LOOK LIKE WE'RE IN OUTPUT WAIT
	MOVEI	IOS,IOACT		;WAIT UNTIL MONITOR BUFFER EMPTY
	IORB	IOS,DEVIOS(DDB)
	JRST	WSYNC
;SCNDSP TTYIN TWSYNC TTYSKP
;DEVICE DEPENDENT PART OF IO UUOS.

;DISPATCH TABLE

	JRST	TTYINI			;INITIALIZATION
	JRST	CPOPJ1			;HUNG TIMEOUT - DO NOTHING.
↑SCNDSP:JRST	TTYREL			;RELEASE
	JRST	OUT			;CLOSE
	JRST	TTYOUT			;OUTPUT
TTYIN:	MOVE	IOS,[TTYIOW,,IOACT]	;INPUT UUO - INDICATE INPUT WAIT
	IORB	IOS,DEVIOS(DDB)
	TLNE	IOS,TTYDTC
	JRST	TTYIN2			;TTY IS DETACHED.  WAIT FOR INPUT
	MOVSI	TAC,TTYATC
	TDNE	TAC,DEVMOD(DDB)		;SKIP IF TTY CONTROLLING A JOB
	TLNN	IOS,TPMON		;TTY ATTACHED TO JOB. SKIP IF MONITOR MODE
	JRST	TTYIN3
TTYIN2:	PUSHJ	P,TWSYNC
	JRST	TTYIN

TTYIN3:	PUSHJ	P,PTICHK		;CHECK PTY WAITERS.
	MOVSI	IOS,DDTM+TPMON
	ANDCAB	IOS,DEVIOS(DDB)
	PUSHJ	P,STLNAC		;GET LINE CHARACTERISTICS
TTYIN1:	SKIPG	TISYNC(DDB)		;SKIP IF THERE'S INPUT READY
	PUSHJ	P,TWSYNC		;WAIT FOR INPUT
	PUSHJ	P,MONUSR		;MOVE DATA FROM TTY BUFFER TO USER
	MOVE	IOS,[TTYIOW!DDTM,,IOSUPR!MERTPO!MERTP1!IOACT]
	ANDCAB	IOS,DEVIOS(DDB)
	POPJ	P,

;TTYSKP, SKIPS IF NEXT INPUT ON CHN WON'T HANG (MUST BE TTY)
;CALL:	CALL	CHAN,['TTYSKP']
;	<DEVICE ON CHANNEL ISN'T A TTY OR HASN'T ANY INPUT>
;	<NEXT INPUT WON'T HANG>

↑TTYSKP:CAMG	UCHN,USRHCU		;SKIP IF CHANNEL SPECIFIED IS OUT OF RANGE
	SKIPN	DDB,USRJDA(UCHN)	;IN RANGE.  SKIP IF THERE'S A DDB
	JRST	IOIERR			;IO TO UNASSIGNED CHANNEL
	MOVE	TAC,DEVMOD(DDB)
	TLNN	TAC,DVTTY		;IS IT A TTY?
	POPJ	P,			;NO, GIVE HANG RETURN
	MOVE	IOS,DEVIOS(DDB)
	TLNN	IOS,TTYDTC		;IF DETACHED, IT WILL HANG.
	SKIPG	TISYNC(DDB)		;SKIP IF THERE'S SOMETING IN THE BUFFER
	POPJ	P,			;WILL HANG
	TLNE	TAC,TTYATC		;IF NOT USER CONSOLE,
	TLNN	IOS,TPMON		;OR NOT IN MONITOR MODE
	AOS	(P)			;WON'T HANG
	POPJ	P,

;TWSYNC IS CALLED FOR INPUT IO WAIT

TWSYNC:	TLNN	LINE,PTYLIN		;IS IT A PTY?
	JRST	TWSYN1			;NO, JUST GO INTO WAIT
	PUSH	P,J
	MOVE	J,PTYJOB-PTYL0(LINE)
	MOVSI	AC1,INTPTI
	TDNE	AC1,JBTIEN(J)
	PUSHJ	P,TTINT
	POP	P,J
	MOVE	CHR,DEVIOS(DDB)
	TLNE	CHR,TTYIOW		;DON'T WAIT IF SOMETHING TYPED AT I-LEVEL
TWSYN1:	PUSHJ	P,WSYNC			;WAIT FOR INPUT
	MOVE	IOS,[TTYIOW+DDTM,,IOACT]
	ANDCAB	IOS,DEVIOS(DDB)
	POPJ	P,
;MONUSR
;ROUTINE TO MOVE A LINE OR STRING FROM TTY INPUT BUFFER TO USER'S INPUT BUFFER
;CALLED ONLY FROM UUO LEVEL,FROM INPUT UUO ONLY

MONUS8:	TLNE	IOS,IOEND		;ROOM FOR ANOTHER BUFFER. ↑Z SEEN?
	POPJ	P,			;↑Z SEEN.
MONUSR:	HRRZ	TAC,DEVIAD(DDB)		;ADDRESS OF BUFFER IN USER AREA
	PUSHJ	P,BUFCLR		;CLEAR BUFFER. (MAY CALL UADRER)
	PUSHJ	P,STLNAC		;SETUP LINE
	MOVEI	AC2,TTICHR		;MAX NUMBER OF CHARACTERS
	HRRZ	AC1,DEVIAD(DDB)		;ADDRESS OF USR BUFFER-1
	ADD	AC1,[10700,,1]		;MAKE BYTE POINTER POINT RIGHT
	MOVEI	DAT,TTIBUF(DDB)		;SPECIFY USER MODE INPUT BUFFER
MONUS1:	PUSHJ	P,GETCHY		;GET A CHAR. FROM IT
	LDB	TAC,[POINT 7,CHR,35]	;NO CTRL BITS
	MOVE	TAC,SPCTAB(TAC)		;GET GOOD BITS
	JUMPE	CHR,MONUS3		;ZERO IMPLIES EMPTY BUFFER
	CAIE	CHR,612			;END OF FILE? CONTROL-META-LF (OR ↑Z)
	JRST	MONUS9			;NOT EOF.
	MOVSI	IOS,IOEND		;SIGNIFY EOF.
	IORB	IOS,DEVIOS(DDB)
	JRST	MONUS3

MONUS9:	XCTR	XDB,[IDPB CHR,AC1]	;PLACE CHAR. IN USER BUFFER
	TLNN	TAC,FCSBRK!BREAKB	;IS IT A SYNC CHAR. ?
MONUS2:	SOJG	AC2,MONUS1		;NO, USER BUFFER FULL?
	CAIE	CHR,600			;STORED CONTROL C?
	JRST	MONUS3			;NO.
	MOVE	CHR,DEVMOD(DDB)		;HANDLE ↑C. 
	TLNN	CHR,TTYATC		;SKIP IF THIS TTY CONTROLS A JOB
	TRNN	CHR,ASSCON!ASSPRG	;TTYS USED AS IO DEVICE CAN'T ↑C
	JRST	MONUS7			;THIS IS REAL ↑C
MONUS3:	HRRZ	AC2,DEVIAD(DDB)		;BREAK CHAR OR COUNTED OUT, INPUT UUO DONE
	SUBI	AC1,1(AC2)		;CALCULATE NUMBER OF WORDS
	XCTR	XRW,[HRRM AC1,1(AC2)]	;STORE IN COUNT WORD OF BUFFER.
	PUSHJ	P,ADVBFF		;INPUT UUO DONE,NEXT BUFFER FULL?
	JRST	MONUS5			;YES, INPUT REALLY IS DONE
	JUMPG	AC2,MONUS5		;IF WE GAVE HIM A WHOLE LINE THEN WE ARE DONE.
	SKIPLE	TISYNC(DDB)		;NO, DO WE HAVE MORE LINES FOR IT?
	JRST	MONUS8			;YES, GIVE USER NEXT LINE, TOO
MONUS5:	MOVSI	IOS,IOFST
	IORB	IOS,DEVIOS(DDB)
	TLZE	IOS,TTYIOW		;TTY IN INPUT WAIT?
	PUSHJ	P,SETIOD		;YES, TAKE IT OUT OF IT
	POPJ	P,

MONUS6:	PUSHJ	P,CNCMOD		;CONTROL C MODE
	MOVSI	TAC,110000		;DECREMENT TAKR POINTER
	ADDM	TAC,TITAKR(DDB)		;SO NEXT ILDB WILL GET ↑C
	AOS	TITCTR(DDB)		;ADJUST COUNTER
	SOS	TIFCTR(DDB)		;ADJUST FREE CHAR. COUNT
	PUSHJ	P,SYNCHK		;FIX UP ACTIVATED COUNT
	PUSHJ	P,COMSET		;WAKE UP COMMAND DECODER
	JRST	WSYNC			;AND WAIT FOR INTERPRETATION

MONUS7:	MOVE	IOS,[TTYIOW,,IOACT]	;THIS IS A ↑C
	IORB	IOS,DEVIOS(DDB)		;PUT JOB BACK IN IOWAIT
	PUSHJ	P,MONUS6
	JRST	TTYIN			;RESTART INPUT UUO
;TTYOUT	- OUTPUT UUO

TTYOUT:	MOVSI	IOS,IOBEG
	TDNE	IOS,DEVIOS(DDB)
	TRO	IOS,IOSUPR		;KILL ↑O ON FIRST OUTPUT
	IOR	IOS,[DDTM,,MERTPO!MERTP1!IOACT]
	ANDCAM	IOS,DEVIOS(DDB)
	MOVSI	IOS,IO+IOFST
	IORB	IOS,DEVIOS(DDB)
	TLNN	IOS,TTYDTC
	PUSHJ	P,STLNAC		;GET LINE CHARACTERISTICS
	PUSH	P,LINE			;SAVE INFO
	TDNN	IOS,[TTYDTC,,IOSUPR]	;SKIP IF ↑O OR DETACHED
	PUSHJ	P,USRMON		;NO, MOVE USER'S BUFFER TO TTO BUFFER
	PUSHJ	P,ADVBFE		;ADVANCE USER'S HEADERS
	SKIPA
	TDZA	IOS,IOS			;MORE BUFFERS. DON'T CLEAR IOACT.
	MOVEI	IOS,IOACT		;NO MORE BUFFERS
	ANDCAB	IOS,DEVIOS(DDB)		;CLEAR ACTIVE IN IOS
	POP	P,LINE			;RESTORE LINE INFO
	PUSHJ	P,TYPGO			;START OUTPUT, IF NECESSARY.
	TRNE	IOS,IOACT		;ARE WE DONE ?
	JRST	TTYOUT			;NO.  DO SOME MORE. 
	POPJ	P,
;USRMON, TTOUWS

;MOVE USER OUTPUT BUFFER TO MONITOR BUUFER IN TTY DDB
;CALLED ONLY AT UUO LEVEL,BY OUTPUT UUO

USRMON:	HRRZ	AC2,DEVOAD(DDB)		;ADDRESS OF 2ND BUFFER WORD
	XCTR	XR,[HRRZ AC2,1(AC2)]	;NUMBER OF WORDS TO OUTPUT
	IMULI	AC2,5			;NUMBER OF CHARACTERS
	HRRZ	AC1,DEVOAD(DDB)		;ADDRESS OF BUFFER
	ADD	AC1,[10700,,1]		;MAKE POINTER.
USRMN2:	XCTR	XLB,[ILDB CHR,AC1]	;PICK UP CHARACTER
USRMN4:	JUMPE	CHR,USRMN5		;IF NULL, IGNORE
	PUSHJ	P,OUTCHR		;PLACE IN OUTPUT BUFFER
	JUMPE	CHR,USRMN3		;IF NO MORE ROOM IN MON. BUFFER
USRMN5:	SOJG	AC2,USRMN2		;LOOP AS LONG AS THERE ARE CHAR'S.
	DPB	AC2,PFITCH		;NO CHARACTERS TO FIT
	POPJ	P,			;DONE

USRMN3:	PUSH	P,AC2			;HERE WE RAN OUT OF ROOM IN DDB.
	CAILE	AC2,777			;GREATER THAN MAX? (9 BIT FIELD)
	MOVEI	AC2,777			;YES, USE MAX
	DPB	AC2,PFITCH		;NUMBER OF CHARACTERS TO GO
	PUSH	P,AC1			;SAVE RELOCATABLE POINTER
	MOVE	LINE,-3(P)		;GET SAVED LINE CHAR WORD
	PUSHJ	P,TTOUWS		;WAIT FOR IO
	POP	P,AC1			;RESTORE POINTER
	POP	P,AC2			;GET BACK CHR COUNT
	MOVE	IOS,DEVIOS(DDB)		;RESTORE IOS
	XCTR	XLB,[LDB CHR,AC1]	;GET LAST CHARACTER
	TRNN	IOS,IOSUPR		;USER TYPED ↑O?
	JRST	USRMN4			;RETURN TO OUT LOOP
	POPJ	P,			;YES, CONSIDER BUFFER MOVED

TTOUWS:	MOVEI	IOS,IOACT		;SET DEVICE ACTIVE (TTY)
	IORB	IOS,DEVIOS(DDB)
	PUSHJ	P,TYPGO			;START TYPING IF NEEDED
	JRST	WSYNC			;WAIT TILL ROOM IN BUFFER
;OLD III KEYBOARD STUFF  -  KBDINT, SHFTBL, CONVTB

IFN FTOIKB,<				;OLD III KEYBOARD CODE
↑KBDINT:JSR	SCNSAV			;SAVE AC'S, SET UP P
	DATAI	KBD,CHR
	LDB	LINE,[POINT 4,CHR,17]
	LDB	UCHN,[POINT 2,CHR,9]	;GET CONTROL BITS.
	TLZ	CHR,777577
	CAIN	CHR,2			;CHECK FOR LOST CHR
	POPJ	P,
	ADDI	LINE,DPYL0
	CAIN	CHR,1			;USE BLANK KEY FOR ALTMODE
	MOVEI	CHR,174
	CAIN	CHR,177			;IS IT A BACKSPACE ?
	MOVEI	CHR,136			;YES. PRETEND HARDWARE CODE IS 136.
	HRRZ	DSER,CHR		;PRESERVE UNSHIFTED CHAR.
	TLZE	CHR,200
	HRRZ	CHR,SHFTBL(CHR)
	HRRZ	CHR,CONVTB(CHR)
	CAIE	CHR,600
	DPB	UCHN,[POINT 2,CHR,28]	;PUT IN THE CTRL. BITS.
KBDIN1:	CAIN	CHR,213			;<CTRL1>VT?
	MOVEI	CHR,10042
	CAIN	CHR,212			;<CTRL1>LF?
	MOVEI	CHR,10044
	CAIN	CHR,412			;<CTRL2>LF?
	MOVEI	CHR,10000		;PATCH FOR ↑O
	JRST	RECINA

SHFTBL:	0↔ 174 ↔0↔0↔22↔177↔0↔0
	0↔11↔12↔13↔14↔15↔0↔0
	0↔20↔0↔0↔0↔0↔24↔0
	32↔0↔0↔0↔0↔0↔0↔23
	40↔1↔0↔0↔0↔0↔0↔0
	173↔175↔0↔176↔77↔25↔46↔17
	2↔3↔6↔7↔10↔44↔52↔100
	42↔47↔33↔134↔34↔36↔35↔0
	REPEAT 30,<0>	;100-127
	0↔0↔0↔31↔16↔27↔136↔43
	45			;140
XXZ←←101
	REPEAT 32,<XXZ
XXZ←←XXZ+1>
	0↔174↔0↔0↔136

↑CONVTB:	XWD 0,600
	XXZ←←1
	REPEAT 27,<XWD XXZ,XXZ
	XXZ←←XXZ+1>
	XWD 137,137
	XWD 31,31
	XWD 134,136
	XXZ←←33
	REPEAT 45,<XWD XXZ,XXZ
	XXZ←←XXZ+1>
	XWD 140,140
	XXZ←←101
	REPEAT 33,<XWD XXZ,XXZ
	XXZ←←XXZ+1>
	XWD 177,32	;134
	XWD 135,135
	XWD 32,177	;136 IS HARDWARE FORM OF DELETE THESE DAYS.
	XWD 30,30
	XWD 100,100
	XXZ←←141
	REPEAT 33,<XWD XXZ,XXZ
	XXZ←←XXZ+1>
	XWD 176,175	;174 IS HARDWARE ALTMODE.
	XWD 174,176	; 
	XWD 175,174
	XWD 136,134	

>;IFN FTOIKB
;DKBINT - MICROSWITCH KEYBOARD SCANNER INTERRUPT SERVICE.

↑DKBINT:MOVEM	CHR,DKBCHR	;SAVE ONE AC WHILE WE THINK ABOUT THIS CHAR
	DATAI	DKB,CHR
	TRNE	CHR,1B23	;INVALID?
	TRNE	CHR,1B22	;SPW?
	JRST	DKBLUZ		;IGNORE
	EXCH	CHR,DKBCHR	;STORE CHARACTER WHERE WE'LL SEE IT LATER
	JSR	SCNSAV

IFN FTHG,<	PUSHJ	P,HG	>

NOKL10,<	DATAI	APR,CHR
		JUMPGE	CHR,.+2
		DATAO	PI,DKBCHR	;DISPLAY IN LIGHTS IF DATA SWITCH 0 SET
>;NOKL10

	MOVE	CHR,DKBCHR	;GET BACK CHAR
	HLRZ	LINE,CHR
	CAIL	LINE,DPYNUM+DDNUM
	POPJ	P,		;IMPOSSIBLE LINE NUMBER
	ADDI	LINE,DPYL0	;OFFSET TO ORIGIN OF DPYS AND DDS

IFN FTTKKB,<	CAMN	LINE,TKKBLN
		JRST	TKKBCV		;CONVERT TK KBD CODES >

	ANDI	CHR,1777		;MASK UNWANTED BITS
	TRC	CHR,1700		;MAKE SENSE OF THESE BITS RIGHT
TKKBRT:	MOVEI	AC2,(CHR)		
	LDB	TAC,[POINT 2,CHR,29]	;SHIFT-TOP
	LDB	UCHN,[POINT 2,CHR,27]	;CTRL-META
	ANDI	CHR,77			;JUST THESE FOR INDEX
	CAIE	CHR,41			;BREAK?
	CAIN	CHR,42			;ESCAPE?
	JRST	DKBSPC			;SPECIAL CHARACTER
	CAIN	CHR,44			;CLEAR?
	JRST	DKBSPC
	LDB	DAT,DKBBYT(TAC)
	ANDCMI	TAC,1			;TOP ONLY
	LDB	DSER,DKBBYT(TAC)	;UNSHIFTED CHAR.
	MOVEI	CHR,(DAT)		;GET BACK SAVED CHAR.
	CAIE	CHR,600			;EXCEPT FOR ↑C
	DPB	UCHN,[POINT 2,CHR,28]	;GET BACK CONTROL BITS
	TRZA	DSER,600		;NO CONTROL BITS HERE
DKBSPC:	TRO	CHR,10000		;MAKE IT SPECIAL
	JRST	RECINA

DKBLUZ:	EXCH	CHR,DKBCHR	;RESTORE CHR, LEAVE CHARACTER WHERE WE CAN SEE IT

NOKL10,<DATAO	PI,DKBCHR >	;DISPLAY LOSING LINE NUMBER (AND CHAR) IN LITES

	JRST	12,@CH5		;DISMISS INTERRUPT


DKBBYT:	POINT 9,DKBTBL(CHR),8
	POINT 9,DKBTBL(CHR),17
	POINT 9,DKBTBL(CHR),26
	POINT 9,DKBTBL(CHR),35
;DKBTBL
DEFINE DKBCHR(A,B)<
BYTE(9)<"A">+40,<"A">,<"B">,<"B">
>


;FORMAT IS   BYTE(9)CHAR	SHIFT CHAR	TOP CHAR	TOP SHIFT CHAR

DKBTBL:	0
	DKBCHR	A,≤
	DKBCHR	B,π
	DKBCHR	C,ε
	BYTE(9)	"d","D",74,74
	BYTE(9)	"e","E",100,100
	BYTE(9)	"f","F",76,76
	DKBCHR	G,≠
	DKBCHR	H,=
	DKBCHR	I,'
	BYTE(9)	"j","J",137,137
	DKBCHR	K,<→>
	DKBCHR	L,<↔>
	DKBCHR	M,∃
	DKBCHR	N,∀
	BYTE(9)	"o","O",173,173
	BYTE(9)	"p","P",176,176
	DKBCHR	Q,∧
	DKBCHR	R,#
	DKBCHR	S,≥
	DKBCHR	T,&
	BYTE(9)	"u","U",140,140
	DKBCHR	V,λ
	DKBCHR	W,∨
	DKBCHR	X,β
	BYTE(9)	<"y">,<"Y">,42,42
	DKBCHR	Z,α

DEFINE DKBCHR(A,B)<
BYTE(9)<"A">,<"A">,<"B">,<"B">
>

	BYTE(9)	15,15,15,15
	DKBCHR	<\>,∞
	BYTE(9)	12,12,12,12
	0					;36
	0					;37 PROG SEL
	BYTE(9)	40,40,40,40			;40
	0					;41 BREAK
	0					;42 ESC
	BYTE(9)	600,600,600,600			;43 ↑C
	0					;44 CLEAR
	BYTE(9)	11,11,11,11
	BYTE(9)	14,14,14,14
	BYTE(9)	13,13,13,13
	DKBCHR	<(>,[
	DKBCHR	<)>,<]>
	DKBCHR	*,⊗
	DKBCHR	+,|
	DKBCHR	<,>,!
	DKBCHR	-,¬
	DKBCHR	.,?
	DKBCHR	/,∂
	DKBCHR	0,0
	DKBCHR	1,≡
	DKBCHR	2,∩
	DKBCHR	3,∪
	DKBCHR	4,⊂
	DKBCHR	5,⊃
	DKBCHR	6,$
	DKBCHR	7,%
	BYTE(9)	<"8">,<"8">,32,32
	BYTE(9)	<"9">,<"9">,30,30
	DKBCHR	:,↓
	DKBCHR	<;>,↑
	BYTE(9)	177,177,177,177
	BYTE(9)	175,175,175,175
	0
	0
;TK KBD

IFN FTTKKB,<
TKKBCV:	MOVE TAC,CHR			;SAVE META, CTRL, SHIFT LOCK, SHIFT BITS
	LDB DSER,[POINT 1,CHR,28]	;TOP BIT
	DPB DSER,[POINT 30,CHR,29]	;SEVENTH BIT.  CLEAR REST OF AC
	IDIVI CHR,5
	LDB CHR,TKKBBY(DSER)
	LDB DSER,[POINT 30,CHR,29]	;PUT TOP BIT BACK. (SAVE ON LITERAL)
	DPB DSER,[POINT 1,CHR,28]
	TRZ CHR,100			;CLEAR BIT WHERE TOP USED TO BE
	TRZE TAC,2000			;FLUSH SHIFT BIT, SKIP IF WAS OFF
	TRCE TAC,200			;IF SHIFT WAS ON AND TOP IS OFF...
	JRST TKKBC2
	JRST TKKBC1			;..TURN IT ON IN PREP FOR SHIFTING NONLETTER
TKKBC2:	ANDI TAC,1500			;KEEP META, CTRL, SHIFT LOCK
	IORI CHR,(TAC)
	JRST TKKBRT

TKKBC1:	CAIL CHR,1
	CAILE CHR,32
	SKIPA CHR,TAC			;NOT LETTER DO TOP FOR SHIFT
	TROA TAC,100			;LETTER  DO SHIFT LOCK FOR SHIFT
	JRST TKKBCV			;HAVE TURNED SHIFT OFF, TOP ON.  TRY AGAIN
	JRST TKKBC2

TKKBBY:	350700,,TKKBTB(CHR)
	260700,,TKKBTB(CHR)
	170700,,TKKBTB(CHR)
	100700,,TKKBTB(CHR)
	010700,,TKKBTB(CHR)

TKKBTB:	BYTE (7) 41,42,61,62,63		;BREAK, ESC, 1 THRU 3
	BYTE (7) 64,65,66,67,70		;4 THRU 8
	BYTE (7) 71,60,55,105,121	;9, 0, -, @, ∧
	BYTE (7) 74,43,44,45,75		;BS, CALL, CLEAR, TAB, ALT
	BYTE (7) 21,27,05,22,24		;QWERT
	BYTE (7) 31,25,11,17,20		;YUIOP
	BYTE (7) 150,151,34,57,152	;[, ], \, /, ⊗ for Circle -
	BYTE (7) 152,46,47,74,01	;⊗ FOR Circle +, FF, VT, RUBOUT, A
	BYTE (7) 23,04,06,07,10		;SDFGH
	BYTE (7) 12,13,14,73,72		;JKL;:
	BYTE (7) 33,35,35,32,30		;CR, LF, LF FOR Back/Next, ZX
	BYTE (7) 03,26,02,16,15		;CVBNM
	BYTE (7) 54,56,57,40,141	;,./<SPACE> <TOP>BREAK
		;CODES FROM HERE ON ARE TOP <MUMBLE>S (ON TK KEYBOARD)
	BYTE (7) 142,154,131,122,166	;<ESC>!"#$
	BYTE (7) 167,124,111,50,51	;%&'()
	BYTE (7) 171,110,125,170,174	;_=`~ <BS>
	BYTE (7) 143,144,145,175,121	;CALL, CLEAR, TAB, ALT, ∧
	BYTE (7) 127,162,163,164,165	;∨∩∪⊂⊃
	BYTE (7) 155,152,172,173,117	;¬⊗↓↑<LEFT CURLY BRACE>
	BYTE (7) 120,153,134,173,172	;<RIGHT CURLY> |∞ ↑ for Delta, ↓ for Del
	BYTE (7) 146,147,174,101,123	;FF VT RUBOUT ≤≥
	BYTE (7) 161,157,107,156,112	;≡∂≠ ? FOR Help, ←
	BYTE (7) 113,114,53,52,133	;→↔+* CR
	BYTE (7) 135,135,132,130,103	;LF LF for Back/Next, αβε
	BYTE (7) 126,102,116,115,104	;λπ∀∃ <LESS THAN>
	BYTE (7) 106,156,140		;<GREATER> ? <SPACE>
>
;SCNINT, SCNIN1, CTYINT, DTXMT1, DTRCV1

;SCANNER INTERRUPT SERVICE ROUTINE.

↑SCNINT:JSR	SCNSAV
	CONSO	DCSA,10		;RECEIVER FLAG?
	JRST	SCNIN1		;NO, XMITTER FLAG
	CONI	DCSB,LINE	;SCANNER INPUT.
	DATAI	DCSB,CHR
	CAIL	LINE,SCNNUM	;ARE WE ENABLED FOR THIS LINE NUMBER?
	POPJ	P,		;NO, DISMISS INTERRUPT
	CAIE	LINE,APLINE
	CAIN	LINE,NYLINE
	JRST	.+2		;AP OR NY LINE
	JRST	RECINT
	LSH	CHR,-2		;SHIFT CHARACTER.
	JUMPN	CHR,RECINT
	MOVEI	CHR,100		;NULLS ARE SIGNIFICANT, SO DISALLOW NULLS.
	JRST	RECINT

SCNIN1:	DATAI	DCSA,LINE		;GET LINE NUMBER FROM FULL DUPLEX.
	CONO	DCSA,4000+FSNCHN	;RELEASE XMITTER SCANNER
	JRST	XMTINT			;IN SCNSER OR TTYSER

NOKL10,<
↑CTYINT:JSR	SCNSAV			;CTY INTERRUPT SERVICE.  SAVE ACS
	MOVEI	LINE,TCONLN		;LOAD LINE WITH PROPER
	CONSO	CTY,40			;TTI FLAG?
	JRST	CTYOU1			;NO.
	DATAI	CTY,CHR
	JRST	RECINT			;RECEIVER INTERRUPT HANDLER

CTYOU1:	CONO	CTY,200+SCNCHN		; CLEAR TTO FLAG
	JRST	XMTINT			;COMMON TRANSMIT INTERRUPT HANDLER
>;NOKL10

IFKL10,<
↑DTXMT1:MOVEI	LINE,TCONLN		;HERE FROM DTESER WITH XMIT DONE
	JRST	XMTINT

↑DTRCV1:MOVE	CHR,TAC			;FROM DTESER WITH RECIEVED CHAR IN TAC
	MOVEI	LINE,TCONLN
	JRST	RECINT
>;IFKL10
;RECINT RECINA RECINB RECINC RECIM3 NOESC ESCRET SCNBU2 SCNBU4

↑SCNBU2:
	CONO	PI,PIOFF
	EXCH	P,APRPDL
	PUSHACS
	PUSHJ	P,DISMES
	ASCIZ	/SCNCNT WAS -2 OR LESS.  CALLERS ADDRESS IN SCNBUG.
/
	PUSHJ	P,DISFLUSH
	PUSHJ	P,WDDTCA
	SETZM	SCNCNT			;FIX IT I HOPE
	POPACS
	EXCH	P,APRPDL
	CONO	PI,PION
	JRST	2,@SCNBUG

↑SCNBU4:
	EXCH	P,APRPDL
	PUSHACS
	PUSHJ	P,DISMES
	ASCIZ	/SCNCNT WAS ABOUT TO BECOME -2 OR LESS.  CALLERS ADDRESS IN SCNBU3.
/
	PUSHJ	P,DISFLUSH
	PUSHJ	P,WDDTCA
	SETZM	SCNCNT			;FIX IT I HOPE
	POPACS
	EXCH	P,APRPDL
	JRST	2,@SCNBU3

;COMMON RECEIVER INTERRUPT FOR ALL KEYBOARD DEVICES

↑RECINT:
IFN FTDM,<
	MOVE	TAC,LINTAB(LINE)
	TLNN	TAC,DMDLIN		;Is this a Datamedia display?
	JRST	RECIN0
	SETZB	AC1,AC2			;Used by DMESC and below
	JUMPE	CHR,DMESC		;NULL is the DM display ESCAPE char
	CAIN	CHR,200
	JRST	DMMETA			;EDIT-NULL is the "add META" character
	LDB	UCHN,[POINT 1,CHR,28]	;Get EDIT bit
	ANDI	CHR,177			;Flush EDIT bit and any other garbage
	CAIGE	CHR,40			;Special char?
	MOVE	AC1,DMTABL(CHR)		;Yes, get DM bits for this char
	TRNN	TAC,REGESC!SPCESC	;Is char being quoted or getting META added?
	JRST	RECDM5			;No
	TRNN	TAC,REGESC
	JRST	RECDM8			;Add META
	TLNE	AC1,INQUOT		;Can we quote this char?
	DPB	AC2,[ESCFLD,,LINTAB(LINE)] ;Yes, clear quote (ESC) flag
	JRST	RECDM2			;No, must be ESC char

RECDM8:	IORI	UCHN,2			;Give him META
	DPB	AC2,[ESCFLD,,LINTAB(LINE)] ;Clear "add META" flag
	TLNE	AC1,INQUOT		;Does META quote this char?
	JRST	RECDM2			;Yes
RECDM5:	CAIN	CHR,176
	JRST	[MOVEI CHR,32↔JRST RECDM2] ;176→32 (tilde)
	CAIN	CHR,175
	AOJA	CHR,RECDM2		;175→176 (right brace)
	TLNN	AC1,DMCONV		;Need to convert this character?
	JRST	RECDM2			;No
	LDB	CHR,[POINT 9,AC1,17]	;Get new character
	TRNE	CHR,600
	JRST	RECDM7			;Already has bits--preserve 'em (CALL)
	JUMPN	CHR,RECDM2		;Now put in CONTROL bit, if typed
	CAME	AC1,DMTABL+HOLDER	;Is this the hold/unhold character
	JRST	RECDM6
	JUMPN	UCHN,RECDM9
	MOVEI	CHR,10044		;CONTROL-CLEAR for assumed unhold
	SKIPE	AC1,LETAB(LINE)
	SKIPL	DPHOLD(AC1)		;Are we holding?
RECDM9:	MOVEI	CHR,10041		;No, use CONTROL-BREAK for hold
	MOVEI	UCHN,1
	JRST	RECDM7

RECDM6:	CAME	AC1,DMTABL+MASTER	;Is this the clear character?
	JRST	4,CPOPJ			;Then what is it?
	MOVEI	CHR,10044		;Clear--leave EDIT bit as is
	JRST	RECDM7			;Notice that EDIT-CLEAR will do an unhold

RECDM2:	DPB	UCHN,[POINT 2,CHR,28]	;Put control bits into character
RECDM7:	LDB	DSER,[POINT 7,CHR,35]
	CAIL	DSER,"A"
	CAILE	DSER,"Z"
	JRST	RECINA
	TROA	DSER,40			;Make lower case
>;FTDM
RECIN0:	MOVEI	UCHN,0			;NO CONTROL BITS FROM MOST KEYBOARDS.
RECINA:	HLL	LINE,LINTAB(LINE)	;Enter here from NOTALK (w/↑C) and DKBINT
	MOVE	TAC,LINTAB(LINE)
PTYREC:	JUMPE	CHR,CPOPJ		;PTY OUTPUT ROUTINES ENTER HERE (UUO LEVEL)
	TRNE	CHR,10000
	JRST	SETESC			;ESCAPE TYPED.
NOESC:	TRNE	TAC,REGESC+SPCESC
	JRST	DOESC			;NON-ESCAPE AFTER ESCAPE SEEN.
ESCRET:	HLL	LINE,LINTAB(LINE)	;TEST TO SEE IF TTYS ARE LOCKED OUT
	TLNN	LINE,CTYLIN		;ALWAYS LET CTY BY
	SKIPN	TTYLOK			;ARE WE IN LOCKOUT MODE?
	JRST	NOLOCK			;NO
	PUSH	P,AC2
	PUSH	P,AC3
	MOVSI	AC2,400000		;A TEST BIT
	MOVEI	AC3,0
	MOVNI	LINE,(LINE)
	LSHC	AC2,(LINE)
	TDNN	AC2,TTYENB		;SKIP IF TTY IS ENABLED
	TDNE	AC3,TTYENB+1
	JRST	NOLOK1
	SUB	P,[2,,2]
	POPJ	P,			;THIS TTY ISN'T ENABLED

NOLOK1:	POP	P,AC3
	POP	P,AC2
NOLOCK:	LDB	LINE,[POINT PUNITS,TAC,35]	;LINE←MAPPED LINE NUMBER.
	MOVSI	DDB,KILTTY
	ANDCAB	DDB,TTYTAB(LINE)	;Don't let DDB be killed now
	JUMPN	DDB,RECIN1		;IS THERE A DDB FOR THIS LINE?
	CAIE	LINE,IMSSS		;No.
	CAIN	LINE,APLINE		;FLUSH AP LINE OR IMSSS IF NO DDB
	POPJ	P,
	CAIN	LINE,NYLINE		;FLUSH NY LINE TOO IF NO DDB.
	POPJ	P,
	PUSH	P,AC1
	PUSHJ	P,DDBSRC		;NO, FIND ONE
	JRST	TYPX
	POP	P,AC1
RECIN1:	HLL	LINE,LINTAB(LINE)
PRINTX WHY NOT FLUSH THE PJOBN BUG TRAP?
;***REG BUG TRAP.  OCCASIONALLY A DDB WINDS UP WITH THE WRONG JOB NUMBER.
;***HERE WE LOOK FOR THAT AND HALT IF WE'RE LOSING.
	PUSH	P,J
	MOVE	J,DEVMOD(DDB)		;GET MODE BITS
	TLNN	J,TTYATC
	JRST	RCBXIT			;NOT IN USE AS A CONSOLE.
	LDB	J,PJOBN			;GET JOB NUMBER OF THIS DDB
	JUMPE	J,RCBXIT		;IF NONE, WE'RE OK.
	HRRZ	J,JBTLIN(J)		;GET SUPPOSED LINE NUMBER FOR THIS JOB.
	CAIN	J,(LINE)		;SHOULD MATCH
	JRST	RCBXIT
	PUSHACS
	PUSHJ	P,DISMES
	ASCIZ	/PJOBN OF TTY DDB INCONSISTENT AT RECIN1.
/
	PUSHJ	P,DISFLU
	POPACS
	PUSHJ	P,WDDTCALL
	MOVEI	J,0			;AND THIS IS HOW WE FIX IT.
	DPB	J,PJOBN			;WILL THE CURE BE WORSE THAN THE DISEASE?
RCBXIT:	POP	P,J
;****END REG BUG TRAP.

RECIN8:
IFN FTTALK,<	CAIN	CHR,10044	;DID HE TYPE CLEAR?
		JRST	RECINZ		;YES, LET POOR FELLOW FLUSH HIS LINED
		TLNE	LINE,TLKRNG	;IN A TALK RING?
		JRST	DOTALK		;YES, GO TALK
RECINZ:
>
	MOVE	IOS,DEVIOS(DDB)		;SET UP IOS
	TLNE	LINE,DDDLIN!DISLIN!DMDLIN
	JRST	KBDEDP		; IF A DPY, GO TO SMART EDITOR UNLESS PTLIP SET
	TLNE	LINE,IMLIN	;IMLAC LINE?
	JRST	RECIML		;YES, SPECIAL INTERRUPT RECEIVER FOR IMLACS
RECIM2:	TRNE	CHR,10000
	POPJ	P,		;DISCARD ESC COMMANDS ON NON-DISPLAYS
	TLNE	LINE,DMLIN	;DATAMEDIAS HAVE ANOTHER BIT (200--EDIT=CONTROL)
	LDB	UCHN,[POINT 1,CHR,28]
	ANDI	CHR,177		;7-BIT ASCII ONLY
	TLNN	LINE,DMLIN	;Datamedias should have all the chars somewhere
	JRST	NOTDM
	CAIN	CHR,176
	MOVEI	CHR,32
	CAIN	CHR,175
	MOVEI	CHR,176
	CAIN	CHR,33
	MOVEI	CHR,175
NOTDM:
;*** BEGIN RPH HACK TO RUN DATAPHONES AS DATA DEVICES
	TLNE	IOS,TPMON	;MONITOR HEAL THY SELF
	JRST	NOSPMD		;NO SPECIAL MODE (IN CASE THIS IS HIS CONSOLE)
	LDB	TAC,PIOMOD	;PICK UP IO MODE
	CAIE	TAC,10		;SPECIAL "IMAGE" MODE?
	CAIN	TAC,11		;ANOTHER SPECIAL MODE FOR AP WIRE
	TLZA	IOS,IMLTTY	;**BO MOD TO TURN OFF IMLAC CONTROL FLAG**
	JRST	NOSPMD		;NOT AN IMAGE MODE.
	TLNE	IOS,TTYHLD
	PUSHJ	P,TTYUNH	;ALSO DON'T ALLOW HOLDING.
	MOVEI	DAT,TTIBUF(DDB)
	PUSHJ	P,PUTCHI	;PUT CHARACTER DIRECTLY INTO INPUT BUFFER
	JFCL			;IGNORE FAILURE
	MOVE	DAT,FCTR(DAT)
	CAIE	TAC,10		;INTERRUPT EVERY CHAR?
	CAIG	DAT,TTICHR/2	;NO, HALF FULL YET?
	TLOA	IOS,DDTM	;YES, ACTIVATE IT NOW
	JRST	SNKTST		;DON'T ACTIVATE YET
	JRST	RECIN4		;ACTIVATE, BUT NOT COMMAND DECODER

NOSPMD:
;*** END RPH HACK
	CAIE	CHR,0
	CAIN	CHR,3			;CONTROL C?
RECINB:	PUSHJ	P,CNCTST		;YES, SEE IF 2ND CONTROL C
	TLNE	LINE,IMLIN
	JRST	RECIM3			;IMLAC'S SEND ALL THE RIGHT CODES.
	TLNN	LINE,PTYLIN		;PTY'S WILL BE SENDING RIGHT CURLY BRACKET
	CAIE	CHR,176
	CAIN	CHR,33			;CONVERT OLD LOSING ALTMODES INTO NEW.
	MOVEI	CHR,175
RECIM3:	LDB	HPOS,PHPOS		;PICK UP HORIZONTAL POSITION OF OUTPUT CHAR.
	MOVEI	DAT,TTIBUF(DDB)		;USER MODE INPUT BUFFER
	PUSHJ	P,TTEDIT		;GO EDIT (AND ECHO) CHARACTER
	TLNN	IOS,TPMON		;NOT IN MONITOR MODE
	TLNN	LINE,PTYLIN
	JRST	RECIN5			;ONLY SPECIAL CHECK FOR PTYS
	JUMPE	UCHN,RECIN5
	MOVE	TAC,ACTMOD(DDB)
	TRNE	TAC,SUPSCM
	CAIE	UCHN,3
	TRNN	TAC,SUPBTS
	TLO	IOS,SYNC		;ACTIVATE PTY ON CTRL META
RECIN5:	TRNN	IOS,NOECHO		;IF WE ECHOED IT,
	DPB	HPOS,PHPOS		;STORE HORIZONTAL POSITION
	TLNE	IOS,TTYHLD		;IF TYPEOUT IS HOLDING
	CAMN	TAC,SPCTAB+2		;AND THE CHAR WASN'T ↑B...
	CAIA
	PUSHJ	P,TTYUNH		;THEN UNHOLD.
	HLLM	LINE,LINTAB(LINE)	;UPDATE LINE TABLE
	MOVE	TAC,TIFCTR(DDB)		;FREE SPACES LEFT
	CAIG	TAC,12			;ONLY 10 LEFT?
	JRST	RWARN			;YES. GO OUTPUT XOFF
	TLNN	IOS,SYNC!DDTM		;WAS A BREAK CHARACTER TYPED?
	JRST	SNKTST			;NO, GO SEE IF ECHO NEED BE TYPED
	TLNN	IOS,SYNC		;DON'T CRANK UP CH7 UNLESS SYNC CHAR.
	JRST	RECIN4
;RECIN3 RECIN4 UTYPET TYPTST TYPGO TTINT STXTIM STXTM2 STXTM3 RWARN TYPT2

RECIN3:	MOVSI	TAC,COMBIT		;IS IT IN COMMAND WAIT NOW?
	TDNN	TAC,TTYTAB(LINE)	;..
	PUSHJ	P,COMSET		;NO, WAKE UP COMMAND DECODER NOW
RECIN4:	MOVEI	DAT,TTIBUF(DDB)		;SET FOR SYNCHA
	TLZE	IOS,SYNC!DDTM		;ACTIVATION CHAR.?
	PUSHJ	P,SYNCHA		;UPDATE ACTIVATED CHAR. COUNT
					;CLEAR SYNC IN CORE
	MOVEM	IOS,DEVIOS(DDB)		; ..
	MOVE	TAC,TIPCTR(DDB)		;UPDATE COUNTER FOR ↑U
	DPB	TAC,PLSTLC
	TLNE	IOS,TPMON		;NO INTERRUPTS IN MONITOR MODE.
	JRST	TYPTST
	LDB	J,PJOBN			; PICK UP JOB NUMBER
	MOVSI	AC1,INTTTY		; GIVE HIM A TTY INTERRUPT IF DESIRED
	TDNE	AC1,JBTIEN(J)		; IS HE ENABLED FOR IT?
	PUSHJ	P,TTINT			; YES, DO IT.
	TLZN	IOS,TTYIOW		;IN TELETYPE INPUT WAIT?
	JRST	TYPTST			;NO, GO ECHO
SNKWAK:	PUSHJ	P,STTIOD		;YES, SET IO DONE (OUT OF TTY IOW)
	PUSHJ	P,STXTIM		;UPDATE INTERACTION RUN TIME (XTIME)
	MOVSI	IOS,IOW!TTYIOW!SNKWAT
	ANDCAB	IOS,DEVIOS(DDB)		;CLEAR WAIT BITS
↑UTYPET:
TYPTST:	TLNE	IOS,TTYDTC
	POPJ	P,			;FLUSH IF DETACHED
	PUSHJ	P,STLNAC		;CLOBBERED BY STTIOD
↑TYPT2:	TLNE	LINE,PTYLIN		;IS THIS A PTY
	JRST	PTOCK			;YES, JUST GO CHECK PTY STUFF
	MOVSI	IOS,TOIP
	OFFSCN				;TURN OFF SCANNER CHANNEL
	TDNE	IOS,DEVIOS(DDB)		;TYPE OUT HAPPENNING?
	JRST	SCNONJ
	IORB	IOS,DEVIOS(DDB)		;NO, BUT THERE IS NOW
	ONSCN				;TURN ON SCANNER CHANNEL
	TLNN	IOS,TTYDTC		;DON'T TYPE IF HE'S DETACHED...
	JRST	XMTI1B			;START OUTPUT
	POPJ	P,

SNKTST:	TLNN	IOS,SNKWAT		;IS USER IN SNEAK WAIT?
	JRST	TYPTST			;NO, PROCEED NORMALLY
	JRST	SNKWAK

↑TYPGO:	MOVE	IOS,DEVIOS(DDB)
	TDNE	IOS,[XWD TTYDTC,IOSUPR]
	POPJ	P,			;FLUSH OUTPUT
	PUSHJ	P,STLNAC
	MOVSI	IOS,IO
	OFFSCN				;TURN OFF SCANNER CHANNEL
	IORB	IOS,DEVIOS(DDB)
	PUSHJ	P,TYPTST
	ONSCN
	POPJ	P,

RWARN:	TLO	IOS,DDTM		;ACTIVATE EVERYTHING SO FAR
	TLNE	LINE,FULTWX!PTYLIN!DISLIN!IMLIN!DMDLIN	;CAN LINE BE STOPPED?
	JRST	RECIN3			;NO. WAKE JOB AND CROSS FINGERS.
	MOVEI	CHR,23			;YES. SEND AN XOFF.
	PUSHJ	P,PUTCHO		; ..
	MOVEI	CHR,IDLECH		;AND AN IDLE FOR TTY TO THINK ON.
	PUSHJ	P,PUTCHO		;OUTPUT IT.
	JRST	RECIN3			;GO WAKE JOB.

↑TTINT:	IORM	AC1,JBTIRQ(J)		;(ALSO CALLED FROM ELFSER)
	SETOM	INTREQ(PID)
	HLLOS	CLKFLG(PID)
	CONO	PI,1B24!1⊗(7-CLKCHN)
	POPJ	P,

STXTM3:	SKIPA	J,JOB(PID)		;ENTER HERE FROM SNEAKW
STXTIM:	LDB	J,PJOBN			;GET JOB NUMBER
↑STXTM2:				;ENTRY POINT FROM RUN-JOB CODE
	JUMPE	J,CPOPJ			;IF NO JOB, NO XTIME
	SKIPGE	XTIME(J)		;IS NO-UPDATE BIT ON?
	POPJ	P,			;YES.  DONT DO ANYTHING!
	MOVE	TAC,TTIME(J)		;PICK UP CURRENT RUN TIME
	MOVEM	TAC,XTIME(J)		;UPDATE INTERACTION RUN TIME
	SKIPGE	TAC,JBTWAT(J)		;PICK UP WAIT TIME
	ADD	TAC,UPTIME		;MAKE IT HONEST
	MOVEM	TAC,JB2WAT(J)		;AND SAVE IT
	HRLS	DSKOPS(J)		;SAVE CURRENT NUMBER OF DISK OPERATIONS
	POPJ	P,
;ESCAPE BITS
;DEFINITIONS FOR ESCAPE PROCESSOR
;ALL THIS STUFF GOES IN RH(LINTAB)

REGESC←←400000	;NORMAL ESCAPE TYPED
SPCESC←←200000	;SPECIAL--"Add META bit to next char" if DM
ESCNEG←←100000	;NEGATION FLAG (BREAK, ETC.)

ESCTYP←←200200			;BYTE PNTR FOR TYPE BITS
ESCARG←←PUNITS⊗14+<17-PUNITS>⊗6	;EVERYTHING ELSE IS ARG
ESCFLD←←PUNITS⊗14+<22-PUNITS>⊗6	;WHOLE ESCAPE FLD
↑ESCNUL←←ESCNEG⊗-PUNITS-1	;MAX VAL USED FOR NULL (ZERO SOMETIMES LEGAL)
ESCMAX←←ESCNUL-1		;MAX LEGAL VALUE
;SETESC STDESC ESCOCS ESCOCT DMESC DMMETA DMBONG
;HERE ON <ESC>,<BREAK>, OR <CLEAR> (ALSO FUNNY CHARS FROM PTYS)
;ESCAPE CODE BITS ARE SET UP FOR NEXT TIME

DMMETA:	SKIPA AC3,[SPCESC⊗-PUNITS+ESCNUL]
DMESC:	MOVEI AC3,REGESC⊗-PUNITS+ESCNUL		;<ESC>
	SKIPN AC1,LETAB(LINE)	;Gotta have dpy header to type ESC or META on DM
↑DMBONG:TDZA AC3,AC3
	SETOM LEACT(AC1)	;But if you got one, we'll let you keep it a while
	DPB AC3,[ESCFLD,,LINTAB(LINE)]
	JUMPN AC3,CPOPJ
	MOVEI CHR,7
	SETZ DDB,
	JRST TYPDM		;Output a bell to tell user bye

SETESC:	CAIN CHR,10044
	JRST NOESC		;<CLEAR> ISN'T REALLY AN ESC CHR
	MOVEI AC3,
	CAIN CHR,10042
	MOVEI AC3,REGESC⊗-PUNITS+ESCNUL		;<ESC>
	CAIN CHR,10041
	JRST [	CAIE UCHN,1	;WATCH OUT FOR CTRL-BRK
		MOVEI AC3,<REGESC+ESCNEG>⊗-PUNITS+ESCNUL	;BREAK
		JRST .+1]
	CAIN AC2,1641
	MOVEI AC3,SPCESC⊗-PUNITS+ESCNUL
	DPB AC3,[ESCFLD,,LINTAB(LINE)]
	JUMPN AC3,CPOPJ		;EXIT IF ESC CHR
	HLRE AC1,CHR
	JUMPLE AC1,.+2
	ANDI AC1,ESCNUL
	JUMPN AC1,.+2
	MOVEI AC1,ESCNUL	;ELSE MAP 10XXX→<ESC>XXX, 14XXX→<BRK>XXX
	TRNE CHR,4000		;(EASIER FORM FOR PTYUUO'S)
	MOVN AC1,AC1
STDESC:	CAIN DSER,"a"
	JRST VDESCA		;ADD CHANNEL
	CAIN DSER,"d"
	JRST VDESCD		;DELETE CHANNEL
	CAIN DSER,"s"
	JRST VDESCS		;SELECT CHANNEL
	CAIN DSER,"t"
	JRST VDESCT		;SELECT TEMPORARY CHANNEL
	CAIN DSER,"u"
	JRST ASESC		;AUDIO SWITCH CHANNEL SELECT
	CAIN DSER,"b"
	JRST ESCB		;AUDIO SWITCH UNBEEPER
	CAIN DSER,"m"
	JRST VDESCM		;DD LINE MAPPING
	JUMPGE AC1,STDES2	;ESC L IS FOR LINE EDITOR TO DO,
	CAIN DSER,"l"		;  BUT BREAK L IS FOR US
	JRST VDESCL		;  AND SETS VDTIE
STDES2:	TRO CHR,10000		;PASS IT ON TO LINED
	CAIN AC1,ESCNUL		; WITH ARG IN SIGN-MAGNITUDE FORM
	MOVEI AC1,
	JUMPGE AC1,ESCRET
	MOVN AC1,AC1
	CAIN AC1,ESCNUL
	MOVEI AC1,
	HRLI AC1,400000
	JRST ESCRET

;REMEMBER THAT ARG WE READ IN IN DECIMAL? WELL, WE REALLY WANTED
;TO READ IT IN OCTAL, SEE, SO . . .

ESCOCS:	AOS (P)
ESCOCT:	IDIVI AC1,=100
	IDIVI AC2,=10
	LSH AC2,3
	ADD AC2,AC3
	LSH AC1,6
	ADD AC1,AC2
	POPJ P,
;DOESC
;HERE ON NEXT CHAR AFTER ESCAPE. ANY ARG IS ACCUMULATED LEAVING ESC BITS SET.
;OTHER CHARS CLEAR BITS (LEAVING ESCAPE MODE) AND DISPATCH TO APPROP HANDLER

DOESC:	LDB AC1,[ESCARG,,TAC]
	LDB AC2,[ESCTYP,,TAC]
	CAIE AC2,1
	JRST .+3
	CAIE UCHN,3
	SOJA AC2,ESCXIT
	CAIL DSER,"0"
	CAILE DSER,"9"
	JRST DOESC1
	CAIN AC1,ESCNUL
	TDZA AC1,AC1
	IMULI AC1,12
	ADDI AC1,-"0"(DSER)
	CAILE AC1,ESCMAX
	MOVEI AC1,ESCMAX
	DPB AC1,[ESCARG,,LINTAB(LINE)]
	POPJ P,

DOESC1:	CAIN DSER,"-"
	JRST DOESCN
	TRNE TAC,ESCNEG
	MOVN AC1,AC1
ESCXIT:	ANDI TAC,1⊗PUNITS-1
	HRROI AC3,1⊗PUNITS-1	;BH 3/13/75 BUG FIX, PTYUUO TO MAPPED TTY
	ANDM AC3,LINTAB(LINE)	;  UNMAPPED IT WHEN THIS WAS HRRM TAC,
	JRST @ESCDSP(AC2)	;NOTE AC2>0 OR WE WOULDN'T BE HERE

ESCDSP:	ESCRET
	SPESC
	STDESC

DOESCN:	MOVEI TAC,ESCNEG
	XORM TAC,LINTAB(LINE)
	POPJ P,
;SPESC, VDESCM, VDESCL

SPESC:	TLO TAC,200000
IFN FTDDT,<
	CAIN CHR,600
	CAIE UCHN,3
	CAIA
	JRST DDTCAL
>;FTDDT
	CAIE CHR,600-40(DSER)
	JRST ESCRET
	CAIE CHR,600+"P"
	JRST STDESC
	PUSHJ P,ESCOCT
	CAIL AC1,TTPLEN
	MOVEI AC1,(LINE)
	HRRM AC1,LINTAB(LINE)
	POPJ P,

VDESCM:	HLL LINE,LINTAB(LINE)	;BH 12/4/74 USER KBD MAP COMMAND
	TLNN LINE,DDDLIN	;ONLY FROM DD TERMINAL
	POPJ P,
	JUMPGE	AC1,VDESM7	;JUMP IF <ESC>
	MOVM	AC1,AC1		;BREAK M - GET POSITIVE ARGUMENT
	CAIN	AC1,ESCNUL	;NULL ARGUMENT?
	JRST	VDESM4		;YES, BREAK M MEANS FIND NEXT JOB SAME PRG - BH
VDESM7:	CAIN AC1,ESCNUL		;IF NO ARG,
	JRST VDESM1		;USE OWN LINE
	PUSHJ P,ESCOCT		;ELSE GET LINE NUMBER
	CAIL AC1,DDL0		;ONLY CAN MAP TO DD LINES
	CAIL AC1,DDL0+DDNUM
	POPJ P,
VDESM6:	PUSHJ P,VDESMX		;CHECK IF ALLOWED
	 POPJ P,
VDESM2:	HRRM AC1,LINTAB(LINE)	;OK
VDESM3:	MOVEI AC1,ESCNUL	;12/8/74 NOW SWITCH HIS SCREEN TOO

↑VDESCL:MOVMS AC1		;BREAK N L LOOKS AT LINE N
	CAIN AC1,ESCNUL
	JRST VDESL1		;  OR THE ONE YOU'RE MAPPED TO
	PUSHJ P,ESCOCT
VDESL2:	CAIL AC1,DDL0		;CHECK ARG FOR RANGE
	CAIL AC1,DDL0+DDNUM
	POPJ P,			;FOO
	TLNE TAC,200000		;MAGIC BIT
	JRST VDESL3
	PUSHJ P,VDESMX
	 POPJ P,
VDESL3:	MOVEI TAC,-DDL0(LINE)	;ALSO CHECK WHO IS GIVING THE COMMAND
	JUMPL TAC,CPOPJ
	CAIL TAC,DDNUM
	POPJ P,
	MOVEM AC1,VDTIE(TAC)	;WIN, TIE HIM TO THE ARGUMENT
	JRST VDOUT		;REALLY DO IT

VDESL1:	LDB AC1,[POINT PUNITS,LINTAB(LINE),35]
	JRST VDESL2

VDESM1:	HRRM LINE,LINTAB(LINE)	;USE OWN LINE
	JRST VDESM3

VDESM4:	HRRZ	DDB,TTYTAB(TAC)	;BH 2/6/75 BREAK M GETS NEXT JOB OF SAME PRG
	JUMPE	DDB,CPOPJ	;NO-OP IF TTY NOT IN USE
	HLL	TAC,LINTAB(TAC)
	TLNN	TAC,DDDLIN	;YOU'D THINK SOMEONE WHO KNOWS HOW TO GET INTO
	POPJ	P,		;  THIS STATE WOULD KNOW NOT TO DO THIS...
	LDB	AC1,PJOBN	;ELSE GET JOB NUMBER USING TTY
	JUMPE	AC1,CPOPJ	;NO JOB, DO NOTHING
	HRRZ	AC2,PRJPRG(AC1)	;PROGRAMMER NAME
	MOVE	AC3,JBTSTS(AC1)
	TLNN	AC3,JNA		;INCASE JOB ISN'T LOGGED IN.
	POPJ	P,
	MOVEI	AC3,1		;SET DIRECTION FOR ESCQY
;AC2←PRG NAME. AC3←DIRECTION (1). AC1←STARTING JOB NUMBER.
VDESM5:	PUSHJ	P,ESCQY		;SEEK SOME OTHER JOB NUMBER WITH SAME PRG
	POPJ	P,		;NONE THERE - NO-OP
	MOVE	CHR,JBTLIN(AC1)	;JOB OK, NOW CHECK OK TTY
	TLNN	CHR,PTYLIN	;THIS CATCHES DETACHED JOBS
	TLNN	CHR,DDDLIN	;MUST BE AT A DATA RISK
	JRST	VDESM5		;RECYCLE FROM HERE TO FIND ANOTHER JOB.
	MOVEI	AC1,(CHR)	;WIN, DO OUR THING
	JRST	VDESM6

VDESMX:	CAIE AC1,(LINE)		;MAP TO SELF ALLOWED
	SKIPN AC2,LETAB(AC1)
	JRST CPOPJ1		;ALSO MAP TO VACANT LINE
	HLRZ AC2,PRGNUM(AC2)	;ELSE CHECK HIDDEN BIT
	SKIPL DDTAB(AC2)	;FOR THE CHANNEL (THAT'S WHY JUST DD!)
	AOS (P)
	POPJ P,
;ESCAPES VDESCN VDESCA TVSTRB TVSTR VDESAD VDESCD VDESCS VDESCT VDESTV

;ADD CHANNEL TO MAPPING
VDESCA:	PUSHJ P,VDESTV
	PUSHJ P,VDECHK
	PUSHJ P,VDVCHK
	 DPB AC1,[400,,VDTMP(AC2)]
	PUSHJ P,TVSTRB
	 IORM AC3,VDTMP(AC2)
	POPJ P,

TVSTRB:	PUSHJ P,VDBIT
TVSTR:	JUMPGE TAC,TVSTRX
	TLNE AC1,-1			;THIS IS FOR IIIS
	HLLZ AC3,AC1			;PICK UP BITS PASSED, IF ANY
	SKIPN AC2,LETAB+DDL0(TAC)
	JRST CPOPJ1
	HRLI AC2,VPGACT↑
	CONO PI,PIOFF
	IDPB AC2,CLKQ			;SET TO DO PGACT AT CLK LEVEL
	CONO PI,PION
	SETOM LEACT(AC2)		;SO HEADER STAYS AROUND
	MOVEI AC2,PRGACT-VDTMP(AC2)	;MAKE PNTR TO PGACT BITS
	SKIPL @(P)			;IS DIDDLING INSTR BOOLEAN?
	HRR AC3,VDTMP(AC2)		;NO, COPY RH SO IT WON'T GET CLOBBERED
	XCT @(P)
	JRST CPOPJ1

;COPY EXISTING MAP FROM DPY HEADER IF NEEDED FOR ESC A OR D
↑VDESAD:JUMPL TAC,CPOPJ			;NOT FOR III
	HRRZ AC2,VDTIE(TAC)
	JUMPE AC2,CPOPJ
	PUSH P,AC3
	SKIPE AC3,LETAB(AC2)
	SKIPA AC2,VDTMP(AC3)
	MOVE AC2,VDPRM(AC2)
	MOVEM AC2,VDMAP(TAC)
	SETZM VDTIE(TAC)
	POP P,AC3
	POPJ P,

;NORMALIZE SWITCH FOR THIS CHANNEL
VDESCN:	HRREI TAC,-DDL0(LINE)	;WHEN WE GET HERE, LINE HAS BEEN MAPPED ALREADY
	JUMPL TAC,CPOPJ
	CAIL TAC,DDNUM
	POPJ P,
	JRST VDNORM

;DELETE CHANNEL FROM MAPPING
VDESCD:	PUSHJ P,VDESET
	POPJ P,
	PUSHJ P,VDBIT
	CAIL AC1,40
	MOVEI AC3,17		;ANY HIGH # CLEARS ANALOG SELECT
	PUSHJ P,TVSTR
	 ANDCAM AC3,VDTMP(AC2)
	POPJ P,

;SELECT SINGLE CHANNEL INTO MAPPING
VDESCS:	CAIE AC1,ESCNUL
	JRST VDESS1
	MOVEI AC2,-DDL0(LINE)
	JUMPL AC2,VDESS1
	CAIGE AC2,DDNUM
	JRST VDESN1
VDESS1:	PUSHJ P,VDESTV		;<ESC>S
	PUSHJ P,VDECHK
	SETZM VDTIE(TAC)
VDESS2:	PUSHJ P,VDVCHK
	 MOVEM AC1,VDTMP(AC2)
	PUSHJ P,TVSTRB
	 MOVEM AC3,VDTMP(AC2)
	POPJ P,

VDESN1:	LDB AC3,[POINT PUNITS,LINTAB(LINE),35]
	CAIL AC3,DDL0
	CAIL AC3,DDL0+DDNUM
	POPJ P,
	MOVEM AC3,VDTIE(AC2)	;IS TAC STILL SET? COULD SKIP LDB
	MOVEI TAC,-DDL0(AC3)
	JRST VDNORM

;SELECT SINGLE CHANNEL TEMPORARILY
VDESCT:	PUSHJ P,VDESTV
	PUSHJ P,VDECHK
	MOVSI AC3,400000
	MOVEM AC3,VDTIE(TAC)
	JRST VDESS2

;<BRK> N [S|T|A] WHERE N IS IN THE RANGE 3-6 GETS VIDEO CHAN 40+N
;AND AUDIO CHAN 10+N.  <BRK> [S|T|A] WITH NO ARG GETS LOUNGE TV (N=5)

TVMIN←←3		;ANALOG CHANNEL 43 IS LOWEST WITH AUDIO
TVMAX←←6		;ANALOG CHANNEL 46 IS HIGHEST WITH AUDIO
TVDFLT←←5		;CHANNEL 45 IS THE LOUNGE TV

VDESTV:	JUMPGE AC1,CPOPJ	;<ESC>S OR <ESC>T OR <ESC>A
	CAMN AC1,[-ESCNUL]	;IF <BRK> WITH NO NUMBER,
	MOVNI AC1,TVDFLT	; GET DEFAULT TV ARGUMENT
	CAMG AC1,[-TVMIN]
	CAMGE AC1,[-TVMAX]
	POPJ P,			;ARGUMENT NOT IN TV RECEIVER RANGE
	MOVNS AC1
	MOVEI AC1,=40(AC1)	;TURN INTO POSITIVE ANALOG CHANNEL NUMBER
	PUSH P,AC1
	PUSH P,TAC
	SUBI AC1,=40-=10	;GET CORRESPONDING AUDIO CHANNEL
	PUSHJ P,ASESC		;SIMULATE ESC # U WHERE # = 10+ARG
	POP P,TAC
	POP P,AC1
	POPJ P,
;MORE ESCAPES	VDESET	VDECHK	VDVCHK
;SET UP ARGS FOR VD CMDS, SKIP IF LEGAL.
;NO ARG => MY CHAN. + ARG => DD CHAN #. - ARG => CHAN FOR TTY #.
VDESET:	HRRI TAC,-DDL0(LINE)
	MOVE AC2,LINTAB+DDL0(TAC)
	TLNN AC2,DDDLIN
	JRST VDEST4
	JUMPL AC1,VDEST3
	CAIE AC1,ESCNUL
	JRST ESCOCS
	MOVEI AC1,-DDL0(AC2)
	TLO TAC,200000
VDEST2:	SKIPN AC2,LETAB+DDL0(AC1)
	SKIPA AC1,AVLCHN
	HLRZ AC1,PRGNUM(AC2)
	JRST CPOPJ1

VDEST3:	MOVN AC1,AC1
	CAIN AC1,ESCNUL
	JRST VDEST1		;STILL NECESSARY FOR BRK D ALTHOUGH NOT S,A,T
	PUSHJ P,ESCOCT
	SUBI AC1,DDL0
	CAIGE AC1,DDNUM
	JUMPGE AC1,VDEST2
	POPJ P,

VDEST1:	MOVEI AC1,45		;<BRK> WITH NO ARG IS ALWAYS TV CHANNEL
	JRST CPOPJ1		;RPH OCT-27-72

VDEST4:	TLNE AC2,DISLIN		;NOT DD, SEE IF III
	SKIPN LETAB+DDL0(TAC)
	POPJ P,			;NOT III OR NO DPY HEADER MEANS ILLEGAL
	JUMPL AC1,CPOPJ
	HRROI TAC,(TAC)		;(THANK YOU MR. FROST - REG) SET SIGN FOR VDSTRI
	CAIN AC1,ESCNUL
	SKIPA AC1,[-4,,]	;NULL ARG MEANS ALL P OF G'S
	PUSHJ P,ESCOCT
	TRNN AC1,-20
	AOS (P)			;SKIP IF LEGAL P OF G #
	POPJ P,

;SET UP ARGS & CHECK PRIVACY. RETURNS UPLEVEL ON LOSSAGE
VDECHK:	PUSHJ P,VDESET
	JRST TPOPJ
	TLNE TAC,200000
	POPJ P,
	CAIGE AC1,40
	SKIPL DDTAB(AC1)
	POPJ P,
	MOVEI AC3,(TAC)
	MOVEI J,
	PUSHJ P,VDCCHK
	SUB P,[1,,1]
	POPJ P,

;CHECK IF CHANNEL IS REALLY ANALOG, AND HANDLE SPECIALLY
VDVCHK:	TRZN AC1,-40
	JRST CPOPJ1
	ANDI AC1,7
	IOR AC1,VDSYNC(AC1)
TVSTRX:	HRRZ TEM,VDTIE(TAC)
	JUMPE TEM,VDVCH1
	SKIPN AC2,LETAB(TEM)
	JRST VDVCH0
	XCT @(P)
	SKIPGE LETBPT(AC2)
	JRST VDVCH2
	MOVEI AC2,VDPRM-VDTMP-DDL0(TEM)
	XCT @(P)
VDVCH2:	SUB P,[1,,1]
	MOVEI TAC,-DDL0(TEM)
	JRST VDOUTP↑

VDVCH0:	PUSHJ P,VDESAD		;ADDING TO AVAILABLE LINE, UNTIE HIM
VDVCH1:	MOVEI AC2,VDMAP-VDTMP(TAC)
	XCT @(P)
	SUB P,[1,,1]
	JRST VDOUT
;ASSCN, ASESC, ESCB  AUDIO SWITCH SERVICE

;ASBTAB HAS DURATION OF BEEP IN 1/4 SEC UNITS
;IF NON-ZERO, INDICATES BEEP IS HAPPENING

;ASTAB BITS
;RH HAS TIME REMAINING IN TEMP SELECTION IN 1/4 SEC UNITS
;	ZERO MEANS INFINITE
;BITS	  FUNCTION
;0     => UUO IS HANGING UNTIL TEMPORARY SELECTION TIMES OUT
	ASHANG←←400000
	ASHGBP←←430100
;1     => CURRENT SELECTION IS TEMPORARY
	ASTEMP←←200000
;2     => PAGING NOW
	ASPAGN←←100000
;3     => BEEP WHEN TEMPORARY SELECTION TIMES OUT
	ASDBEP←←40000
;4     => PERMANENT CHANNEL NOT PAGE INTERRUPTIBLE
	ASPPUN←←20000
	ASPPUP←←370100
;5     => PERMANENT CHANNEL NOT BEEP INTERRUPTIBLE
	ASPBUN←←10000
	ASPBUP←←360100
;6-7   => TEMPORARY CHANNEL BEEPING DISPOSITION
	ASBPDP←←340200
;8-9   => TEMPORARY CHANNEL PAGING DISPOSTION
	ASPGDP←←320200
;10-13 => TEMPORARY CHANNEL NUMBER
	ASTMPP←←260400
	ASTMPM←←360
;14-17 => PERMANENT CHANNEL NUMBER
	ASPRMP←←220400
	ASPRMM←←17	;MASK

;DISPOSITION CODES
	;0: INTERRUPTIBLE
	;1: NON-INTERRUPTIBLE
	;2: INTERRUPTIBLE, BUT EXTEND DURATION OF TEMP CH
	;3: POSTPONE BEEP UNTIL TEMP SELECTION TIMES OUT

;NOTE: 3 IS APPLICABLE ONLY TO BEEP DISPOSITION

ASPAGC←←0			;AUDIO SWITCH PAGING CHANNEL
ASBEPC←←5			;AUDIO SWITCH BEEP CHANNEL
ASBPTM←←3			;3/4 SEC FOR BEEP

;AUDIO SWITCH CHANNEL PERMANENT SELECTION
ASESC:	HRREI TAC,-DPYL0(LINE)
	JUMPL TAC,CPOPJ
	CAIL TAC,DPYNUM+DDNUM
	POPJ P,			;NEITHER A III NOR A DD
	MOVEI DSER,0
	JUMPGE AC1,ASESC1	;JUMP IF PAGE INTERRUPTIBLE PERM SELECTION ESC U
	MOVN AC1,AC1		;BRK#U MAKE PAGE UNINT.PERMANENT SELECTION
	MOVEI DSER,ASPPUN	;PERM PAGE UNINTERRUPTIBLE
ASESC1:	CAIN AC1,ESCNUL
	MOVEI AC1,ASPAGC⊗-3*=10+ASPAGC&7	;FAKE OUT ESCOCT
	PUSHJ P,ESCOCT		;ASSUME TYPEIN WAS OCTAL
ASSEL:	LDB AC3,[ASHGBP,,ASTAB(TAC)]	;UUO HANG BIT
	IORI AC1,(DSER)		;PERM SELECTION AND MAYBE PPUN BIT
	HRLZM AC1,ASTAB(TAC)	;CLEAR ALL OTHER BITS
	SETZM ASBTAB(TAC)	;CLEAR BEEP DURATION
	HRLI AC1,(TAC)
	DATAO AS,AC1		;DO SELECTION NOW
	JUMPN AC3,ASUNHG	;UNHANG POOR UUO
	POPJ P,


↑ASSCN:	CONO PK,0		;MAKE SURE WE DON'T RUN PAGING INT CODE
	MOVSI TAC,-<DPYNUM+DDNUM>
	MOVEI TAC1,-1
ASSCNL:	TDNE TAC1,ASBTAB(TAC)	;CHECK FOR BEEPING GOING ON
	JRST ASSCB
	TDNN TAC1,ASTAB(TAC)	;SKIP IF NON-INFINITE TEMP SELECTION
	JRST ASSCLN
	MOVE AC1,ASTAB(TAC)
	LDB AC2,[ASPGDP,,AC1]		;TEMP PAGE DISPOSITION
	TLNN AC1,ASPAGN
	JRST ASSCN1		;NOT PAGING NOW
	CAIN AC2,2
	JRST ASSCLN		;PAGING AND EXTEND, SO DON'T COUNT TEMP DURATION
ASSCN1:	SOS AC1,ASTAB(TAC)	;DECREASE ITS COUNT
	TRNN AC1,-1		;SKIP IF NOT TIME YET
	JRST ASSCTO		;TIMED OUT, SET BACK TO PERMANENT
ASSCLN:	AOBJN TAC,ASSCNL
	CONO PK,PKCHN
	POPJ P,

;IN MIDDLE OF BEEP (CAN'T BE IN A PAGE -- SEE PKINT)
ASSCB:	SOS AC1,ASBTAB(TAC)	;DECREMENT BEEP DURATION
	MOVE AC2,ASTAB(TAC)
	TLNN AC2,ASTEMP		;SKIP IF BEEP INTERRUPTED TEMP SEL
	JRST ASSCB1		;BEEP IS DURING PERM SEL
	LDB AC2,[ASBPDP,,AC2]	;TEMP BEEP DISPOSITION
	TDNE TAC1,ASTAB(TAC)	;IF TEMP SEL IS INFINITE OR ...
	CAIN AC2,2
	JRST ASSCB1		;IF EXTEND, THEN DON'T COUNT TEMP DURATION
	SOS AC2,ASTAB(TAC)
	TRNN AC2,-1		;IF TEMP RUNS OUT DURING BEEP, ...
	TLZ AC2,ASTEMP		;MAKE IT LOOK LIKE INTERRUPTED PERM
	MOVEM AC2,ASTAB(TAC)
ASSCB1:	TRNE AC1,-1
	JRST ASSCLN		;BEEP NOT DONE, CONTINUE SCAN
ASRVRT:	MOVE AC1,ASTAB(TAC)
	TLZE AC1,ASDBEP
	JRST ASRVR1		;GO AND BEEP
	TLNE AC1,ASTEMP		;SKIP IF GOING BACK TO PERM
	JRST ASRVR3		;GOING BACK TO TEMP
	TLNE AC1,ASHANG		;SKIP IF UUO NOT HUNG
	PUSHJ P,ASUNHG		;UNHANG UUO
	LDB AC2,[ASPRMP,,AC1]	;PERM SEL
ASRVR2:	HRLI AC2,(TAC)
	DATAO AS,AC2
	JRST ASSCLN		;CONTINUE SCAN

ASRVR3:	LDB AC2,[ASTMPP,,AC1]	;TEMP SEL
	JRST ASRVR2

ASRVR1:	MOVEM AC1,ASTAB(TAC)	;STORE BACK WITH BEEP BIT OFF
	MOVEI AC2,ASBPTM
	MOVEM AC2,ASBTAB(TAC)	;SET UP BEEP DURATION
	MOVEI AC2,ASBEPC
	JRST ASRVR2		;SELECT BEEP CHANNEL AND CONTINUE SCAN

ASSCTO:	TLZ AC1,ASTEMP		;TEMP SEL TIMED OUT, CLEAR TEMP BIT
	TLNE AC1,ASPAGN
	JRST ASSCT2		;PAGING NOW
	TLZE AC1,ASDBEP
	JRST ASRVR1		;DO DELAYED BEEP
	MOVEM AC1,ASTAB(TAC)
	TLNE AC1,ASHANG
	PUSHJ P,ASUNHG		;UNHANG UUO
ASSCT1:	LDB AC2,[ASPRMP,,AC1]
	JRST ASRVR2		;SELECT PERM AND CONTINUE SCAN

ASSCT2:	MOVEM AC1,ASTAB(TAC)	;JUST CLEAR TEMP BIT AND
	JRST ASSCLN		;CONTINUE SCAN

;UNHANG UUO THAT WAS WAITING FOR TEMP SEL TO FINISH
ASUNHG:	PUSH P,DDB
	PUSH P,J
	MOVSI J,ASHANG
	ANDCAM J,ASTAB(TAC)	;CLEAR UUO HANG BIT
	HRRZ DDB,TTYTAB+DPYL0(TAC)
	JUMPE DDB,ASUNHR	;NO DDB, DONE
	MOVSI J,TTYATC
	TDNN J,DEVMOD(DDB)
	JRST ASUNHR		;NOT CONSOLE, DONE
	LDB J,PJOBN		;JOB NUMBER
	MOVM DDB,JOBQUE(J)
	CAIE DDB,IOWQ
	JRST ASUNHR		;NOT IN IOWQ NOW
	MOVEI DDB,RUNQ		;GRONK INTO RUNQ
	MOVNM DDB,JOBQUE(J)
	PUSHJ P,REQUE
ASUNHR:	POP P,J
	POP P,DDB
	POPJ P,

ESCB:	HRREI AC2,-DPYL0(LINE)
	JUMPL AC2,CPOPJ
	CAIL AC2,DDNUM+DPYNUM
	POPJ P,			;NEITHER A III NOR A DD
	MOVSI TAC,ASPBUN
	JUMPL AC1,ESCB1
	ANDCAM TAC,ASTAB(AC2)	;ESC B MAKES YOU BEEP INTERRUPTIBLE
	POPJ P,

ESCB1:	IORM TAC,ASTAB(AC2)	;BRK B MAKES YOU BEEP UNINTERRUPTIBLE
	POPJ P,
;PKINT	PAGING INTERRUPT SERVICE ROUTINE

↑PKCHN←←5			;PI CHANNEL FOR PAGING KLUDGE
↑PKINTB←←10			;INTERRUPT BIT IN CONI
↑PKPAGE←←20			;PAGING BIT IN CONI
↑PKSET←←10
↑PKCLR←←20

↑PKINT:	JSR PKSAV		;SAVES ACS AND PUSHJS TO .+1
	CONO PK,PKCLR!PKCHN
	MOVSI TAC,-<DPYNUM+DDNUM>
	CONSO PK,PKPAGE		;SKIP IF PAGING JUST BEGINNING
	JRST PKINND		;PAGING FINISHED
	SETOM PAGNOW		;INDICATE PAGING NOW IN PROGRESS
	MOVEI TAC1,-1
PKINL:	MOVEI DSER,0		;-1 => BEEPING
	TDNE TAC1,ASBTAB(TAC)
	MOVNI DSER,1		;BEEPING NOW
	MOVE AC1,ASTAB(TAC)
	TLNN AC1,ASTEMP		;SKIP IF TEMP SELECTION NOW IN FORCE
	JRST PKINP		;PERM
	LDB AC2,[ASPGDP,,AC1]
	CAIN AC2,1
	JRST PKINLA		;NOT PAGE INTERRUPTIBLE
PKINLB:	JUMPE DSER,PKINL1	;NOT BEEPING, JUST DO IT
	HLLZM ASBTAB(TAC)	;FLUSH BEEP
	TLO AC1,ASDBEP		;SET DELAYED BEEP BIT
PKINL1:	TLO AC1,ASPAGN		;PAGING NOW
	MOVEM AC1,ASTAB(TAC)
	MOVEI AC2,ASPAGC
	HRLI AC2,(TAC)
	DATAO AS,AC2
PKINLA:	AOBJN TAC,PKINL
	POPJ P,

;PERMANENT SELECTION IS NOW IN FORCE
PKINP:	TLNE AC1,ASPPUN		;SKIP IF PAGE INTERRUPTIBLE
	JRST PKINLA		;CONTINUE SCAN
	JRST PKINLB

;HERE IF PAGING INTERRUPT BUT PAGING BIT IS OFF
PKINND:	SETZM PAGNOW
	MOVE AC1,ASTAB(TAC)
	TLZN AC1,ASPAGN		;SKIP IF HAS BEEN INTERRUPTED FOR PAGING
	JRST PKINNA		;DON'T HAVE TO MUNG HIM
	TLZN AC1,ASDBEP		;SKIP IF HAVE TO DO BEEP NOW
	JRST PKINN1
	MOVEI AC2,ASBPTM
	MOVEM AC2,ASBTAB(TAC)	;SET UP BEEP DURATION
	MOVEI AC2,ASBEPC	;SELECT BEEP CHANNEL AND CONTINUE SCAN
PKINN2:	MOVEM AC1,ASTAB(TAC)
	HRLI AC2,(TAC)
	DATAO AS,AC2
PKINNA:	AOBJN TAC,PKINND
	POPJ P,

;DELAYED BEEP BIT WAS OFF
PKINN1:	TLNN AC1,ASTEMP		;SKIP IF GOING BACK TO TEMP SEL
	JRST PKINNP
	LDB AC2,[ASTMPP,,AC1]	;TEMP CHANNEL SELECTION
	JRST PKINN2

;GOING BACK TO PERMANENT SELECTION
PKINNP:	TLZE AC1,ASHANG		;SKIP IF UUO NOT HANGING
	PUSHJ P,ASUNHG		;UNHANG THE UUO
	LDB AC2,[ASPRMP,,AC1]	;PERMANENT CHANNEL SELECTION
	JRST PKINN2
;ADSMAP BEEP BEEPTK BEEPJB BEEPND BEEPU BEEPDX BEEPX ADSMRD ADSMWT ADSMT ADSRES BEEPDM

;ADSMAP AC, (EFFECTIVE ONLY FROM A JOB THAT IS ATTACHED TO ITS CONSOLE)
;AC BITS
;0	1 => TEMPORARY, 0=> PERMANENT
;1	1 => SET SELECTION, 0 => READ
;2	1 => MAKE THE SELECTION IMMEDIATELY (IF TEMP SEL)
;3	1 => DON'T HANG UNTIL PREVIOUS TEMP SEL IS COMPLETE
;4	1 => DON'T HANG UNTIL THIS TEMP SEL IS COMPLETE
;5-6	PAGING DISPOSITION
;7-8	BEEPING DISPOSITION
;14-17	NEW SELECTION (AS CHANNEL NUMBER)
;RH	DURATION FOR TEMP SEL IN 1/4 SEC UNITS

;THE FOLLOWING ADDITIONAL BITS ARE RETURNED ON A READ STATUS:
;9	1 => THERE IS AN ACTIVE TEMP MAP FOR THIS LINE
;10	1 => THERE IS A PAGE IN PROGRESS (WHETHER OR NOT ON THIS LINE)
;11	1 => THERE IS A PAGE IN PROGRESS AND ENABLED ON THIS LINE
;12	1 => THERE IS A BEEP IN PROGRESS ON THIS LINE
;13	1 => THERE IS A DELAYED BEEP PENDING FOR THIS LINE

;IF THE AC CONTAINS -1, THE MAP IS RESET TO ITS PERMANENT STATUS

;IF TRYING TO MAKE A TEMP SEL WITHOUT WAITING FOR THE PREVIOUS TEMP
;SEL TO FINISH, THE UUO WILL BE IGNORED IF THE PREV TEMP SEL HAS NOT
;COMPLETED AND BIT 2 IS ZERO

;IF PERMANENT THEN ONLY LOW BIT OF DISPOSITION FIELD IS LOOKED AT

;DISPOSITIONS
;0	INTERRUPTIBLE
;1	NON-INTERRUPTIBLE
;2	INTERRUPTIBLE, BUT EXTEND DURATION OF TEMP CH
;3	POSTPONE BEEP UNTIL TEMP SELECTION TIMES OUT

;NOTE: 3 IS APPLICABLE ONLY TO BEEP DISPOSITION

↑ADSMAP:HRRE AC1,JBTLIN(J)
	JUMPL AC1,CPOPJ		;DETACHED
	SUBI AC1,DPYL0
	JUMPL AC1,CPOPJ		;NOT DD OR III
	CAIL AC1,DPYNUM+DDNUM
	POPJ P,			;NOT DD OR III
	MOVE AC2,TAC
	AOJE AC2,ADSRE2		;TAC=-1 MEANS RESET TO PERM
	TLNN TAC,200000		;SKIP IF SETTING SELECTION
	JRST ADSMRD		;READ SELECTION
	OFFSCN				;TURN OFF SCANNER CHANNEL
	TLNN TAC,140000		;SKIP IF DON'T HAVE TO WAIT FOR PREV TEMP SEL
	PUSHJ P,ADSMWT		;WAIT FOR PREV
	JUMPL TAC,ADSMT		;MAKE TEMP SEL
ADSRE1:	HLRZ TAC,TAC		;GET NEW CH # IN LOW 4 BITS
	MOVEI AC2,0
	DPB TAC,[ASPRMP,,AC2]	;PERM CH #
	MOVSI AC3,ASDBEP
	TDNE AC3,ASTAB(AC1)
	IOR AC2,AC3		;SET DELAYED BEEP BIT IF ALREADY SET
	LDB AC3,[000400,,TAC]	;CHANNEL TO SELECT TO
	TRNN TAC,4000		;SKIP IF PAGE UNINTERRUPTIBLE
	JRST [	PUSHJ P,ADSMP1
		JRST .+2]
	TLO AC2,ASPPUN		;SET PERM PAGE UNINTERRUPTIBLE BIT
	TRNN TAC,1000		;SKIP IF BEEP UNINTERRUPTIBLE
	JRST [	PUSHJ P,ADSMP2
		JRST ADSMP4]
	TLO AC2,ASPBUN		;SET PERM BEEP UNINTERRUPTIBLE BIT
	TLZ AC2,ASDBEP		;CLEAR DELAYED BEEP BIT IF NOT INTERRUPTIBLE
	SETZM ASBTAB(AC1)	;FLUSH BEEPS
ADSMP4:	MOVEM AC2,ASTAB(AC1)
	HRLI AC3,(AC1)
	DATAO AS,AC3		;MAKE SELECTION NOW
	TRNN TAC,400000
	JRST ADSSCZ		;MAKING PERM SEL, SO DON'T WAIT
	TRNN TAC,20000
	PUSHJ P,ADSMWT		;WAIT FOR TEMP SEL TO FINISH
ADSSCZ:	ONSCN				;TURN ON SCANNER CHANNEL
	POPJ P,

;PAGE INTERRUPTIBLE, SO CHECK FOR PAGING GOING ON
ADSMP1:	SKIPN PAGNOW
	POPJ P,
	TLO AC2,ASPAGN		;SET PAGING NOW BIT
	MOVEI AC3,ASPAGC	;SELECT PAGING CHANNEL
	HRRZ DSER,ASBTAB(AC1)
	JUMPE DSER,CPOPJ	;NOT BEEP IN PROGRESS
	TLO AC2,ASDBEP		;SET DELAYED BEEP BIT
	SETZM ASBTAB(AC1)	;FLUSH BEEP
	POPJ P,

;BEEP INTERRUPTIBLE, SO CHECK FOR DELAYED BEEP OR BEEP IN PROGRESS
ADSMP2:	TLNE AC2,ASDBEP		;SKIP IF NO DELAYED BEEP
	JRST ADSMP5
	HRRZ DSER,ASBTAB(AC1)
	JUMPE DSER,CPOPJ	;NO BEEP IN PROGRESS EITHER
	MOVEI AC3,ASBEPC	;CONTINUE WITH BEEP
	POPJ P,
ADSMP5:	TLNE AC2,ASPAGN
	POPJ P,			;PAGING TAKES PRECEDENCE
	TLZ AC2,ASDBEP		;CLEAR DELAYED BEEP BIT
	MOVEI AC3,ASBPTM
	MOVEM AC3,ASBTAB(AC1)	;START UP BEEP
	MOVEI AC3,ASBEPC
	POPJ P,

;MAKE TEMP SEL (SCNOFF)
ADSMT:	MOVE AC2,ASTAB(AC1)
	TRNE AC2,-1		;SKIP IF NO TEMP SEL IN PROG OR INF TEMP SEL IS
	TLNE TAC,100000		;SKIP IF GRONK IS OFF
	JRST ADSMT1		;OK TO MAKE NEW TEMP SEL NOW
	JRST ADSSCZ		;TEMP SEL IN PROG, DON'T GRONK, DON'T WAIT (NOOP)
ADSMT1:	MOVS TAC,TAC		;NEW CH # IN LOW 4 BITS, DURATION IN LH
	LDB AC3,[000400,,TAC]	;NEW CHAN SELECTION
	DPB AC3,[ASTMPP,,AC2]
	LDB TAC1,[130200,,TAC]	;NEW PAGING DISPOSITION
	CAIN TAC1,3
	MOVEI TAC1,1		;CHANGE 3 INTO 1
	DPB TAC1,[ASPGDP,,AC2]	;SET PAGE DISP
	LDB TAC1,[110200,,TAC]	;NEW BEEP DISPOSITION
	DPB TAC1,[ASBPDP,,AC2]	;SET BEEP DISP
	TRNN TAC,400		;SKIP IF NOT PAGE INTERRUPTIBLE
	PUSHJ P,ADSMP1
ADSMT3:	CAIN TAC1,3
	JRST ADSMT4		;DELAY BEEP
	CAIE TAC1,1		;SKIP IF BEEP UNINTERRUPTIBLE
	JRST [	PUSHJ P,ADSMP2
		JRST ADSMT6]
	TLZ AC2,ASDBEP
	SETZM ASBTAB(AC1)
ADSMT6:	HLR AC2,TAC		;DURATION
	TLO AC2,ASTEMP		;SET TEMP SEL BIT
	JRST ADSMP4

;DELAY BEEP MODE
ADSMT4:	HRRZ DSER,ASBTAB(AC1)
	JUMPE DSER,ADSMT6
	TLO AC2,ASDBEP		;SET DELAYED BEEP BIT
	SETZM ASBTAB(AC1)	;FLUSH BEEP NOW
	JRST ADSMT6

;WAIT UNTIL TEMP SELECTION IS DONE
ADSMW2:	OFFSCN				;TURN OFF SCANNER CHANNEL
ADSMWT:	MOVE AC2,ASTAB(AC1)
	TLNE AC2,ASHANG
	JRST ADSMW1
	MOVEI AC3,-1
	TDNN AC3,ASBTAB(AC1)	;SKIP IF BEEPING NOW
	TLNE AC2,ASPAGN		;SKIP IF NOT PAGING NOW
	JRST ADSMW1		;BEEP OR TEMP SEL - WAIT
	TRNN AC2,-1		;NOT BEEPING OR PAGING,TEST FOR TEMP SEL TO WAIT FOR
	POPJ P,			;NOTHING TO WAIT FOR
ADSMW1:	TLO AC2,ASHANG
	MOVEM AC2,ASTAB(AC1)
	MOVEI AC2,IOWQ
	MOVNM AC2,JOBQUE(J)
	ONSCN				;TURN ON SCANNER CHANNEL
	PUSHJ P,WSCHED		;GO INTO IOWQ
	JRST ADSMW2

;READ AS STATUS INTO AC
ADSMRD:	OFFSCN				;TURN OFF SCANNER CHANNEL
	MOVE AC2,PAGNOW
	HRRZ AC3,ASBTAB(AC1)
	MOVE TAC1,ASTAB(AC1)
	ONSCN				;TURN ON SCANNER CHANNEL
	HRR TAC,TAC1		;READ BACK DURATION
	TLZ TAC,177777
	TLNE TAC1,ASTEMP
	TLO TAC,400		;TEMP MAP IN EFFECT NOW
	JUMPE AC2,.+2
	TLO TAC,200		;THERE'S A PAGE GOING ON
	TLNE TAC1,ASPAGN
	TLO TAC,100		;WE'RE PAGING ON THIS LINE
	JUMPE AC3,.+2
	TLO TAC,40		;WE'RE BEEPING THIS LINE NOW
	TLNE TAC1,ASDBEP
	TLO TAC,20		;WE'RE GOING TO BEEP IT LATER
	JUMPGE TAC,ADSMR1	;JUMP IF READING PERM
	LDB AC2,[ASTMPP,,TAC1]	;TEMP CHAN SEL
	LDB AC3,[ASBPDP,,TAC1]	;TEMP BEEP DISP
	LDB TAC1,[ASPGDP,,TAC1]	;TEMP PAGE DISP
ADSMR2:	LSH TAC1,2
	IOR TAC1,AC3
	LSH TAC1,9
	IORI TAC1,200000(AC2)
	TSO TAC,TAC1
	JRST STOTAC

ADSMR1:	LDB AC2,[ASPRMP,,TAC1]	;PERM CHAN SEL
	LDB AC3,[ASPBUP,,TAC1]	;PERM BEEP UNINTERRUPTIBLE BIT
	LDB TAC1,[ASPPUP,,TAC1]	;PERM PAGE UNINTERRUPTIBLE BIT
	JRST ADSMR2

;BEEP AC,
;AC HAS TTY NUMBER TO BEEP OR -1 FOR YOURSELF
↑BEEP:	JUMPGE TAC,BEEP1
↑BEEPJB:HRRE TAC,JBTLIN(J)	;QXFER ENTERS HERE WHEN TIME TO TELL USER WE IS DONE
	JUMPL TAC,CPOPJ		;DETACHED
BEEP1:	ANDI TAC,177
	SUBI TAC,DPYL0
	JUMPL TAC,BEEPND	;NOT A DPY, TRY ↑G
	CAIL TAC,DPYNUM+DDNUM
	JRST BEEPND
BEEPTK:	OFFSCN				;TURN OFF SCANNER CHANNEL
	MOVE AC1,ASTAB(TAC)
	LDB AC2,[ASBPDP,,AC1]	;GET TEMP BEEP DISP
	TLNN AC1,ASTEMP		;SKIP IF TEMP
	LDB AC2,[ASPBUP,,AC1]	;PERM BEEP DISP
	TRNE AC2,1		;SKIP IF INTERRUPTIBLE
	JRST BEEPU
	TLNN AC1,ASPAGN		;SKIP IF PAGING NOW
	JRST BEEPNP
BEEPDX:	TLO AC1,ASDBEP		;SET DELAYED BEEP
	MOVEM AC1,ASTAB(TAC)
BEEPX:	ONSCN				;TURN ON SCANNER CHANNEL
	POPJ P,

BEEPNP:	MOVEI AC2,ASBPTM
	MOVEM AC2,ASBTAB(TAC)
	MOVEI AC3,ASBEPC
	HRLI AC3,(TAC)
	DATAO AS,AC3
	JRST BEEPX

BEEPU:	TLNE AC1,ASTEMP		;SKIP IF PERM
	CAIN AC2,1
	JRST BEEPX		;NOT INTERRUPTIBLE, SORRY
	JRST BEEPDX		;TEMP SEL (INF OR OTHERWISE), SET DELAYED BEEP

BEEPND:	MOVEI LINE,DPYL0(TAC)	;BEEP ADDRESSED TO NON-DPY:
	PUSHJ P,GETDBA		;FIND OR CREATE DDB
	POPJ P,			;NO SUCH TTY OR NO DDBS AVAILABLE
IFN FTDM,<
	HLL LINE,LINTAB(LINE)	;Get bits
	TLNE LINE,DMLIN
	JRST BEEPDM
BEEPN2:
>;FTDM
	MOVEI CHR,7		;GOBBLE A BELL
	PUSHJ P,OUTCHR		;SOCK IT TO HIM!
	JRST TYPTST

IFN FTDM,<
BEEPDM:	SKIPN DAT,LETAB(LINE)	;Better have a dpy header
	JRST BEEPN2		;Can't happen
	PUSHJ P,GETQ
	HRLI DAT,DMQUOT!DMATXY	;Quote the bell and don't care where cursor is
	MOVSM DAT,QFLAGS(AC1)
	MOVE AC2,[POINT 7,[ASCII /π↓↓↓↓/]]
	MOVEM AC2,QTAKR(AC1)
	MOVEI AC2,5		;Send one bell and 4 padding chars
	MOVEM AC2,QDMCNT(AC1)
	MOVEI AC2,DMXY(DAT)
	MOVEM AC2,QXYLOC(AC1)	;Use actual XY position to mean don't care
	SETZM QCOUNT(AC1)	;Don't wake anyone
	MOVEI AC2,DMSPPT-QLINK(DAT)
	PUSHJ P,QDM		;Queue the beep in special queue
	JRST STRTDM
>;FTDM


;RESET AUDIO SWITCH MAP TO PERMANENT SETTING
;CALLED BY ADSMAP WITH AC=-1 AND BY RESET
↑ADSRES:
	HRRE AC1,JBTLIN(J)	;RESET JOB TO PERMANENT ADS MAP
	JUMPL AC1,CPOPJ		;DETACHED
	SUBI AC1,DPYL0
	JUMPL AC1,CPOPJ		;NOT DD OR DPY
	CAIL AC1,DPYNUM+DDNUM
	POPJ P,			;NOT DD OR DPY
ADSRE2:	MOVEI TAC,0
	OFFSCN				;TURN OFF SCANNER CHANNEL
	LDB AC2,[ASPPUP,,ASTAB(AC1)]
	DPB AC2,[POINT 1,TAC,6]
	LDB AC2,[ASPBUP,,ASTAB(AC1)]
	DPB AC2,[POINT 1,TAC,8]
	LDB AC2,[ASPRMP,,ASTAB(AC1)]
	DPB AC2,[POINT 4,TAC,17]
	TLO TAC,360000
	JRST ADSRE1
;RECIML
;SPECIAL CODE FOR IMLACS (JHS CODE REPLACED BY BO)

RECIML:	TLZE	IOS,IMLTTY		;Flag left from preceding char?
	JRST	RECIM1			;Yes.  Add the bucky bits.
	TRNN	CHR,200			;No.  Test the 8th bit.
	JRST	RECIM2			;Off.  Just plain data.
	TLO	IOS,IMLTTY		;On.  Flag it as extra special.
	CAIL	CHR,241			;Is it a prefix meaning bucky bits?
	CAILE	CHR,243
	JRST	RECIM2			;No.
	DPB	CHR,[POINT 2,IMLHAC(DDB),34]	;Save the bucky bits and set IMLTTY
	MOVEM	IOS,DEVIOS(DDB)			;flag for the next char
	POPJ	P,				;and get out fast.

RECIM1:	LDB	UCHN,[POINT 2,IMLHAC(DDB),34]
	JRST	RECIM2
;TYPX, COMSET
;ROUTINE TO TYPE X IF LINE CANNOT GET INTO SYSTEM

TYPX:	SUB	P,[1,,1]
	ANDI	CHR,177
	CAIN	CHR,"X"		;CHAR. RECEIVED AN "X"
	POPJ	P,			;YES, MAY BE ECHO, DISMISS INT.
	MOVEI	CHR,"X"
	JRST	TYPL			;TYPE OUT "X"

;ROUTINE TO WAKE UP COMMAND DECODER IF TPMON IS SET

↑COMSET:TLNN	IOS,TTYDTC		;DTACHED GUYS CAN'T SAY ANYTHING!
	TLNN	IOS,TPMON		;MONITOR MODE?
	POPJ	P,			;NO, NOT MONITOR COMMAND
	MOVE	TAC,DEVMOD(DDB)		;GET SOME GOOD BITS
	TLNN	TAC,TTYATC		;IF NOT A CONSOLE
	TRNN	TAC,ASSCON!ASSPRG	;AND ASSIGNED BY PROGRAM OR CONSOLE
	JRST	.+2
	POPJ	P,			;THEN HE CAN'T TYPE COMMANDS
	MOVSI	IOS,IOFST
	IORB	IOS,DEVIOS(DDB)
	MOVSI	TAC,COMBIT		;SET SIGN BIT
	TDNN	TAC,TTYTAB(LINE)	;SKIP IF COMMAND BIT IS ON
	AOS	COMCNT			;COUNT ANOTHER COMMAND WE HAVE
	IORM	TAC,TTYTAB(LINE)	;IN TTY TRANSLATOR TABLE
IFN FTTTYBUG,<
	PUSHJ	P,COMBCK
	PUSHJ	P,CNTCOM		;CALL THE DRD
>
	POPJ	P,
;TTEDIT TTIPUT DUPLEX DUPLX1 INBFUL AOJDPX TTPT2

;TTY KEYBOARD EDITOR ROUTINE
;UPON RECEIPT OF A CHARACTER, THIS ROUTINE DETERMINES WHAT TO DO
;WITH IT: WHETHER IT'S A SPECIAL CHARACTER NEEDING SPECIAL ECHOING,
;WHETHER SOME OTHER CHARACTER IS TO BE STORED IN ITS PLACE, WHETHER
;IT IS A BREAK CHARACTER (LINE TERMINATOR), OR WHETHER THE CHARACTER
;TYPED IS A SIGNAL TO UNDERTAKE SOME SPECIAL ACTION.
;IN ANY CASE, ALL SPECIAL ACTION, INCLUDING DUPLEXING TAKES PLACE ON
;THE LEVEL OF THIS ROUTINE.
;	THIS ROUTINE CALLS SPCHEK, WHICH MAKES USE OF THE  SPECIAL
;CHARACTER TABLE, SPCTAB. TO MAKE ANY CHANGES IN THE ACTION GENERATED
;BY SPECIFIC CHARACTERS MAKE THE ALTERATIONS REQUIRED BY THE
;COMMENTS DESCRIBING SPCTAB.  NOTE THAT IF A CHARACTER IS TO DISPATCH
;TO A "SPECIAL ACTION ROUTINE" OR A SPECIAL ECHO ROUTINE, THE LEFT
;HALF OF THE CORRESPONDING CHARACTER-WORD MUST HAVE SPACTN
;SET  AND THE ADDRESS OF THE SPECIAL ROUTINE MUST BE
;ASSEMBLED INTO THE RIGHT HALF OF THE WORD.
;CALL	HAVE 7-BIT ASCII CHARACTER IN CHR
;	LDB	HPOS,PHPOS
;	MOVEI	DAT,TTIBUF(DDB)
;	PUSHJ	P,TTEDIT
;	RETURN WITH ACTION DONE, SYNC (LH IOS) SET IF BREAK CHAR. STORED

TTEDIT:	PUSHJ	P,ADJHP		;ADJUST HP AND CHECK SPECIAL
	JFCL
	TLNN	LINE,IMLIN		;IMLAC?
	JRST	TTEDT2			;NOT AN IMLAC.
	TLZE	IOS,IMLTTY		;TEST CONTROL FLAG.
	JRST	TTEDT0			;NO SPECIAL ACTIVATION IF ON.
	CAIN	CHR,177			;LEAVE SPACTN FOR RUBOUT.
	JUMPE	UCHN,TTEDT2		;EXCEPT WITH BUCKY BITS
	TLNN	TAC,IMLCHR		;PREVENT SPACTN ON ~ AND α
	TLNN	TAC,ALLSPA		;AND ANYTHING ELSE THAT'S NOT
	TLZ	TAC,ALLSPA!SPACTN!ECHSUP!SPHPOS		;ALWAYS SPECIAL.
TTEDT2:	TLNE	LINE,SPCBRK		;SPECIAL ACTIVATION MODE?
	TLNE	IOS,TPMON
	JRST	TTEDT0
	PUSH	P,TAC
	PUSHJ	P,SPCACT
	TLO	IOS,SYNC
	POP	P,TAC
	TLNN	TAC,ALLSPA
	TLNN	IOS,SYNC
	CAIA
	TLZ	TAC,SPACTN		;INHIBIT ANY SPECIAL ACTION IF A BREAK
	JRST	TTEDT1
TTEDT0:	TLNE	TAC,BREAKB!FCSBRK
	TLO	IOS,SYNC		;IT'S A BREAK CHAR.
TTEDT1:	MOVEM	IOS,DEVIOS(DDB)		;SET SYNC
	JUMPL	TAC,(TAC)		;JUMP IF CHARACTER HAS SPECIAL DISPATCH
TIPACK:	CAIG	CHR,"Z"+40
	CAIGE	CHR,"A"+40		;LOWER CASE LETTER?
	JRST	TTIPUT			;NO
	TLNN	LINE,FCS		;LOWERCASE.  FULL CHARACTER SET TTY?
	TRZ	CHR,40			;NO. MAKE CHAR UPPER CASE
TTIPUT:	TLZE	LINE,ROBTPD		;HAVE WE BEEN DELETING?
	PUSHJ	P,BSECHO		;YES. OUTPUT A BACKSLASH
TTIPT1:	DPB	UCHN,[POINT 2,CHR,28]	;PUT IN CTRL. BITS.
TTPT2:	PUSHJ	P,PUTCHI		;PUT CHAR IN INPUT BUFFER
	JRST	INBFUL			;IT DIDNT FIT
	TLNN	TAC,ECHSUP		;SHOULD THIS CHAR BE ECHOED?
DUPLEX:	TLNE	LINE,FULTWX		;IS THIS LINE ECHOING ITSELF?
	JUMPE	UCHN,CPOPJ		;YES, DON'T ECHO UNLESS CTRL BITS ON.
DUPLX2:	TLNN	IOS,TPMON		;SHOULD ECHO IF IN MONITOR MODE
	TRNN	IOS,NOECHO		;AND UNLESS USER SAYS NO, IN USER MODE
	JRST	DUPIML			;SO ECHO IT.
	POPJ	P,			;DONT ECHO IF REQUESTED NOT TO BY USER

AOJDPX:	ADDI	HPOS,1
DUPLX1:	PUSH	P,TAC
	MOVEI	TAC,0			;NO UPARROW STUFF FROM THIS ENTRY
	PUSHJ	P,DUPLX2
	POP	P,TAC
	POPJ	P,

INBFUL:	CAIN	CHR,600			;CHAR WONT FIT. WAS IT ↑C?
	JRST	CNCTS1			;YES. PANIC OUT OF THIS BIND
	MOVEI	CHR,7			;NO. JUST ECHO BELL TO SHOW LOSS
	JRST	PUTCHO			;OUTPUT BELL, IF NOT  DPY.

DUPIML:	JUMPE	UCHN,DUPIM4		;IF BUCKY BITS OFF
	TRNN	IOS,NOECHB		;OR NOT TO BE ECHOED
	TLNN	LINE,IMLIN		;OR NOT AN IMLAC,
	JRST	DUPIM4			;JUST ECHO THE CHAR.
	PUSH	P,CHR
	TRNN	UCHN,1			;<CTL> BIT...
	JRST	DUPIM2
	MOVEI	CHR,177			;ECHO [BS] [VT].
	PUSHJ	P,PUTCHO
	MOVEI	CHR,13
	PUSHJ	P,PUTCHO
	TRNN	UCHN,2			;<META>...
	JRST	DUPIM3
DUPIM2:	MOVEI	CHR,177			;ECHO [BS] [FF].
	PUSHJ	P,PUTCHO
	MOVEI	CHR,14
	PUSHJ	P,PUTCHO
DUPIM3:	POP	P,CHR			;NOW ECHO THE CHAR.
	JRST	PUTCHO

DUPIM4:	TLNE	TAC,ARRBIT		;BH 4/27/75
	TLNN	LINE,ECHARR		;IF AN UPARROW CHARACTER
	JRST	PUTCHO			;AND IN THE RIGHT MODE,
	PUSH	P,CHR			;DO IT!
	MOVEI	CHR,"↑"
	PUSHJ	P,PUTCHO
	POP	P,CHR
	ADDI	CHR,100
	JRST	PUTCHO
;CONTC, CONTOB, CONTO, CONTB, ALTMOD, TTYUNH
;CALLED WITH A JUMPL TAC,(TAC), WHERE TAC IS LOADED FROM SPCTAB
;SPECIAL CHARACTER HANDLING ROUTINES


CONTC:	PUSHJ	P,DELETL		;SINCE PEOPLE WANT FREE ↑U
	TLNN	LINE,DDDLIN!DISLIN!DMDLIN; IF THIS IS A DPY (CAN DPYS REALLY GET HERE?--ME)
	JRST	.+3
	JUMPG	UCHN,.+2		;AND IF NO CTRL BITS ARE ON,
	PUSHJ	P,CNCTS1		;PROCESS CONTROL C IMMEDIATELY.
	MOVE	TAC,SPCTAB		;SINCE DELETL CLOBBERS TAC
	PUSHJ	P,TTPT2			;PLACE IN BUFFER.
	MOVEI	CHR,3
	PUSHJ	P,CNTLEC
	JRST	CRLFEC

CONTZ:	PUSHJ	P,CNTLEC		;OUTPUT ↑C OR ↑Z
	PUSHJ	P,CRLFEC		;OUTPUT A CRLF
	MOVEI	CHR,3B28!12		;CHANGE TO INTERNAL CODE.
	TLO	IOS,SYNC
	JRST	TTPT2			;ACTIVATE BUT DON'T STORE

CONTOB:	MOVEI	CHR,"O"-100		;INVENT A ↑O.
CONTO:	PUSHJ	P,SETBF2		;CLEAR THE OUTPUT BUFFER
	MOVEI	IOS,IOSUPR		;SET TO JUNK FURTHER OUTPUT
	XORB	IOS,DEVIOS(DDB)
	JRST	CONTU1			;ECHO, ETC.

CONTU:	TLNE	IOS,DDTM		;IN DDTMODE,
	JRST	TTIPUT			; PASS THIS CHARACTER
	TLZ	LINE,ROBTPD		;NO MORE BACKSLASH
	PUSHJ	P,DELETL		;↑U DELETES INPUT LINE
CONTU1:	PUSHJ	P,CNTLEC		;ECHO ↑O OR ↑U
	JRST	CRLFEC			;OUTPUT A CRLF AND RETURN WITHOUT
					; STORING THE ↑O OR ↑U

ALTMOD:	HRRI	TAC,(CHR)		;SAVE WHICH KIND OF ALTMOD
	TLNN	LINE,IMLIN
	MOVEI	CHR,44			;ECHO A $ EXCEPT ON IMLACS.
	PUSHJ	P,AOJDPX
	MOVEI	CHR,(TAC)		;RESTORE THE CHARACTER
	JRST	TTIPUT			;STORE THE CHARACTER

;FOLLOWING CHANGE BY BO ON RPH'S ADVICE
;CONTF:	TLCA	LINE,FCS		;COMPLEMENT FCS ON ↑F
;CONTB:	TLC	LINE,FULTWX		;COMPLEMENT FULTWX ON ↑B
;	POPJ	P,			;AND RETURN WITHOUT STORING THESE

;CONTB1:TLCA	LINE,FULTWX		;FLUSHED 9/25/74 BH
;CONTF:	TLC 	LINE,FCS		;FLUSHED SINCE UNREFERENCED 2/23/76 ME
;	POPJ	P,

CONTB:
;BH	TLNE	LINE,DISLIN!DDDLIN!PTYLIN
;BH	JRST	CONTB1
	LDB	HPOS,PHPOS		;↑B ISN'T ECHOED, SO DON'T CHANGE HPOS
					;(UNDOES ADJHP) - REG 2/13/76
	TLNE	LINE,TLKRNG		;DON'T ALLOW HOLDING IF TALKING.
	POPJ	P,			;TALKING
TTYUNH:	TLCE	IOS,TTYHLD		;Toggle the hold flag.
	TLNE	LINE,PTYLIN		;BH
	JRST	.+2			;BH
	TLZ	IOS,TOIP		;If it was on, turn off TOIP.  The
	MOVEM	IOS,DEVIOS(DDB)		;STO IOS BACK
	POPJ	P,			;next call to TYPTST will restart
					;the output.
;END BO
;RUBOUT RUBOU1 RUBOU2 CONTK CONTL SIMFF SIMFF1 CONTI1 

RUBOUT:	TLNE	IOS,TPMON		;IN MONITOR MODE, NOT A BREAK CHAR
	JRST	RUBOU2			; AND IGNORE BSACT
	TDNE	IOS,[DDTM,,BKSP]
	JRST	TTIPT1			;STORE RUBOUT IF DDT OR FCS
	MOVEI	IOS,BSACT		;DOES HE WANT TO GET BS FROM
	TDNN	IOS,ACTMOD(DDB)		; BEGINNING OF LINE?
	JRST	RUBOU2			;NOPE
	LDB	IOS,PLSTLC		;YES
	CAME	IOS,PCTR(DAT)		;IS THIS THE BEGINNING OF THE LINE?
	JRST	RUBOU2			;NO
	MOVE	IOS,DEVIOS(DDB)		;YES, RESTORE IOS AND
	JRST	TTIPUT			; NOW GO STUFF THE BS UP HIS BUFFER

RUBOU2:	MOVSI	IOS,SYNC		;THIS RO IS NOT A BREAK, IT IS A DELETE.
	ANDCAB	IOS,DEVIOS(DDB)
	LDB	CHR,PUTR(DAT)		;GET LAST CHAR IN
	PUSHJ	P,DCPUTR		;BACK UP TIPUTR
	JRST	RUBOU1			;IT'S EMPTY ALREADY
	TLON	LINE,ROBTPD		;MARK IN RUBOUT SEQUENCE
	PUSHJ	P,BSECHO		;AND OUTPUT BACKSLASH IF FIRST
	PUSHJ	P,ADJHP			;ADJUST HPOS FOR THIS CHR
	JFCL				;IGNORE SKIP RETURN
	JRST	DUPLX2			;DUPLEX (POSSIBLY WITH UPARROW)

RUBOU1:	TLZE	LINE,ROBTPD		;END OF INPUT STREAM REACHED
	PUSHJ	P,BSECHO		;OUTPUT A BACKSLASH
	JRST	CRLFEC			;AND A CR LF

CONTK:	HRRI	TAC,4			;HERE ON V TAB
	SKIPA
CONTL:	HRRI	TAC,10			;HERE ON FORMFEED
	TLNE	LINE,PTYLIN		;THIS TTY HAVE VERT MECHANICS?
	JRST	TTIPUT			;YES, PUT CHAR IN BUFFER AND ECHO IT
SIMFF:	TLO	TAC,ECHSUP		;DON'T OUTPUT FF OR VT TO A 33
	PUSHJ	P,TTIPUT		;PUT IT IN BUFFER
	MOVEI	CHR,12			;SIMULATE WITH LF'S
	JRST	SIMFF1

CONTI1:	MOVEI	CHR,1			;SYNCHRONOUS IDLE CHARACTERS
SIMFF1:	PUSHJ	P,DUPLX1		;OUTPUT ECHO OF LF OR IDL
	TRNE	TAC,17			;DONE YET?
	SOJA	TAC,.-2			;NO. OUTPUT MORE
	POPJ	P,			;DONE
;CONTI, CONTP

CONTI:	TLNE	LINE,DISLIN!DDDLIN!IMLIN!DMDLIN
	JRST	TTIPUT			;ECHO AND RETURN FOR DISPLAYS
	TLNE	LINE,PTYLIN
	TLNE	LINE,IMPBIT
	CAIA				;NOT A PTY, OR AN IMP-PTY
	JRST	TTIPUT			;ECHO AND RETURN FOR LOCAL PTYS
	LDB	HPOS,PHPOS
	ANDI	HPOS,7
	CAIE	HPOS,7			;IF ONLY 1, WE WILL CONVERT TO SPACE
	TLNE	LINE,TBXPND		;FORCING TAB EXPANSION?
	TLO	TAC,ECHSUP		;YES. DON'T OUTPUT TAB TO 33
	PUSHJ	P,TTIPUT		;PUT IN BUFFER AND MAYBE ECHO
	TLNE	LINE,TBXPND		;EXPANDING TABS?
	JRST	CONTI2			;YES
	LDB	CHR,PHPOS		;WHERE WAS TTY BEFORE TAB
	ANDI	CHR,7			;JUST LOW PART FOR INDEX
	MOVEI	TAC,1			;ASSUME 1
	XCT	(CHR)[	AOJA TAC,CONTI1	;8 SPACES-2 IDLES
			JRST CONTI1	;7 SPACES-1 IDLE
			JRST CONTI1	;6 SPACES-1 IDLE
			JRST CONTI1	;5 SPACES-1 IDLE
			JRST CONTI1	;4 SPACES-1 IDLE
			POPJ P,		;3 SPACES-0 IDLES
			POPJ P,		;2 SPACES-0 IDLES
			JFCL	]	;1 SPACE -CONVERT TO SPACE (OR CTY WILL MISS TAB STOP)
CONTI2:	MOVEI	CHR,40			;SPACES FOR THE 33'S
	LDB	HPOS,PHPOS		;WHERE WAS I BEFORE TAB?
	PUSHJ	P,AOJDPX		;OUTPUT A SPACE
	TRNE	HPOS,7			;AT A TAB STOP?
	JRST	.-2			;NO. MORE SPACES.
	POPJ	P,			;RETURN FROM TTEDIT

REPEAT 0,< ;OLD CODE FOR CONTROL P - TOGGLE STATE OF HARDWARE TABS
CONTP:	MOVE	TAC,LINBIT(LINE)	;GET HIS INITIAL LINE BITS
	TLNE	TAC,TBXPND		;CAN ONLY TOGGLE IF HE HAS HARDWARE TABS!!!
	JRST	NCONTP			;NO CAN DO
	TLC	LINE,TBXPND		;INVERT STATE OF TABS!
	POPJ	P,

NCONTP:	SETZ TAC,			;MAKE SURE IT ECHOS!
	JRST	TTIPUT			;AND BACK TO THE MAIN STREAM
>
;CRLFEC, CRLF, CNTLEC

CRLFEC:	MOVEI	HPOS,0			;ECHO A CR LF, SAVING CHR
	PUSH	P,CHR
	MOVEI	CHR,15			;CARRIAGE RETURN
	PUSHJ	P,DUPLX1		;OUTPUT IT
	MOVEI	CHR,12			;LINE FEED
	PUSHJ	P,DUPLX1		;OUTPUT THAT TOO
CHPOPJ:	POP	P,CHR			;RESTORE CHR
	POPJ	P,

CNTLEC:	HRRI	TAC,100(CHR)		;SAVE UN-CNTL CHARACTER
	MOVEI	CHR,"↑"
	PUSHJ	P,AOJDPX
	MOVEI	CHR,(TAC)		;TYPE ↑ CHAR
	PUSHJ	P,AOJDPX
	TRZ	CHR,100			;RESTORE IT TO A CNTL CHAR
	POPJ	P,

CRLF:	MOVEI	HPOS,0			;HERE ON INPUT OF A CARRIAGE RETURN
	TLNE	LINE,PTYLIN		; IS THIS A PTY
	JRST	CRLFIP			; YES, TEST XON ALWAYS
	TLNE	IOS,TPMON		; ALWAYS GIVE LF AFTER CR IN MON. MODE
	JRST	CRLFMM
CRLFIP:	TLNE	LINE,XON		;IF PAPER TAPE, NO FREE LF
	JRST	TTIPUT			;JUST STORE THE CR
CRLFMM:	PUSHJ	P,TTIPUT		;ORDINARILY, STORE AND GO ON HERE
	MOVEI	CHR,12			;BY ADDING A LF
	MOVSI	IOS,SYNC		;WHICH IS AN ACTIVATOR
	IORB	IOS,DEVIOS(DDB)
	TLNN	LINE,FULTWX		;IF NOT SELF ECHOING,
	JRST	TTIPUT			;THIS WILL GIVE LF ECHO
	PUSHJ	P,TTIPUT		;OTHERWISE, THIS WONT
	JRST 	DUPLX1			;BUT THIS WILL
;CNCTST, CNCMOD

CNCTST:	TLNE	LINE,IMLIN
	TLZE	IOS,IMLTTY		;Char code 3 from an IMLAC needs
	CAIA
	POPJ	P,			;IMLTTY on to be a ↑C.
	MOVE	TAC,DEVMOD(DDB)		;BH 10/23/74
	TLNN	TAC,TTYATC		;IF THIS TTY IS NOT USED AS A CONSOLE
	TRNN	TAC,ASSCON+ASSPRG	;(I.E., ASSIGNED AS A DEVICE AND NO TTYATC)
	JRST	.+2
	POPJ	P,			;LEAVE IT AS A 3
	MOVEI	CHR,600			;INVENT INTERNAL CODE FOR ↑C.
	LDB	TAC,PJOBN
	MOVE	TAC,JBTSTS(TAC)
	TLNE	TAC,JACCT		;REG 11/26/73 NO REASON TO LET PTYS THROUGH
	MOVEI	CHR,33			;SEND ALTMODE INSTEAD
	LDB	TAC,TIPUTR(DDB)
	CAIE	TAC,600
	POPJ	P,
CNCTS1:	PUSHJ	P,SETBFI		;CLEAR INPUT BUFFER.

CNCMOD:	MOVE	IOS,DEVIOS(DDB)
	TRNE	IOS,IOSUPR		;SUPPRESSING OUTPUT?
	PUSHJ	P,SETBF2		;YES, CLEAR OUTPUT BUFFER
	MOVE	IOS,[XWD DDTM!IO!USRB,IOSUPR!MERTPO!MERTP1]
	ANDCAM	IOS,DEVIOS(DDB)
	MOVSI	IOS,TPMON+IOFST
	IORB	IOS,DEVIOS(DDB)
	POPJ	P,
;BSECHO, DCPUTR, DELETL
;ROUTINE TO ECHO BACK-SLASH

BSECHO:	PUSH	P,CHR			;*
	MOVEI	CHR,"\"
	PUSHJ	P,AOJDPX
	JRST	CHPOPJ

;ROUTINE TO DECREMENT PUTR

↑DCPUTR:
	LDB	TAC,PLSTLC		; CHECK FOR NONE TO DELETE
	CAMN	TAC,PCTR(DAT)
	POPJ	P,

	MOVSI	TAC,110000
	ADD	TAC,PUTR(DAT)		;*
	TLNE	TAC,400000
	ADD	TAC,[XWD 337777,-1]
	MOVEM	TAC,PUTR(DAT)
	AOS	FCTR(DAT)
	AOS	TAC,PCTR(DAT)
	CAIG	TAC,TTICHR		;*
	JRST	CPOPJ1			;*
	SUBI	TAC,TTICHR		;*
	MOVEM	TAC,PCTR(DAT)
	MOVEI	TAC,STTIBF
	ADDM	TAC,PUTR(DAT)		;*
	JRST	CPOPJ1

;ROUTINE TO DELETE CURRENT LINE (↑U)

DELETL:	LDB	TAC,PLSTLC		;WHERE WAS LAST BREAK?
	MOVEM	TAC,TIPCTR(DDB)		;STORE COUNT
	PUSHJ	P,TBYTEP		;CONVERT TO A BYTE POINTER
	MOVEM	TAC,TIPUTR(DDB)		;SAVE POINTER
	JRST	TRESC1			;GO COMPUTE TIFCTR
;DOTALK, NOTALK
IFN FTTALK,<
DOTALK:	ANDI	CHR,177
	SKIPN	DDB,TTYTAB(LINE)
	POPJ	P,
IFN FTTKBG,<
	HLRZ	TAC,DDB		;BH 3/15/74 BUG TRAP FOR INCOMPLETE LOOP
	ANDI	TAC,177		;BH JUST THE LINE NUMBER
	SKIPN	TTYTAB(TAC)	;BH TAC IS LINE # TALKER LINKED TO
	JRST	DOTALX		;BH HIS DDB GONE ALTOGETHER (CAN'T HAPPEN...)
	HLRZ	HPOS,TTYTAB(TAC);BH ELSE GET HIS LINK
	ANDI	HPOS,177	;BH JUST THE LINE NUMBER
	CAIN	HPOS,(LINE)	;BH OK IF WE'RE ALL THE SAME
	JRST	DOTALY		;BH
	CAIN	HPOS,(TAC)	;BH COMPARE TO HIMSELF
	JRST	DOTALX		;BH OOPS, THEY'RE THE SAME!
>;FTTKBG
DOTALY:	CAIE	CHR,0
	CAIN	CHR,3
	JRST	NOTALK
	MOVE	UUO,LINTAB(LINE);SAVE TALKER'S XON BIT
	TLZ	LINE,-1		;NO BITS PLEASE
	PUSH	P,LINE
DOTAL1:	LDB	LINE,PTALK
	HRRZ	DDB,TTYTAB(LINE)
	CAMN	LINE,(P)	;BACK TO OURSELVES YET?
	JRST	DOTAL2		;YES, WE ARE SPECIAL
	JUMPE	DDB,DOTAL1	;SKIP GUYS WITHOUT DDBS
	PUSH	P,CHR
	CAIN	CHR,7		;Is this a bell?
	CAIL	LINE,DPYL0+DPYNUM+DDNUM ;Yes, is rcvr maybe a display?
	JRST	NOBELL		;No
	MOVEI	TAC,-DPYL0(LINE);Get display index
	JUMPL	TAC,NOBELL	;Jump if not a display
	PUSHJ	P,BEEPTK	;Note that we don't beep sender of bell, only rcvr
NOBELL:	PUSHJ	P,PUTCHO
	MOVE	CHR,(P)		;GET CHAR
	TLNN	UUO,XON		;IF TALKER HAS XON OR
	CAIE	CHR,15		;IF NOT CR,
	JRST	DOTAL3		;THEN NO LF
	MOVEI	CHR,12
	PUSHJ	P,PUTCHO	;YES, SEND IT
DOTAL3:	MOVE	IOS,DEVIOS(DDB)
	PUSHJ	P,TYPTST
	POP	P,CHR
	JRST	DOTAL1

DOTAL2:	HLL	LINE,LINTAB(LINE)	;GET OUR CHARACTERISTICS
	MOVEM	CHR,(P)			;REPLACE SAVED LINE WITH CHR
	TLNN	LINE,FULTWX
	PUSHJ	P,PUTCHO
	POP	P,CHR
	CAIN	CHR,15			;NEED LF?
	TLNE	LINE,XON		;MAYBE
	JRST	TYPTST			;NO
	MOVEI	CHR,12
	PUSHJ	P,PUTCHO
	JRST	TYPTST

;IF I TYPE A ↑C IN TALK RING, THEN
;ASSUME NEXT←ME←PREV
;SET NEXT←PREV
;IF NEXT=PREV, CLEAR ITS TLKRNG BIT
;SET ME←ME
;CLEAR TLKRNG BIT IN LINTAB(ME)

NOTALK:	MOVEI	HPOS,0(LINE)		;ME
	TLNE	LINE,CTYLIN		;CTY?
	JRST	NOTLKB			;YES, CLEAR EVERYONE IN THIS RING
	LDB	CHR,PTALK		;NEXT
NOTAL1:	LDB	UUO,PTALK
	CAMN	UUO,HPOS		;ME←?
	JRST	NOTAL2			;YES. LINE=PREV
	MOVE	LINE,UUO		;NO. FIND PREV
	JRST	NOTAL1

NOTAL2:	DPB	CHR,PTALK		;MAKE NEXT←PREV
	CAIE	CHR,(HPOS)		;NO ↑←N BREAKING SOLITAIRE TALK
	CAIE	CHR,(LINE)		;RING NOW EMPTY?
	JRST	NOTAL3			;NO
NOTLKA:	MOVSI	CHR,TLKRNG		;YES. CLR HIS BIT
	ANDCAM	CHR,LINTAB(LINE)
	MOVE	DDB,TTYTAB(LINE)	;AND TELL HIM ABOUT IT BY GOLLY!!!
	PUSH	P,HPOS
FOR X ε {↑←N}	{
	MOVEI	CHR,"X"
	PUSHJ	P,PUTCHO
}					;USING ANSI STANDARD TEXT 87
	MOVE	IOS,DEVIOS(DDB)
	PUSHJ	P,TYPTST
	POP	P,HPOS
	MOVE	DDB,TTYTAB(HPOS)	;RESTORE DDB
	MOVE	LINE,UUO
	CAIE	LINE,(HPOS)		;IN WHICH CASE IT HAS NEXT IN RING
	JRST	NOTLKC			;WHICH MAY BE ME ANYWAY
NOTAL3:	MOVSI	CHR,TLKRNG
	MOVE	LINE,HPOS		;ME
	DPB	HPOS,PTALK		;ME←ME
	ANDCAM	CHR,LINTAB(LINE)	;CLR MY BIT
	MOVEI	CHR,600			;GET A ↑C AGAIN
	DPB	CHR,TIPUTR(DDB)		;LOOK LIKE 2 OF THEM
	HLL	LINE,LINTAB(LINE)	;GET GOOD BITS!
	TLNN	LINE,DDDLIN!DISLIN!DMDLIN;FOR THESE GUYS, LEAVE IT AS CTRL-META-NULL
	MOVEI	CHR,3			;EVERYBODY ELSE GETS THIS
	JRST	RECINA			;AND PROCESS IT FROM THE TOP

NOTLKB:	LDB	LINE,PTALK		;CTY: GET NEXT GUY
	CAIN	LINE,(HPOS)		;IF ONLY ME,
	JRST	NOTAL3			;  JUST CLEAR ME QUIETLY
NOTLKC:	LDB	UUO,PTALK		;SAVE HIS NEXT
	DPB	LINE,PTALK		;CLEAR HIM OUT
	JRST	NOTLKA			;AND TELL HIM

IFN FTTKBG,<
DOTALX:	PUSHACS				;BH 3/15/74 BUG TRAP TO END OF PAGE
	PUSH	P,TAC			;OFFENDING TALKEE
	PUSH	P,DDB			;TALKER'S TTYTAB
	ANDI	LINE,177		;TALKER'S NUMBER
	PUSH	P,LINE
	PUSHJ	P,DISMES
	ASCIZ /INCOMPLETE LOOP AT DOTALK!!
TALKER=/
	POP	P,TAC
	PUSHJ	P,DISOCT
	PUSHJ	P,DISMES
	ASCIZ /  DDB=/
	POP	P,TAC
	PUSHJ	P,DISOCT
	PUSHJ	P,DISMES
	ASCIZ /
TALKING TO /
	MOVE	TAC,(P)
	PUSHJ	P,DISOCT
	POP	P,TAC
	SKIPE	TTYTAB(TAC)
	JRST	DOTLX1
	PUSHJ	P,DISMES
	ASCIZ /  WHO HAS NO DDB/
	JRST	DOTLX2
DOTLX1:	PUSHJ	P,DISMES
	ASCIZ /  WHO IS LINKED TO HIMSELF/
DOTLX2:	PUSHJ	P,DISMES
	ASCIZ /
FIND A WIZARD, OR TYPE POPJ 3,$X
/
	PUSHJ	P,DISFLU
	POPACS
	PUSHJ	P,DDTCAL
	DPB	LINE,PTALK		;NOW FIX IT UP
	JRST	NOTALK			;SMASH DOPEY RING!
>;FTTKBG
>
;XMTINT XMTIN1 DPYSTR DPYDON XMTI1A NODPY2 XMTI1B
;COMMON TRANSMITTER INTERRUPT FOR SCANNER AND CTY(TTY)

;Here when starting up typeout on any kind of tty (from TYPT2 and PTRD1S)
XMTI1B:	TLNE	LINE,DMLIN
	SKIPN	DAT,LETAB(LINE)
	JRST	XMTIN1
	SKIPN	DPHOLD(DAT)		;If on DM and not holding,
	PUSHJ	P,DPYSTR		; then plant clock request for DPYTYP
	JRST	XMTIN1

↑XMTINT:
	HLL	LINE,LINTAB(LINE)	; GET LINE CHAR.
	SKIPN	DDB,TTYTAB(LINE)	;GET DDB ADDRESS
	POPJ	P,			;IF NONE, X BEING TYPED
	MOVE	IOS,DEVIOS(DDB)		;GET IO STATUS
XMTIN1:	MOVEI	CHR,0			;CTL-B HOLDING ON PTY NEEDS THIS
	LDB	DAT,PDVTIM		;RESET HUNG COUNT
	DPB	DAT,PDVCNT
	MOVEI	DAT,TTOBUF(DDB)		;GET PTR. FOR OUTPUT BUFFER.
	TLNE	LINE,DISLIN!DDDLIN
	JRST	DPYSTR			;IF A DISPLAY, GO TO OUR OWN STARTUP ROUTINE
IFN FTDM <
	TLNE	LINE,DMDLIN
	JRST	DMXMT			;TRANSMITTER ROUTINE FOR DATAMEDIAS
NODPY2:					;DMXMT returns here if tty has no dpy hdr
>;FTDM
	OFFSCN				;TURN OFF SCANNER CHANNEL
XMTI1A:	MOVE	TAC,TAKR(DAT)		;IS OUTPUT BUFFER EMPTY?
	CAME	TAC,PUTR(DAT)		;(I.E., HAS TAKR CAUGHT UP WITH PUTR?)
	JRST	XMTIN2			;NO, TYPING STILL IN PROGRESS
	TRNE	IOS,MERTP1		;MONITOR ERROR MESSAGE?
	CAIE	DAT,TTOBUF(DDB)		;OUTPUT BUFFER?
	JRST	XMTIN4			;NO, MUST REALLY BE DONE
	MOVEI	DAT,TTIBUF(DDB)		;YES, NOW EMPTY OUT TTI BUFFER
	JRST	XMTI1A

;;INITIATE TYPEOUT ON A DISPLAY CONSOLE.  Requires line number in RH of LINE.
DPYSTR:	MOVSI	DAT,DPYTYP		;MAKE INTO CLOCK REQUEST ON DPYTYP (DPYSER)
	JRST	DPYTLN			;AND ENTER IN DPY CLOCK QUEUE.

;HERE FROM DPYTLX WITH SCANNER OFF
↑DPYDON:MOVE	IOS,DEVIOS(DSER)	;HERE FROM DPYTYP (IN DPYSER) WHEN OUTPUT BUFFER EMPTY.
	HRRZ	DDB,DSER		; DPYSER SAVES DDB ADDRESS IN DSER
	PUSHJ	P,STLNAC		;SET UP AC LINE.
	TRNE	IOS,MERTP1		;ERROR MESSAGE TYPEOUT ?
	CAIE	DSER,-TTOBUF(DAT)	;YES. MUST WE STILL TYPE OUT THE INPUT BUFFER ?
	JRST	XMTIN4			; NO, GO FINISH UP
	PUSHJ	P,DPYERT		;YES. GO TYPE REST OF ERROR MESSAGE FROM INPUT BUFFER.
	ONSCN				;TURN SCANNER CHANNEL BACK ON
	POPJ	P,
;XMTIN4 XMTIN2 LINDON TTYPE XMTIN5 XMTIN6
;HERE WHEN OUTPUT BUFFER(S) EMPTIED.

;Here from CLRBFO UUO and PTYREL
XMTIN5:	OFFSCN				;TURN OFF SCANNER CHANNEL
	MOVEI	IOS,MERTPO!MERTP1
	JRST	XMTIN6			;Don't turn off TOIP

XMTIN4:	MOVE	IOS,[XWD TOIP,MERTPO!MERTP1]
	TLNE	LINE,DMDLIN
	TLZ	IOS,TOIP		;DM isn't done until queues are empty.
XMTIN6:	ANDCAB	IOS,DEVIOS(DDB)
	PUSHJ	P,PAUCHK		;CHECK PAUSEB and CLEAR CHR
	ONSCN				;TURN ON SCANNER CHANNEL
	TLNE	IOS,TOIP		;Type out finished?
	JRST	LINDON			;No, must be DM
	LDB	HPOS,PJOBN		;JOB NUMBER DDB IS ATTACHED TO
	TLNN	IOS,IO
	JRST	LINDON
	MOVSI	IOS,IO
	ANDCAB	IOS,DEVIOS(DDB)
	TLNN	LINE,TLKRNG		;KEEP DDB IF TALKING
	JUMPE	HPOS,TTYKIL		;ELSE KILL IF NO JOB
	JRST	LINDON			;KEEP IT

XMTIN2:	ONSCN				;TURN ON SCANNER CHANNEL
	TLNE	IOS,TTYHLD		;IF HOLDING OUTPUT, RETURN.
	POPJ	P,
	PUSHJ	P,GETCHO		;NO, GET NEXT CHAR. IN BUFFER
	JUMPE	CHR,XMTIN1		;IGNORE NULLS
	JUMPL	IOS,TTYPE		;KEEP TYPING IF INPUT I/O WAIT
	TRNN	IOS,IOACT		;ARE WE IN I/O WAIT?
	JRST	TTYPE			;NOT IN IO WAIT

PRINTX HERE'S A PLACE TO OPTIMIZE TYPEOUT FOR HIGH SPEED LINES
;FOR HIGH SPEED LINES THE PARAMETER (NOW TTOCHR/2) BELOW SHOULD BE MADE SMALLER
;TO WAKE THE JOB EARLIER (SINCE THE BUFFER EMPTIES SOONER)
	LDB	HPOS,PFITCH		;YES, CHECK TO FIT INTO TTO BUFFER 
	CAIL	HPOS,TTOCHR/2		;
	MOVEI	HPOS,TTOCHR/2		;CLIP PFITCH TO HALF A BUFFER FULL
	CAML	HPOS,FCTR(DAT)		;IS THERE ROOM ENOUGH TO ADD SOME MORE?
	JRST	TTYPE			;NO, KEEP TYPING
LINDON:	TLNE	IOS,IOW			;IN IO WAIT?
	TLNE	IOS,TTYIOW		;YES, TTY INPUT WAIT?
	JRST	TTYPE			;NO, GO TYPE CHAR.
	PUSH	P,LINE			;SAVE LINE
	PUSHJ	P,SETIOD		;YES, SET IO DONE (OUT OF WSYNC)
	POP	P,LINE			;RESTORE LINE
	MOVE	IOS,[IOW,,IOACT]	;INDICATE NO IO ACTIVE OR WAIT
	ANDCAB	IOS,DEVIOS(DDB)

TTYPE:	TLNN	LINE,PTYLIN		;DON'T TYPE IF THIS IS A PSEUDO-TTY.
	JUMPN	CHR,TYPL		;IS TYPING STILL TO BE IN PROGRESS?
	POPJ	P,			;NO.
;TYPL PAUCHK SCNTYP TYPDM PAUCH2 PAUCH3

;ROUTINE TO TYPE CHAR - SCANNER LEVEL OR UUO LEVEL
;CALL	MOVE	LINE,<LINE NUMBER>
;	MOVE	CHR,<CHARACTER>
;	PUSHJ	P,TYP

↑TYPL:	TLNE	LINE,DISLIN!DDDLIN!DMDLIN
	POPJ	P,			;DON'T DO THIS ON DPYS (MAINLY TYPX)
↑TYPDM:	MOVE	TAC,CHR			;GENERATE EVEN PARITY BIT (MODEL 37)
	IMULI	TAC,200401		;SEE PDP-10 SYSTEM REFERENCE MANUAL.
	AND	TAC,[ 11111111]		;FORM 8 COPIES OF ORIGINAL BITS
	IMUL	TAC,[ 11111111]		;ADD 8 BITS TOGETHER
	TLNE	TAC,10			;TEST PARITY OF SUM
	TRO	CHR,200			;PARITY IS ODD,  MAKE IT EVEN
	TLNN	LINE,CTYLIN		;CONSOLE TTY?
	JRST	SCNTYP			;NO. TYPE CHAR VIA 630-SCANNER
	DPB	CHR,PLASTC

IFE PRCONF,<	DATAO	CTY,CHR		;KA10 TYPEOUT
		POPJ	P,		>;IFE PRCONF

IFG PRCONF,<	MOVE	TAC,CHR		;KL10 TYPEOUT
		JRST	DTETYP		>;IFG PRCONF

SCNTYP:	OFFSCN				;TURN OFF SCANNER CHANNEL
	CONO	DCSB,(LINE)		;(MUSTN'T INTERRUPT BETWEEN CONO - DATAO)
	DATAO	DCSA,CHR
	ONSCN				;TURN ON SCANNER CHANNEL
	SKIPE	DDB
	DPB	CHR,PLASTC		;SAVE CHAR FOR FULL DUPLEX
	POPJ	P,

;HERE WHEN OUTPUT BUFFER IS EMPTY. TURN PAUSEB TO COMBIT. CONO PI,SCNON. CLEAR CHR.
PAUCHK:	MOVSI	CHR,PAUSEB
	TDNN	CHR,TTYTAB(LINE)	;COMMAND WAITING FOR OUTPUT BUFFER TO EMPTY?
	JRST	PAUCH3			;NO
	ANDCAM	CHR,TTYTAB(LINE)	;OFF WITH THE BAD BIT (PAUSEB)
	MOVSI	CHR,COMBIT		;ON WITH THE GOOD BIT (COMBIT)
	OFFSCN				;TURN OFF SCANNER CHANNEL
	SKIPGE	TTYTAB(LINE)		;SKIP UNLESS COMBIT ALREADY SET
	JRST	PAUCH2
	IORM	CHR,TTYTAB(LINE)	;SET IT NOW
	AOS	COMCNT			;COUNT A COMMAND
PAUCH2:	ONSCN				;TURN ON SCANNER CHANNEL
PAUCH3:	SETZ	CHR,
	POPJ	P,
;PTYGET PTOCK PTICHK PTYCLR POPJJ

PTYGET: SKIPE	TTYLOK			;CREATE A PTY.   NOT UNDER TTYLOK
	POPJ	P,
	MOVSI	LINE,-PTYNUM		;HOW MANY ARE AVAIABLE?
	MOVSI	TAC,PTYLIN
	TDNE	TAC,LINTAB+PTYL0(LINE)
	AOBJN	LINE,.-1
	JUMPG	LINE,CPOPJ
	ADDI	LINE,PTYL0
	PUSHJ	P,DDBSRC		;GET A DDB
	POPJ	P,			;NONE AVAILABLE
	HRLI	LINE,PTYLIN!PTYUSE!XON!FCS	;DON'T INVENT LF'S (XON).
					;ALSO FULL CHARACTER SET MODE
	MOVEM	LINE,LINTAB(LINE)
	MOVEM	J,PTYJOB-PTYL0(LINE)	;RECORD WHICH JOB OWNS THIS PTY.
	XCTR	XW,[MOVEM LINE,(UUO)]	;RETURN PTY LINE NUMBER TO USER
	JRST	CPOPJ1			;GIVE SKIP RETURN

;COME HERE WHEN A PTY OUTPUTS ANYTHING, TO WAKE UP JOBS WAITING FOR IT.
PTOCK:  MOVE	AC1,TOTAKR(DDB)
	CAME	AC1,TOPUTR(DDB)		;IS THERE ANYTHING IN PTY'S OUTPUT BUF?
	TLNN	LINE,PTYUSE		;IS PTY STILL IN USE ?
	JRST	SETBF3			;NO. FLUSH THE OUTPUT BUFFER.
	SKIPLE	TAC,PTYPTR(DDB)		;IS SOMEONE WAITING FOR OUR OUTPUT ?
	JRST	PTCHK2
	PUSH	P,J
	MOVE	J,PTYJOB-PTYL0(LINE)
	MOVSI	AC1,INTPTO		;GIVE PTY OUTPUT INTERRUPT
	TDNE	AC1,JBTIEN(J)
	PUSHJ	P,TTINT
POPJJ:	POP	P,J
	POPJ	P,

PTICHK:	SKIPL	TAC,PTYPTR(DDB)
	POPJ	P,
PTCHK2:	SETZM	PTYPTR(DDB)
	EXCH	TAC,DDB
	PUSHJ	P,SETIOD
	MOVSI	AC1,IOW+TTYIOW
	ANDCAM	AC1,DEVIOS(DDB)
	EXCH	TAC,DDB
	PUSHJ	P,STLNAC
	LDB	J,PJOBN			;CLOBBERED BY STTIOD.  UUOCON MAY CARE
	POPJ	P,

↑PTYCLR:HRRE	LINE,JBTLIN(J)
	JUMPL	LINE,PTYCL2
	MOVSI	TAC,SPCBRK!XON
	HLL	LINE,LINTAB(LINE)	;GET LINE BITS BACK
	TLNE	LINE,PTYLIN		;IS THIS A PTY?
	TLZ	TAC,XON			;YES, GIVE HIM BACK HIS LFS
	ANDCAM	TAC,LINTAB(LINE)
	ANDCAM	TAC,JBTLIN(J)
	PUSHJ	P,TTYSRC		;FIND HIS TTY DDB
	MOVSI	TAC,STDTBL		;AND SET HIS BREAK TABLE TO STANDARD.
	HRRI	TAC,ACTBTS(DDB)
	BLT	TAC,ACTMOD(DDB)
	MOVEI	TAC,NOECHO!NOECHB
	ANDCAM	TAC,DEVIOS(DDB)		;TURN ECHOING BACK ON!
PTYCL2:	MOVEI	LINE,PTYL0		;PREPARE TO SEARCH ALL PTY'S.
PTYCL1:	CAIL	LINE,PTYL0+PTYNUM	;DONE?
	POPJ	P,
	PUSH	P,LINE
	PUSH	P,J
	PUSHJ	P,PTYRL2		;YES. RELEASE IT FOR HIM.
	POP	P,J
	POP	P,LINE
	AOJA	LINE,PTYCL1
;PTYUUO, LINMAP, PTOCNT, PTIFRE

↑PTYUUO:JUMPE	UCHN,PTYGET
	XCTR	XR,[HRRZ TAC,(UUO)]
	TRZE	TAC,400000		;USE THIS TO MAP REAL LINES
	JRST	LINMAP
	CAIG	TAC,TTPLEN
	CAILE	UCHN,PTYXNO
	JRST	UUOERR
	JUMPN	TAC,PTYUU3
	HRRE	TAC,JBTLIN(J)		;IF HE ASKS FOR LINE 0,
	JUMPL	TAC,CPOPJ		;NOT IF DETACHED.
	JRST	PTYUU2			;GIVE HIM HIS OWN TTY.

PTYUU3:	CAIL	TAC,PTYL0		;IS IT A PTY ?
	CAME	J,PTYJOB-PTYL0(TAC)	;YES. DOES HE OWN IT ?
	CAIN	UCHN,PTRLCD		;NO. AN ERROR UNLESS HE'S RELEASING IT.
PTYUU2:	SKIPA	LINE,LINTAB(TAC)
	JRST	UUOERR			;THE LINE YOU REQUESTED ISN'T YOURS
	HRRI	LINE,(TAC)
	ADDI	UUO,1
	HRLI	UUO,(<POINT 36,0,35>)	;MAKE FULL-WORD BYTE PTR. IN UUO.
	SKIPE	DDB,TTYTAB(LINE)	;GET LOC. OF HIS DDB.
	JRST	PTYUU4
	PUSHJ	P,DDBSRC		;NO DDB, SO GET HIM ONE.
	JRST	UUOERR			;NONE AVAILABLE.
PTYUU4:	SKIPG	PTYDIS(UCHN)		;LEGAL FOR TTY'S?
	TLNE	LINE,PTYLIN		;NO.  IS THIS A PTY?
	JRST	@PTYDIS(UCHN)
	JRST	UUOERR			;PTY UUO THAT'S NOT LEGAL ON A TTY

LINMAP:	CAILE	TAC,TTPLEN
	JRST	UUOERR
	MOVE	AC1,JBTPRV(J)
	TLNE	AC1,MESPRV
	JRST	PTYUU2			;ALL OK NOW
	SKIPN	DDB,TTYTAB(TAC)
	JRST	UUOERR
	LDB	AC1,PJOBN
	CAMN	AC1,J
	JRST	PTYUU2
	JRST	UUOERR

DEFINE UUOS{FOR X IN(PTYGET,<PTYREL,PTRLCD←←.-PTYDIS>,PTIFRE,<PTOCNT>
,<PTRD1S,400000>,<PTRD1W,400000>,PTWR1S,<PTWR1W>
,<PTRDS,400000>,PTWRS7,PTWRS9,<PTGETL,,GETLN1>
,<PTSETL,,SETLIN>,<PTLOAD,,PTLLED>,PTJOBX,PTL7W9)}

PSHSYS
LOSYS

UUOMAC PTYDIS,PTYUUO
PTYXNO←←UUOCNT-1

POPSYS

PTOCNT:	MOVN	CHR,TOFCTR(DDB)		;-(AMOUNT OF ROOM LEFT IN BUFFER)
	ADDI	CHR,TTOCHR		;+(TOTAL NUMBER OF CHARS BUFFER WILL HOLD)
	JUMPN	CHR,PTSTOR		;=(NUMBER OF CHARS IN OUTPUT BUFFER)
	PUSHJ	P,PAUCHK		;CHECK PAUSEB AND LEAVE CHR ZERO
PTSTOR:	XCTR	XW,[MOVMM CHR,(UUO)]
	POPJ	P,

PTIFRE:	MOVE	CHR,TIFCTR(DDB)		;AMOUNT OF ROOM LEFT IN INPUT BUFFER
	SOJA	CHR,PTSTOR		;COUNT CAN ONLY GO TO 1 NOT 0.
;PTYREL, PTRD1S, PTRD1W, PTWAIT

PTYREL:	TLNE	LINE,PTYLIN		;RELEASE THE PTY, IF IT REALLY IS ONE.
PTYRL2:	CAME	J,PTYJOB-PTYL0(LINE)	;DOES THIS JOB OWN THIS PTY?
	POPJ	P,
	SKIPN	DDB,TTYTAB(LINE)	;THIS IS NEEDED IF WE CAME FROM PTYCLR.
	JRST	LINCLR			;CLEAR LINE BITS AND RETURN.
	PUSHJ	P,XMTIN5		;FINISH OUTPUT.
	PUSHJ	P,TSETBF		;CLEAR BOTH ITS BUFFERS.
	SETZM	PTYJOB-PTYL0(LINE)	;CLEAR OWNERSHIP FLAG.
	MOVSI	TAC,PTYUSE		;MARK PTY AS NO LONGER USED, SO DDB WILL
	ANDCAM	TAC,LINTAB(LINE)	;  BE KILLED BY TTYKIL.
	LDB	J,PJOBN			;GET JOB ON THIS PTY
	JUMPE	J,.+2			;IF ANY
	PUSHJ	P,INTKILL		;NOW KEEP HIM FROM FUTZING AROUND
	MOVE	UUO,[BYTE(7)3,3,"K",12,0]
	XCTR	XW,[MOVEM UUO,JOBTM1]	;PUT IT IN USER CORE.
	MOVE	UUO,[POINT 7,JOBTM1]	;THIS WILL BE RELOCATED.
	PUSHJ	P,PTWR2			;SEND JOB ↑C ↑C K<LF>.
	POPJ	P,

PTRD1S:	MOVE	IOS,DEVIOS(DDB)		;GET STATUS WORD.
	PUSHJ	P,XMTI1B
	XCTR	XDB,[DPB CHR,UUO]	;GIVE CHARACTER TO USER
	JUMPE	CHR,CPOPJ
	JRST	CPOPJ1

PTRD1W:	PUSHJ	P,PTRD1S
	SKIPA	UCHN,DDB
	POPJ	P,
	PUSHJ	P,TTYGET
	HRRZM	DDB,PTYPTR(UCHN)
	MOVSI	IOS,IOW!TTYIOW!DDTM
	TLNE	LINE,PTYWAK		;DO WE WANT TO HEAR TTY INPUT ?
	IORM	IOS,DEVIOS(DDB)
	PUSHJ	P,PTWAIT
	SETZM	PTYPTR(DDB)
	PUSHJ	P,PTRD1S
	POPJ	P,
	POPJ	P,

PTWAIT:	MOVEI	TAC,IOWQ
	MOVNM	TAC,JOBQUE(J)
	MOVE	DDB,UCHN		;RECOVER DDB FOR PTY.
	PUSHJ	P,STLNAC		;RESTORE LINE (CLOBBERED BY TTYGET).
	JRST	WSCHED
;PTWR1S, PTLL3, PTWR1W, PTRDS, PTWRS7, PTWRS9

PTWR1S:	MOVEI	CHR,1
	CAML	CHR,TIFCTR(DDB)		;IS THERE ROOM (>1 NOT 0).
	POPJ	P,
	AOS	(P)			;THERE'S ROOM FOR THIS CHR., SKIP RETURN
	XCTR	XLB,[LDB CHR,UUO]
	LDB	UCHN,[POINT 2,CHR,28]
PTLL3:	LDB	DSER,[POINT 7,CHR,35]	;SIMULATE KBDINT--PTY COULD BE A DPY
	CAIL	DSER,"A"
	CAILE	DSER,"Z"
	JRST	.+2
	TRO	DSER,40
	MOVEI	AC2,
	PUSHJ	P,STLNAC		;IN CASE KBDED IS AROUND CLOBBERING THINGS.
	MOVE	TAC,LINTAB(LINE)	;SET UP ESCAPE BITS
	DPB	LINE,[PUNITS⊗6,,TAC]	;BUT NULLIFY MAPPING
	OFFSCN				;TURN OFF SCANNER CHANNEL
	PUSHJ	P,PTYREC		;PRETEND CHR. HAS JUST BEEN TYPED IN.
	JRST	SCNONJ			;TURN ON SCANNER AND POPJ.

PTWR1W:	TLNE	LINE,IMLIN		;IMLAC FORWARD-SPACE KLUDGE
	JRST	IMWR1W
IMWR10:	PUSHJ	P,PTWR1S		;WRITE A CHAR.
	SKIPA	UCHN,DDB		;DIDN'T GO. LET'S WAIT A WHILE.
	POPJ	P,			;ALL DONE.
	PUSHJ	P,TTYGET
	HRROM	DDB,PTYPTR(UCHN)
	PUSHJ	P,PTWAIT
	JRST	PTWR1W

IMWR1W:	XCTR	XLB,[LDB CHR,UUO]	;IMLAC...
	CAIN	CHR,211			;<CONTROL>TAB?
	JRST	IMWR11
	CAIE	CHR,240			;<CONTROL>SPACE?
	JRST	IMWR10			;NEITHER.  BACK TO OLD CODE.
	SKIPA	CHR,[ASCID/ε↓/]		;CTL-SPACE.  COMMAND TO MOVE FORWARD 1.
IMWR11:	MOVE	CHR,[ASCID/ε}/]		;CTL-TAB.  MOVE FORWARD A BUNCH.
	PUSHJ	P,TTYFNU
	JRST	FIVOUT			;SEND THE COMMAND.

;PTRDS, PTWRS7, PTWRS9 CHANGED 3-30-71 TO USE LH (ADR+1) AS BYTE
;POINTER SPEC IF NON-ZERO ------ DCS

PTRDS:	XCTR	XR,[MOVE UUO,(UUO)]	;GET ADDRESS OF BUFFER IN LOSER CORE.
	TLZN	UUO,7777		;CLEAR SIZE FIELD, CHECK FOR BP THERE
	HRLI	UUO,440700		;NONE, GIVE 7-BIT PTR TO FIRST CHAR
	TLO	UUO,700			;ASSURE CORRECT SIZE FIELD, AT LEAST
	IBP	UUO			;STUPID SAIL!
PTRDSA:	PUSHJ	P,PTRD1W		;WAIT FOR AT LEAST ONE CHAR. TO APPEAR.
PTRDS2:	IBP	UUO
	PUSHJ	P,PTRD1S		;GET ANY FURTHER CHARS.
	POPJ	P,			;NO MORE.
	JRST	PTRDS2			;MAYBE MORE.

PTWRS7:	TLCA	UUO,444300		;MAKE 7-BIT PTR. ...
PTWRS9:	TLC	UUO,445500		;MAKE 9-BIT PTR.
	HLR	CHR,UUO			;SAVE BP SPEC FOR FIRST CHAR
	XCTR	XR,[MOVE UUO,(UUO)]	;GET ADDRESS OF BUFFER IN USER CORE.
	TLZN	UUO,7777		;CLEAR SIZE AND INDEX, CHECK
	HRL	UUO,CHR			;ZERO, PROVIDE CORRECT PTR
	DPB	CHR,[POINT 12,UUO,17]	;ASSURE CORRECT SIZE FIELD
PTWR2:	XCTR	XLB,[ILDB CHR,UUO]
	JUMPE	CHR,STLNAC		;DONE IF NULL
	PUSHJ	P,PTWR1W		;GIVE NEXT CHAR. TO PTY.
	JRST	PTWR2			;LOOP UNTIL WE SEE A NULL.
;PTJOBX

PTJOBX:	LDB	TAC,PJOBN		;GET JOB WHICH IS ON THIS PTY
	XCTR	XR,[MOVE TAC1,(UUO)]	;GET COMMAND
	TLNN	TAC1,770000		;IS IT SIXBIT OR DIRECT INDEX?
	JRST	PTJDIR			;DIRECT
	MOVEI	AC1,PTJLEN		;LENGTH OF TABLE
	CAME	TAC1,PTJTAB-1(AC1)	;MATCH?
	SOJG	AC1,.-1
	MOVE	TAC1,AC1
PTJDIR:	JUMPLE	TAC1,UUOERR
	CAILE	TAC1,PTJLEN		;IS IT IN TABLE?
	JRST	UUOERR			;NO
	HRRZ	TAC1,PTJDIS-1(TAC1)	;GET DISPATCH
	JRST	(TAC1)			;AND DISPATCH

DEFINE NAMES
<	C	HALT,PTJHLT,0
	C	CONT,PTJCON,0
	C	DOFF,PTDOFF,0
	C	DON,PTDON,0
	C	LOGIN,PTLOGN,0
	C	IWAITS,PTIWTS,0
	C	CLRBFI,PTCLRB,0
>
DEFINE C(A,B,BITS)
<	XWD BITS,B
>
PTJDIS:	
XLIST
	NAMES
LIST
PTJLEN←←.-PTJDIS
DEFINE C(A,B,BITS)
<	SIXBIT/A/
>
PTJTAB:	
XLIST
NAMES
LIST
;PTJHLT, PTJCON, PTIWTS, PTCLRB

;HALT JOB RUNNING ON THIS PTY.  ENTER AT PTJHLT
NOTOK:	POP	P,J
	PUSHJ	P,WSCHED	;WAIT A WHILE
PTJHLT:	JUMPE	TAC,CPOPJ	;HALT JOB RUNNING ON THIS PTY
	PUSH	P,J		;SAVE OURSELVES FIRST.
	MOVE	J,TAC		;NOW DO IT TO HIM
	CAMN	J,STUSER	;SYSTEM TAPE USER?
	JRST	HLTOK0
	PUSHJ	P,STOPCK	;NO, OK TO STOP?
	JRST	NOTOK
HLTOK:	PUSHJ	P,STOP1
	POP	P,J
	JRST	CPOPJ1		;SUCCESS RETURN

HLTOK0:	PUSHJ	P,ANYACT	;IS IO ACTIVE? (SKIPS IF JOB ISN'T INCORE)
	JRST	NOTOK		;YES.  WE NEED TO WAIT AWHILE
	PUSHJ	P,ESTOP
	POP	P,J
	JRST	CPOPJ1		;SUCCESS RETURN

PTJCON:	JUMPE	TAC,CPOPJ	;CONTINUE THE JOB RUNNING ON THIS PTY
	PUSH	P,J
	MOVE	J,TAC
	MOVM	TAC,JOBQUE(J)
	CAIE	TAC,STOPQ	;THIS IS ONLY PLACE YOU CAN CONTINUE FROM
	JRST	NOCONT		;CAN'T CONTINUE
	MOVE	TAC,JBTSTS(J)
	TLNE	TAC,JERR
	JRST	NOCONT		;CAN'T CONTINUE FROM ERROR
	MOVNI	TAC,RUNQ
	MOVEM	TAC,JOBQUE(J)
	PUSHJ	P,SETRUN
	AOS	-1(P)		;SUCCESS RETURN (2 SKIPS)
NOCONT:	POP	P,J
	JRST	CPOPJ1		;SUCCESS RETURN

;SKIP IF PTY IS WAITING FOR INPUT

PTIWTS:	MOVE	IOS,DEVIOS(DDB)
	TLNE	IOS,TPMON	;MONMODE OR USRMODE?
	JRST	PTIWT1
	JUMPL	IOS,CPOPJ1	;USER MODE, CHECK TTYIOW BIT
	POPJ	P,		;IT WAS OFF

PTIWT1:	LDB	LINE,PUNIT		;(PTJOBX MUNGS "TAC1")
	MOVE	TAC,TTYTAB(LINE)	;MONITOR MODE, GOBBLE TTYTAB
	TLNN	TAC,COMBIT!DLYBIT!PAUSEB ;ANY COMMANDS STILL TO BE PROCESSED?
	AOS	(P)			;NO
	POPJ	P,

;PTJOBX [N ↔ SIXBIT /CLRBFI/] -- DO CLRBFI FOR TTYN
PTCLRB:	JRST	SETBFI		;YES, I KNOW THIS WASTES A CELL AND A CYCLE
;PTDON, PTDOFF,PTLOGN,IMLOAD
; ROUTINES TO SET DUPLEXING OF PTY

PTDON:	MOVEI	IOS,NOECHO
	ANDCAB	IOS,DEVIOS(DDB)
	POPJ	P,

PTDOFF:	MOVEI	IOS,NOECHO
	ORB	IOS,DEVIOS(DDB)
	POPJ	P,

;START A NEW JOB ON A PTY.  USES FORK CODE.

PTLOGN:	JUMPN	TAC,PTLGN1	;LOSE IF THERE'S A JOB ALREADY
	HRLM	J,(P)		;SAVE OUR JOBNUM
	PUSHJ	P,INIJOB	;GOBBLE A NEW JOB
	JRST	PTLGN0		;SORRY, NO JOBS
	JRST	PTLGN0		;THIS CAN'T HAPPEN (IT SAYS HERE)
	PUSHJ	P,FORKC		;THIS COPIES THE OLD JOB'S STUFF
	MOVEI	TAC,(J)		;TO RETURN IT TO LOSER
	AOSA	(P)
PTLGN0:	MOVEI	TAC,0
PTLGN1:	XCTR	XW,[MOVEM TAC,(UUO)]
	POPJ	P,

;DO A PTLOAD TO AN IMLAC

IMLOAD:	PUSHJ	P,TTYFNU
	XCTR	XR,[MOVE UUO,(UUO)]	;GET GUY'S PTR.
	TLNN	UUO,-1			;IS IT ALREADY (PRESUMABLY) A BYTE PTR. ?
	HRLI	UUO,440700		;NO. MAKE IT ONE.
IMLOD0:	MOVE	CHR,[ASCID/0/]		;Load command is "0"+no. of chars.
	MOVE	TAC,[POINT 7,CHR,6]
IMLOD1:	XCTR	XLB,[ILDB AC3,UUO]	;Get a char,
	JUMPE	AC3,IMLOD2		;end on a null.
	ADD	CHR,[BYTE (7)1]		;Count the chars.
	IDPB	AC3,TAC			;Stuff char into the command.
	TLNE	TAC,760000			;Full word (4 chars)?
	JRST	IMLOD1			;No.  Do it again.
	PUSHJ	P,FIVOUT		;Send those 4 to the IMLAC
	JRST	IMLOD0			;and keep going.

IMLOD2:	CAME	CHR,[ASCID/0/]		;Done.  Put out the last few chars.
	PUSHJ	P,FIVOUT
	MOVE	CHR,[ASCID/¬/]		;Command to move to beginning of
	JRST	FIVOUT			;line and return to normal.
;PHONE DIALER LIVES HERE
IFE DILNUM,<DIAL:JRST UUOERR>;IF NO DIALER, UUOERR
IFN DILNUM,<
;DIALER BITS AND DEFINITIONS
DIL0TT←←11		;TTY11 IS DIALER 0

;CONI BITS
DILDS1←←4000		;DATASET ANSWERED OR DIALED END OF NUMBER CODE
DILDS0←←2000		;DATASET HUNG-UP
DILBSY←←1000		;DIALER BUSY
DILOK←←400		;DIALER OK (NOT TIMED OUT)
DILDSS←←200		;CONNECTED
DILVMD←←100		;IN VOICE MODE
DILPWR←←40		;POWER FAIL
;       20		;DIALER IS INTERRUPTING

;CONO BITS
DILCLR←←40		;CLEAR INTERRUPT CONDITION
DILHUP←←20		;HANG UP
DILENB←←10		;ENABLE INTERRUPT

;DATAO BITS (LEFT HALF)
DAREA←←4000		;DIAL AREA CODE
DVOICE←←2000		;GO TO VOICE MODE ON DSS←1

;DIALER INITIALIZE ROUTINE
DILINI:	CONO	DIL,DILCLR!DILHUP!DILENB!DILCHN	;INIT HARDWARE
	SETZM	DILZBG				;BEGIN ZERO OF DIALER DATA
	MOVE	TAC,[DILZBG,,DILZBG+1]
	BLT	TAC,DILZND			;AND ZERO TO END
	POPJ	P,

DILTRL:	MOVSI	AC1,-DILNUM
DILTR1:	HRRZ	TAC,DILTTY(AC1)
	CAIE	TAC,(LINE)
	AOBJN	AC1,DILTR1
	JUMPGE	AC1,CPOPJ
	PUSH	P,LINE
	HRRZ	LINE,AC1
	SKIPE	DILJOB(LINE)
	PUSHJ	P,RELDIL			;RELEASE DIALER
	POP	P,LINE
	POPJ	P,
;DIAL UUO
;CALL
;	MOVEI AC,ADDR
;	DIAL AC,
;	<ERROR RETURN, AC CONTAINS STATUS BITS>
;	<SUCCESS, AC CONTAINS ANY DATA RETURNED>
;
;ADDR:	DIALER #,,FUNCTION CODE
;	SEE INDIVIDUAL CALL FOR REST OF DATA

DILER0:	JSP TAC,DILERR
DILER1:	JSP TAC,DILERR
DILER2:	JSP TAC,DILERR
DILER3:	JSP TAC,DILERR
DILER4:	JSP TAC,DILERR

DILERR:	SUBI TAC,DILER0+1
	HRRZ TAC,TAC
DILSTT:	XCTR XW,[MOVEM TAC,(UCHN)]	;STORE ERROR CODE BACK IN AC
	POPJ P,

;ERROR CODES FOR ALL DIAL UUO'S
;ERROR 0 -- ILLEGAL DIALER #
;ERROR 1 -- DON'T OWN DIALER
;ERROR 2 -- DON'T MEET DILOWN CONDITIONS
;ERROR 3 -- DIALER BUSY
;ERROR 4 -- DIALING FAILURE

↑DIAL:	XCTR XR,[HRRZ UUO,(UCHN)]	;FETCH POINTER TO ARG BLOCK
	XCTR XR,[HLRZ LINE,(UUO)]	;GET DIALER NUMBER
	CAIL LINE,DILNUM		;LEGAL?
	JRST DILER0			;NO, ERROR 0
	XCTR XR,[HRRZ DSER,(UUO)]	;GET FUNCTION CODE
	CAIL DSER,MXDLCD		;LEGAL FUNCTION CODE?
	JRST UUOERR			;NO
	CAME J,DILJOB(LINE)		;HIS?
	JUMPN DSER,DILER1		;NO, ERROR 1 (UNLESS DILGET)
	JRST @DILDIS(DSER)		;YES, CALL ROUTINE

DILDIS:	DILGET				;0 GET DIALER
	DILSTA				;1 GET DIALER STATUS
	DILDIL				;2 DIAL A NUMBER
	DILHNG				;3 HANG UP
	DILREL				;4 RELEASE
MXDLCD←←.-DILDIS

;CODE 0	GET DIALER
DILGET:	CAMN J,DILJOB(LINE)		;DOES HE OWN IT?
	JRST CPOPJ1			;ALREADY HAS IT, SUCCESS
	SKIPE DILJOB(LINE)		;DOES ANYONE OWN IT?
	JRST DILER1			;YES, DON'T OWN ERROR
	XCT DILOWN(LINE)		;CHECK OTHER CONDITIONS
	JRST DILER2			;LOSE
	MOVEM J,DILJOB(LINE)		;CLAIM IT
	JRST CPOPJ1

DILTTY:	400000,,DIL0TT			;TTY NUMBER FOR THIS DIALER
					; (SIGN BIT MEANS CONNECTED TO AD/DA)

DILOWN:	PUSHJ P,DIL0CK			;CHECK ROUTINE FOR DIALER 0

DIL0CK:	MOVE DDB,DILTTY(LINE)
	SKIPN DDB,TTYTAB(DDB)		;CHECK TTY FOR DIALER
	POPJ P,				;NO TTY THERE AT ALL
	LDB TAC,PJOBN
	CAME TAC,J			;IS IT HIS?
	POPJ P,				;NO
	MOVE TAC,DEVMOD(DDB)
	TRNE TAC,ASSPRG			;DOES HE HAVE IT INITED?
	AOS (P)				;YES, SUCCESS
	POPJ P,

;CODE 1 GET STATUS
DILSTA:	CONI DIL,TAC			;GET CURRENT STATUS
	HRL TAC,DILCNI(LINE)		;LAST I-LEVEL CONI IN LEFT HALF
	AOS (P)				;ALWAYS SUCCESSFUL HERE
	JRST DILSTT			;RETURN STATUS BITS IN AC

;CODE 2 DIAL A NUMBER
DILDIL:	CONSZ DIL,DILBSY
	JRST DILER3			;DIALER BUSY
	CONSZ DIL,DILPWR		;IS DIALER POWER OK?
	JRST DILER4			;NO, GIVE HIM AN ERROR RIGHT AWAY
	XCTR XR,[MOVE TAC,2(UUO)]	;PICKUP DATAO WORD

IFN 0,<;ENABLE WHEN AD/DA CONNECTED
	TLNE TAC,DVOICE			;ATTEMPTING VOICE MODE?
	SKIPL DILTTY(LINE)		;CONNECTED TO AD/DA?
	JRST DILNM1
;CHECK AD/DA OWNERSHIP HERE
DILNM1:
>;IFN 0

	XCTR XR,[MOVE AC1,1(UUO)]	;PICKUP CONO WORD
	ANDI AC1,777700			;JUST AREA CODE
	CAIN AC1,4B21!1B25!5B29		;AREA 415?
	TLZ TAC,DAREA			;YES, DON'T DIAL AREA CODE
	CONO PI,DILOFF			;DISABLE DIALER CHANNEL
	CONO DIL,DILCLR!DILENB!DILCHN(AC1)	;SETUP
	DATAO DIL,TAC			;AND GO
DILWAT:	MOVNI TAC,IOWQ
	MOVEM TAC,JOBQUE(J)
	PUSHJ P,REQUE
	MOVE AC1,[JRST DILING]		;DISPATCH FOR I-LEVEL
	MOVEM AC1,DILIDS(LINE)
	SETZM DILCNI(LINE)		;CLEAR CONI BITS FOR CHECK
	CONO PI,DILON
	PUSHJ P,WSCHED			;WAIT FOR DIALER
	CONO PI,DILOFF			;INTERLOCK
	SKIPN TAC,DILCNI(LINE)		;GET CONI BITS
	JRST DILWAT
	CONO PI,DILON
	TRC TAC,DILDS1!DILOK!DILDSS	;ALL THESE SHOULD BE ON
	TRCN TAC,DILDS1!DILOK!DILDSS
	TRNE TAC,DILDS0!DILPWR		;THESE SHOULD BE OFF
	CAIA
	JRST DILSTAT			;OK, RETURN STATUS
	CONO DIL,DILHUP!DILENB!DILCHN	;HANG IT IN YOUR EAR
	JRST DILER4			;DIALER ERROR

;CODE 3 HANG UP
DILHNG:	CONO DIL,DILHUP!DILENB!DILCHN	;HANG IT IN YOUR EAR
	JRST DILSTAT			;RETURN STATUS

;CODE 4 RELEASE DIALER
DILREL:	PUSHJ P,RELDIL
	JRST DILSTAT			;RETURN STATUS

RELDIL:	SETZM DILIDS(LINE)		;CLEAR I-LEVEL DISPATCH
	CONO DIL,DILHUP!DILENB!DILCHN	;HANG IT IN YOUR EAR
	SETZM DILJOB(LINE)
	POPJ P,
;DIALER INTERRUPTS COME HERE
↑DILINT:MOVEM LINE,DILLIN
	MOVEI LINE,0			;ONLY ONE LINE FOR NOW
	MOVEM TAC,DILTAC
	CONI DIL,TAC			;GET STATUS BITS
	MOVEM TAC,DILCNI(LINE)		;LATEST CONI BITS
	SKIPE DILIDS(LINE)		;THIS DIALER ACTIVE?
	XCT DILIDS(LINE)		;DISPATCH TO DIALER ROUTINE OR EXIT
DILXIT:	CONSO DIL,DILBSY		;DIALER BUSY?
	JRST DILXT1			;NO, DON'T CHECK FOR HANGUP
	CONSO DIL,DILOK			;IF NOT OK
	CONO DIL,DILHUP			;HANG UP
DILXT1:	CONO DIL,DILCLR!DILENB!DILCHN	;CLEAR INTERRUPT, ENABLE, SET CHANNEL
	MOVE TAC,DILTAC
	MOVE LINE,DILLIN
	JEN @DILCHL

DILING:	TRNE TAC,DILDS1			;SHOULD HAVE JUST CONNECTED
	TRNN TAC,DILDSS			;AND STILL BE CONNECTED
	TDZA TAC,TAC			;NOT CONNECTED, IDLE STATE
	MOVE TAC,[JRST DILACT]		;CONNECTED, SET TO ACTIVE STATE
	MOVEM TAC,DILIDS(LINE)		;SET DISPATCH
	MOVEM J,DILJ
	MOVE J,DILJOB(LINE)
	MOVM TAC,JOBQUE(J)
	CAIE TAC,IOWQ			;STILL WAITING FOR US?
	JRST DILIN1
	MOVNI TAC,RUNQ
	MOVEM TAC,JOBQUE(J)
	MOVEI TAC,QJOB(J)
	CONO PI,PIOFF
	SKIPE (TAC)
	JRST DILIN0
	EXCH TAC,QJOB
	HRROM TAC,@QJOB
DILIN0:	CONO PI,PION
DILIN1:	MOVE J,DILJ
	JRST DILXIT

DILACT:	TRNE TAC,DILOK			;IF NOT OK,
	TRNE TAC,DILDS0!DILPWR		;OR ANY ERRORS
	XCT DILERP(LINE)		;THEN REPORT ERROR
	JRST DILXIT			;I WONDER WHAT WAS WRONG?

DILERP:	JRST DILERT			;REPORT TO TTY

DILERT:	MOVE TAC,DILTTY(LINE)
	SKIPN TAC,TTYTAB(TAC)		;JUST IN CASE
	JRST DILXIT			;FOO
	MOVEM J,DILJ
	MOVSI J,IODERR
	IORM J,DEVIOS(TAC)		;FLAG ERROR TO TTY
	MOVE J,DILJ
	JRST DILXIT
>;IFN DILNUM
;TTYDDL (TTYSET) TTESC TTWID LINCLE LINSET NOCCR TTYSTO GETHP GETWID STIOS CLIOS GTIOS

;TTYSET UUO EXECUTE COMMANDS FROM A TABLE
;CALL BY
;	MOVE AC,[-LEN,,TABLE]
;	TTYSET AC,
;
;TABLE:	BLOCK LEN
;
;HIGH ORDER 9 BITS OF EACH WORD IN TABLE SPECIFY OPERATION TO BE CARRIED OUT.
;REMAINDER OF WORD IS ARGUMENT.  NOT ALL OF REMAINDER IS ALWAYS USED.

↑TTYDDL:
	JUMPGE	TAC,CPOPJ
TTYDD0:	XCTR	XR,[MOVE UUO,(TAC)]	;GET NEXT COMMAND
	LDB	AC1,[POINT 9,UUO,8]	;PICK UP OP CODE
	CAIL	AC1,LTTYOP
	JRST	UUOERR
	HRRE	LINE,JBTLIN(J)		;GET LINE NUMBER (ROUTINE MAY CLOBBER LINE)
	JUMPL	LINE,CPOPJ		;NO-OP IF DETACHED
	SKIPN	DDB,TTYTAB(LINE)	;GOTTA HAVE A DDB (ROUTINE MAY CLOBBER DDB)
	POPJ	P,			;HOW CAN THIS HAPPEN IF TTY IS ATTACHED?
	HLL	LINE,LINTAB(LINE)	;GET LINE CHARACTERISTICS
	PUSH	P,TAC			;PRESERVE IMPORTANT ACS
	PUSH	P,J
	PUSHJ	P,@TTYOP(AC1)		;EXECUTE COMMAND
	POP	P,J
	POP	P,TAC
	AOBJN	TAC,TTYDD0		;ANY MORE COMMANDS?
	POPJ	P,			;NO

;NOTE THAT TTYSET UUO IS ALWAYS A NO-OP WHEN GIVEN BY A DETACHED JOB
TTYOP:	CPOPJ		;0		;NO-OP
	LINSET		;1		;TURN ON GIVEN LINE CHARACTERISTICS BITS
	LINCLE		;2		;TURN OFF GIVEN LINE CHARACTERISTICS BITS
	GETLN2		;3		;GET LINE CHARACTERISTICS
	TTESC		;4		;DO ESC COMMAND
	TTWID		;5		;SET TTY WIDTH FIELD
	GETWID		;6		;GET TTY WIDTH OR DPY WIDTH
	GETHP		;7		;GET TTY HORIZONTAL POSITION
	NOCCR		;10		;PREVENT USER FROM DOING CONTROL-CR NOW ONLY
	STIOS		;11		;TURN ON GIVEN IOS BITS
	CLIOS		;12		;TURN OFF GIVEN IOS BITS
	GTIOS		;13		;GET TTY'S IOS BITS
;	PTYOWN				;GET PTY'S OWNER JOB
;	STSPCL				;SET SPECIAL BITS IN 4TH WORD OF ACT TABLE
;	GTSPCL				;GET SPECIAL BITS IN 4TH WORD OF ACT TABLE
;	STACT				;SET ACTIVATION TABLE LESS SPECIAL BITS
;	GTACT				;GET ACTIVATION TABLE INCLUDING SPECIAL BITS
LTTYOP←←.-TTYOP

TTWID:	MOVEI	TAC1,(UUO)		;GET ARG
	JUMPE	TAC1,TTWID0		;IF NO ARG, USE OLD DEFAULT
	JRST	TTWID1

;NOTE THAT THIS CLOBBERS J BECAUSE LINED USES J FOR DPY HEADER ADDRESS.
;ANY TTY CAN TRY TO SEND ESCAPES, BUT CERTAIN ONES ARE NO-OPS IF TTY ISN'T A DISPLAY
TTESC:	MOVE	J,LETAB(LINE)		;GET DPY HEADER IF ANY
	MOVE	DAT,LINE		;LINED WANTS LINE BITS IN DAT
	LDB	AC1,[POINT 9,UUO,26]	;GET NUMERICAL ESCAPE ARGUMENT
	CAILE	AC1,ESCMAX
	MOVEI	AC1,ESCMAX		;MAX ALLOWABLE ARG
	TRNE	UUO,400			;DOES HE WANT BREAK INSTEAD OF ESCAPE?
	HRLI	AC1,400000		;YES, ARG IS IN SIGN-MAGNITUDE FORM
	LDB	DSER,[POINT 7,UUO,35]	;GET ESCAPE LETTER
	TRZ	DSER,40			;MAKE SURE IT'S UPPER CASE
	JRST	TTYESC			;GO OFF TO LINED

NOCCR:	OFFSCN				;TURN OFF SCANNER CHANNEL
	SKIPG	J,LETAB(LINE)		;ONLY DO IT IF HAVE HDR & LINE EDITOR EMPTY
	JRST	SCNONJ			;CONO PI,SCNON AND POPJ
	TLNN	J,WTFLAG		;IS LINE BEING TRANSFERRED TO TTY INPUT BUF?
	SETZM	LEPNT1(J)		;NO, SEND INIT2 (LINED) TO INITIT ON CTRL-CR
	ONSCN				;TURN ON SCANNER CHANNEL
	POPJ	P,

GETHP:	SKIPN	LETAB(LINE)		;GET DPY HEADER, IF ANY
	JRST	GETHP2			;NO, GIVE HIM TTY HPOS
	PUSHJ	P,PPWAIT		;WAIT FOR TYPEOUT TO FINISH ON DPY
	LDB	LINE,PUNIT		;PPWAIT MAY CLOBBER ALL KINDS OF ACS
	SKIPN	J,LETAB(LINE)		;(IT BETTER NOT CLOBBER UUO OR DDB)
	JRST	GETHP2			;WHERE'D HIS DPY HEADER GO?
	MOVE	DAT,CURPP(J)		;GET POINTER TO CURRENT PP
	MOVE	TAC,DPHPOS(DAT)		;GET NEGATIVE OF AMT OF ROOM LEFT ON LINE
	ADD	TAC,LNLNGT(DAT)		;ADD LENGTH OF LINE
TTYSTO:	MOVEI	UUO,(UUO)		;JUST LEAVE ADDRESS IN UUO
	CAIL	UUO,20			;IS ADDRESS LEGAL? (IS IT AN AC?)
	CAILE	UUO,JOBPFI		;NOT AN AC. IS IT IN PROTECTED PART?
	JRST	.+2			;NO, LEGAL ADDRESS
	JRST	UADERR			;USER WOULD NEVER HAVE SEEN RESULT--ERROR
	XCTR	XW,[MOVEM TAC,(UUO)]	;STORE RESULT IN USER'S CORE
	POPJ	P,

GETHP2:	LDB	TAC,PHPOS		;GET CURRENT HORIZONTAL POSITION
	JRST	TTYSTO

GETWI2:	LDB	TAC,PTTYWD		;GET TTY WIDTH
	JRST	TTYSTO

GETWID:	SKIPN	J,LETAB(LINE)		;GET DPY HEADER IF ANY
	JRST	GETWI2			;NONE, GIVE HIM TTY WIDTH
	MOVE	DAT,CURPP(J)
	MOVE	TAC,LNLNGT(DAT)		;GET DISPLAY'S LINE LENGTH
	JRST	TTYSTO

LINSET:	TLOA	LINE,(UUO)		;TURN ON BITS REQUESTED
LINCLE:	TLZ	LINE,(UUO)		;TURN OFF BITS REQUESTED
	XCTR	XW,[MOVEM LINE,JOBTM1]	;STORE IN USER CORE FOR SETLIN
	MOVEI	UUO,JOBTM1		;TELL SETLIN WHERE TO FIND CHARACTERISTICS
	JRST	SETLIN

STIOS:	TDOA	UUO,DEVIOS(DDB)		;TURN ON SPECIFIED IOS BITS
CLIOS:	ANDCA	UUO,DEVIOS(DDB)		;TURN OFF SPECIFIED IOS BITS
	JRST	SETIOS

GTIOS:	MOVE	TAC,DEVIOS(DDB)		;GIVE USER HIS IOS SETTINGS
	JRST	TTYSTO
;DATAMEDIA INTERRUPT LEVEL (CH5) CODE: COMMENTS AND DEFS

IFN FTDM,<

;FIGURES OUT WHAT TEXT TO SEND OUT TO THE DM NEXT.
;UNQUOTED TTY CONTROL CHARS (BELOW 40) ARE SENT AS BLINKING LETTERS,
;ALTHOUGH THE HARDWARE MAY BE MODIFIED TO DISPLAY "BLINKING" CHARS AS BOLD
;AND VICE VERSA.  "BLINKING" HERE MEANS WHAT DATAMEDIA CORP. THINKS CAUSES BLINKING.

;   FLAGS in DAT:

;DM STATE FLAGS
;(RH of DAT, RH of DMFLAG(J))

↑STUCK←←100000	;A protected field exists on the screen
↑TBSSET←←40000	;Tabs have been set
↑RAPPED←←20000	;Temporary flag indicating we just passed col 80, or need to skip LF
;;modes←←17	;See 4 mode flags below.

;QUEUE ENTRY FLAGS
;(LH of DAT and RH of QFLAGS(TAC); LH of DMLEFL(J) for line editor xfers.)

↑DMXUSR←←200000	;Call routine in LH of QFREE(TAC) when xfer done
↑DMQUOT←←100000	;Don't interpret any text		
↑TRUNCA←←40000	;Ignore text byond col 80
↑NOEEOL←←20000	;Suppress erasing each old line before output on it
↑NOEEOB←←10000	;Suppress erasing of lines on which nothing is output but CRLF
↑BETWEE←←4000	;Ignore spaces between tabs and ending tab
↑USERGO←←2000	;Don't interrupt user program in progress
↑CHASTE←←1000	;No output (nor EEOL) done yet on current line
↑QUO177←←400	;Don't interpret 177's as quoting anything, just send them
↑DMATXY←←200	;Get and store X-Y position @QXYLOC
↑DMXLE←←100	;Line editor xfer--store final XY position at DMLEXY(J)
;;modes←←17	;See 4 mode flags below.
;;Note that the CHASTE bit on in a user program header block flag word means
;; that any previously queued and unfinished user program should be flushed
;; immediately.  This flushes only those entries in the user program queue that
;; have a QXYLOC word equal to <job number>,,0 in addition to having the DMXUSR
;; bit on.  Thus a job can flush any of the programs which that particular
;; job queued.

;The next four flags are used in both halves of DAT
;In LH, a one means Queue entry has set corresponding mode.
;In RH, a one means the DM is actually in the corresponding mode.
↑BLNKON←←10	;Blink mode
↑PROTON←←4	;Protected field mode
↑IDON←←2	;Insert/Delete mode
↑ROLLON←←1	;Roll mode

;This is the mask of user-settable flags
↑DMUMSK←←DMQUOT!TRUNCA!NOEEOL!NOEEOB!BETWEE!USERGO

;Special flag in RH of CHR indicating character is an arrow char (control char).
CTRLCH←←400000	;Output this character as blinking

;Normally, an EEOL is output before the first character on a line, but this
;is inhibited if either DMQUOT or NOEEOL is on, or if NOEEOB is on and nothing
;printable (what's that mean, you ask?) has been output (CHASTE is on).
;DMTABL dispatch table for quoted DM control characters

;Dispatch table for quoted control characters.  routines keep track of X-Y and flags
;These routines keep track of the X-Y position and the mode flags,
;and many of these routines do nothing but diddle these things without doing output.
;Therefore, it is necessary that any way out of this code save the DAT flags in
;QFLAGS(TAC) and DMFLAG(J).

;400000		;Means character need not be quoted on output to get special effect
IDSPCL←←200000	;Special output char in I/D mode--doesn't change cursor position
XYSPCL←←100000	;Special output char when seen just after FF (as X or Y position)
INQUOT←←40000	;This character can be quoted on input by NULL or "add META".
DMCONV←←20000	;This character normally gets converted to something else on input.
;;convertedchr←←777	;Bits in LH used to hold character we convert to on input.

;MASTER is the CLEAR character which clears the line editor.
;HOLDER is the HOLD character that holds PP output.
;These two chars' entries must be unique in the table below.

DEFINE C(X) <↑X←←.-DMTABL>

DMTABL:		DMNOOP			;000 NL	;↑@	;null--if it prints, put DMXMT5 here
		DMNOOP			;001 ↓	;↑A	;no-op
C(HOME)	  XYSPCL,,DMHOME		;002 α	;↑B	;home
	  DMCONV!INQUOT!600,,DMNOOP	;003 β	;↑C	;no-op
C(LEMOVE)	DMLEMV			;004 ∧	;↑D	;no-op except for LE
C(LEDELE)	DMLEDE			;005 ¬	;↑E	;no-op except for LE
		DMNOOP			;006 ε	;↑F	;no-op
		DMNOOP			;007 π	;↑G	;bell
C(IDDELC) IDSPCL,,DMBACK		;010 λ	;↑H	;back cursor (I/D: delete char)
	  400000,,DMTAB			;011 TB	;↑I	;tab
C(IDADDR) 400000!IDSPCL,,DMLF		;012 LF	;↑J	;lf (I/D: add row)
		DMTABC			;013 VT	;↑K	;tab clear
	  XYSPCL,,XYGET			;014 FF	;↑L	;set X-Y position
	  400000,,DMCR			;015 CR	;↑M	;cr
C(BLINK)	DMBLNK			;016 ∞	;↑N	;blink on
C(PROTEC)	DMPROT			;017 ∂	;↑O	;protected field on
C(ID)		DMID			;020 ⊂	;↑P	;I/D on
	  XYSPCL,,DMXMT6		;021 ⊃	;↑Q	;transmit page, currently flushed
	  XYSPCL,,DMXMT6		;022 ∩	;↑R	;transmit page to printer, currently flushed
		DMXMT6			;023 ∪	;↑S	;transmit line, currently flushed
		DMNOOP			;024 ∀	;↑T	;no-op
		DMNOOP			;025 ∃	;↑U	;no-op
		DMNOOP			;026 ⊗	;↑V	;no-op
C(EEOL)		DMNOOP			;027 ↔	;↑W	;erase to end of line
C(CANCEL) XYSPCL,,DMCANC		;030 _	;↑X	;cancel (unlock)
		DMTABC			;031 →	;↑Y	;set tab
C(IDDELR) DMCONV!IDSPCL!33,,DMUP	;032 ~	;↑Z	;up cursor (I/D: delete row)
	  DMCONV!175,,DMNOOP		;033 ≠	;↑[	;no-op
C(IDADDC) IDSPCL,,DMXMT5		;034 ≤	;↑\	;forward cursor (I/D: add char)
C(ROLL)		DMROLL			;035 ≥	;↑]	;roll on
C(MASTER) DMCONV!INQUOT!XYSPCL,,DMMAST	;036 ≡	;↑↑	;master clear--like home+erase+clears tabs
C(HOLDER) DMCONV!INQUOT!XYSPCL,,DMHOME	;037 ∨	;↑←	;erase screen
	  400000,,DMSPAC		;040 SP		;space
;DMXMT DMXDEQ DMXDUN DMXMG2 DMXMGO DMXMT1 DMXMT2 DMXMT8 DMNOXY NODPYH

;DPY HEADER CELLS FOR "QUICK" OUTPUT:
;DMQKCT	count of bytes waiting for output
;DMQKPT byte pointer to waiting quick bytes
;DMQKBF buffer for quick output bytes, probably four words long
;	(must be able to hold: FF,X,Y,CANCEL,PROTECT,BLINK,ID,ROLL,EEOL,8 SPACES)

;OTHER DPY HEADER CELLS
;UCOUNT
; <job>,,<address of user run flag to SOS (or SETZM?) when user dpy program is done>
;	(used by clock level routine which actually SOSes the cell)
;	(UCOUNT cell must be cleared by RESET; perhaps RESET should actually flush
;	  DM user dpy program and SOS the user cell before clearing UCOUNT.)
;DMLEPT	;Header of queue of Line Editor incremental xfers
;DMPPPT	;Header of queue of Page Printer xfers
;DMUSER	;Header of queue of User display program xfers
;DMWHO	;Header of queue of Wholine xfers
;DMFLAG ;Flag word indicating current actual status of DM terminal
;DMXY	;Actual X-Y position of DM cursor
;DPYHGT	;Number of lines on display's screen (should be valid for any type of dpy)
;(The above are all included now in dpy header.)

↑DMXMT:	PUSH P,J			;Preserve J throughout DMXMT
	SKIPN J,LETAB(LINE)
	JRST NODPYH			;Can't get here without a dpy header
	PUSH P,[POPJJ]			;Restore J when POPJing
DMXMG2:	SOSGE DMQKCT(J)			;Any quick (uninterruptible) chars ready?
	JRST DMXMT1			;No
DMXMGO:	ILDB CHR,DMQKPT(J)
	JRST TYPDM			;Yes, output one

;Any routine to be called when xfer is done (LH QFREE) better
; preserve J,TAC,TAC1,DDB.
DMXDEQ:	TLNE DAT,DMXLE
	MOVEM DAT,DMLEFL(J)		;Line editor xfer--store flags in dpy hdr
	HLRZ AC1,QFREE(TAC)		;Get address of routine to run now
	TLNE DAT,DMXUSR			;Does this queue entry have routine to call?
	PUSHJ P,(AC1)			;Yes
	PUSHJ P,DEQ			;Use DD routine to unqueue request finished
	HRRZS DMFLAG(J)			;No old output going
DMXMT1:	MOVE DAT,DMFLAG(J)		;Get flags
	TLNE DAT,USERGO			;Uninterruptible user program in progress?
	JRST DMXMT2			;Yes
	HRRZ TAC,DMLEPT(J)		;Pointer to first LE incremental queue block
	CAIE TAC,DMLEPT-QLINK(J)	;Header point to itself?
	JRST DMXMTL			;No, output LE stuff
	HRRZ TAC,DMSPPT(J)		;Pointer to first special queue block
	CAIE TAC,DMSPPT-QLINK(J)	;Header point to itself?
	JRST DMXMTO			;No
	SKIPE DPHOLD(J)			;Are we holding
	JRST DMXMT2			;Yes, don't do any PP output
	HRRZ TAC,DMPPPT(J)		;Pointer to first PP queue block
	CAIE TAC,DMPPPT-QLINK(J)	;Header point to itself?
	JRST DMXMTO			;No
DMXMT2:	HRRZ TAC,DMUSER(J)		;Pointer to first user program queue block
	CAIE TAC,DMUSER-QLINK(J)	;Header point to itself?
	JRST DMXMTO			;No
	HRRZ TAC,DMWHO(J)		;Pointer to wholine queue block
	CAIE TAC,DMWHO-QLINK(J)		;Header point to itself?
	JRST DMXMTO
;No more queued requests. 
;We may need to plant a clock request for DPYTYP now because someone may be waiting,
;but then again maybe anyone waiting has taken care of himself (or herself).
;Now we will leave the cursor wherever the line editor wants it.
	MOVE AC3,CVP(J)		;Vertical position of LE cursor
	SOJL AC3,DMNOXY		;LE counts lines from 1 but DM counts from 0
	CAML AC3,DPYHGT(J)	;Is the vertical position on the screen?
	JRST DMNOXY		;No, flush cursor
	HRL AC3,CHP(J)		;Horizontal position of LE cursor
	CAMN AC3,DMXY(J)	;Is cursor already there?
	JRST DMXMT8		;Finally all done
	MOVEM AC3,DMXY(J)	;Remember where we are putting cursor
	PUSHJ P,DMSETQ		;Initialize quicky byte pointer and count
	PUSHJ P,DMCURS		;Calculate FF,X,Y string to position cursor
	MOVEM DAT,DMFLAG(J)	;Might have had to turn of ID mode (and others)
	JRST DMXMG2		;Now output a char

DMNOXY:	MOVSI AC3,707070	;Funny code to mark cursor gone (used here only)
	CAMN AC3,DMXY(J)	;Cursor already gone?
	JRST DMXMT8		;Yes, and we are too now
	MOVEM AC3,DMXY(J)	;No, but it will be in a moment
	MOVEI CHR,14		;FF will erase cursor
	JRST TYPDM		;Put out one last char

DMXMT8:	OFFSCN
	MOVSI IOS,TOIP		;Typeout has ended
	ANDCAB IOS,DEVIOS(DDB)
	JRST SCNONJ

IFN FTDM,<
NODPYH:	POP	P,J
	PUSHACS
	PUSHJ	P,DISMES
	ASCIZ	/NO DPY HEADER FOR DATAMEDIA LINE AT DMXMT.
/
	PUSHJ	P,DISFLU
	POPACS
	PUSHJ	P,WDDTCA
	JRST	NODPY2
>;FTDM
;XYGET DMXMTO DMXMT6 DMHOME DMPREP DMSETQ DMCURS IGNORE DMBETW DM175 DMXM5D DMHOME DMTAB DMSPAC DMCURS DMBACK DMXMTL DMLEDE

XYGET:	SOSGE QDMCNT(TAC)
	JRST DMXDEQ		;OOPS, end of entry.
	ILDB CHR,QTAKR(TAC)	;X
	PUSHJ P,XYCHK		;See if legal X char
	CAIL CHR,=80
	TDZA AC1,AC1		;Out of range, use column 0
	MOVEI AC1,(CHR)		;Save X while checking Y
	SOSGE QDMCNT(TAC)
	JRST DMXDEQ		;OOPS, end of entry.
	ILDB CHR,QTAKR(TAC)	;Y
	PUSHJ P,XYCHK		;See if legal Y char
	CAML CHR,DPYHGT(J)
	MOVEI CHR,0		;Out of range, use line 0
	HRL CHR,AC1
	MOVEM CHR,QXY(TAC)
	TLNN DAT,DMXLE
	JRST XYGET2
	MOVEM CHR,DMLEXY(J)	;Make sure line editor knows where we are
	JRST DMXMT6
	
XYGET2:	TLO DAT,CHASTE		;New virgin output line waiting
	JRST DMXMT6		;Get next output char

XYCHK:	CAIL CHR,40
	TRCA CHR,140
	SKIPA AC2,DMTABL(CHR)
	POPJ P,
	AOS (P)			;Control-chars are out of range for both X and Y.
	TLNN AC2,XYSPCL		;Is this a special char in X-Y position setting?
	POPJ P,			;No
	SUB P,[1,,1]		;Don't return to XYGET
	JRST DMXMT4		;Now go process this special char

↑DMSETQ:
	MOVEI DSER,DMQKBF(J)
	HRLI DSER,440700	;Initialize byte pointer for storing quicky output
	MOVEM DSER,DMQKPT(J)	;Set up taker byte pointer, too.
	SETZM DMQKCT(J)		;No quickies yet
	POPJ P,

DMXMTL:	HLL DAT,DMLEFL(J)	;Get line editor flags
	JRST DMXMTM

DMXMTO:	HRL DAT,QFLAGS(TAC)	;Get flags for this transfer
DMXMTM:	PUSHJ P,DMSETQ		;Initialize quicky output byte ptr and byte count
	TLNN DAT,DMATXY		;X-Y position stored in special word?
	JRST DMXMT6
	MOVE AC3,@QXYLOC(TAC)	;Yes, get X-Y position
DMLEM5:	MOVEM AC3,QXY(TAC)	;Put into queue entry for use here
DMXMT6:	SOSGE QDMCNT(TAC)	;Decrement number of characters in the entry
	JRST DMXDEQ		;End of queue entry
DMXMT3:	ILDB CHR,QTAKR(TAC)	;Get next character
	MOVE AC3,QXY(TAC)	;Save X-Y position we are supposed to be at.
	TLNE DAT,DMQUOT		;Quoting everything?
	JRST DMXMT7		;Yes
	CAIL CHR,175
	JRST DM175-175(CHR)	;Special dispatch on 175, 176, 177
	CAIN CHR,32
	TRCA CHR,32≠176		;Map Stanford tilde to ASCII tilde
	CAILE CHR,40		;Control char or space?
	JRST DMXMT5		;No, just update X-Y and send the char
	SKIPGE AC2,DMTABL(CHR)
	JRST DMXMT4		;This character doesn't need to be quoted
	JUMPE CHR,DMXMT6	;Non-quoted nulls are simply discarded
	CAIN CHR,"≠"
	TRCA CHR,"≠"≠32		;Turn not-equals sign into ↑Z, to match input rep.
	CAIG CHR,32
	TROA CHR,140!CTRLCH	;Use lower case for control-letters
	TRO CHR,100!CTRLCH	;Use "upper case" for control-funny-chars
DMXMT5:	HLRZ AC2,AC3		;Get column position
	ADDI AC2,1
	HRLM AC2,QXY(TAC)
	CAIL AC2,=80
DMTAB2:	TRO DAT,RAPPED		;Moved past end of line
DMNOOP:	PUSHJ P,DMPREP		;Make sure cursor is at right place w/right modes
DMNOO2:	TLZE DAT,CHASTE		;Any previous output on this line?
	TLNE DAT,DMQUOT!NOEEOL	;No, suppressing erasures?
	JRST DMXM5B		;Yes to one of these
	MOVEI AC1,EEOL		;Erase to end-of-line char
	IDPB AC1,DSER		;Erase new line
	AOS DMQKCT(J)		;Count a quicky
DMXM5B:	IDPB CHR,DSER		;Put in real character (but don't count it)
	TRZN DAT,RAPPED		;Did we just pass col 80?
	JRST DMXM5D		;No
	AOS DMQKCT(J)		;Count following CR as quicky
	TLNN DAT,TRUNCA		;Want to suppress stuff beyond col 80?
	JRST DMXM5C		;No, but if CRLF follows immediately, gobble it now
	PUSHJ P,IGNORE		;Yes, skip to CR or LF
	JRST DMXM5E
	JRST DMCR2		;Found a CR, look for following LF

DMXM5C:	SOSGE QDMCNT(TAC)	;Look for following CR
	JRST DMXM5E		;Nothing there
	ILDB AC1,QTAKR(TAC)
	CAIE AC1,15
	JRST DMXM5F		;Back up byte pointer and counter
DMCR2:	SOSGE QDMCNT(TAC)	;Look for following LF
	JRST DMXM5E		;Nothing there
	ILDB AC1,QTAKR(TAC)
	CAIE AC1,12
DMXM5F:	PUSHJ P,IGNFF		;Back up byte pointer and counter
DMXM5E:	MOVEI AC1,15		;Clear DM hardware flags by sending actual CRLF now
	IDPB AC1,DSER
	AOS DMQKCT(J)		;Count following LF as quicky
	PUSHJ P,DMCR3		;Adjust X-Y position to beginning of next line
DMLF4:	MOVEI AC1,12
	IDPB AC1,DSER
DMXM5D:	MOVEM DAT,DMFLAG(J)	;Save DM state flags
	HLRM DAT,QFLAGS(TAC)	;Save transfer dependent flags
	MOVE AC1,QXY(TAC)
	MOVEM AC1,DMXY(J)	;Save DM actual position
	TLNE DAT,DMATXY		;Is X-Y position stored somewhere special?
	MOVEM AC1,@QXYLOC(TAC)	;Yes, store X-Y position there
	TLNE DAT,DMXLE
	MOVEM DAT,DMLEFL(J)	;Line editor xfer--store flags in dpy hdr
	SKIPG DMQKCT(J)		;Did we set up any quickies?
	JRST TYPDM		;No, just output one char
	JRST DMXMGO		;Avoid one AOS and immediate SOS--output quickies

;Routine to skip text beyond col 80 until see CR, LF, or FF.  Skips on CR.
IGNORE:	SOSGE QDMCNT(TAC)	;Here to skip text beyond column 80
	POPJ P,			;Nothing to ignore
	ILDB AC1,QTAKR(TAC)
	CAIN AC1,15
	AOSA (P)		;Skip return on CR
	CAIN AC1,12
	POPJ P,			;All done for sure
	TLNE DAT,DMQUOT		;Quoting everything?
	JRST IGNOR2		;Yes
	TLNN DAT,QUO177		;Are 177's themselves quoted?
	CAIE AC1,177		;No, quoting next char?
	JRST IGNORE		;No
	SKIPG QDMCNT(TAC)	;Peek at char after 177 to look for FF
	POPJ P,			;Nothing is being quoted
	MOVE AC2,QTAKR(TAC)
	ILDB AC1,AC2
	CAIE AC1,14
	JRST IGNORE
	JRST IGNFF		;Back up byte pointer and byte count over the 177

;Here if quoting everything
IGNOR2:	CAIE AC1,14
	JRST IGNORE		;Loop back and ignore more
IGNFF:	MOVSI AC1,070000
	ADDM AC1,QTAKR(TAC)	;Back up byte pointer so we'll see same char again
	AOS QDMCNT(TAC)		;Fix up count too
	POPJ P,

;The next three words are JRSTed to for output of chars 175, 176, 177, respectively.
DM175:	MOVEI CHR,45		;175: Output altmode as dollar sign (44, sic)
	SOJA CHR,DMXMT5		;176: Right brace -- becomes ASCII 175
	TLNE DAT,QUO177		;177: Is it quoting next char?
	JRST DMXMT5		;No, it is itself quoted--just send it (assumes 177 prints)
	SOSGE QDMCNT(TAC)	;Here to quote next character
	JRST DMXDEQ		;WHAT! Nothing there to quote!
	ILDB CHR,QTAKR(TAC)
DMXMT7:	CAIL CHR,40		;Control-char?
	JRST DMXMT5		;No, update X-Y position and send char (assumes 177 prints)
	MOVE AC2,DMTABL(CHR)	;Yes, dispatch to special routine
DMXMT4:	TLNE AC2,IDSPCL		;Special char in I/D mode?
	TLNN DAT,IDON		;Yes, are we in I/D mode?
	JRST (AC2)		;No, go to special routine
	JRST DMNOOP		;I/D--just send the char--no cursor change

DMMAST:	TRZ DAT,TBSSET!STUCK	;This will clear all tabs, unfortunately
DMHOME:	MOVE AC2,[1,,1]		;Back to home corner
	MOVEM AC2,QXY(TAC)	;With everything but ROLL mode cleared
	TRNE DAT,STUCK		;Any protected fields?
	TDZ DAT,[ROLLON,,ROLLON!TBSSET]	;Yes, no longer in roll mode and no tabs set
	TDZ DAT,[BLNKON!PROTON!IDON,,BLNKON!PROTON!IDON]
	TLO DAT,CHASTE		;New virgin output line waiting
	JRST DMXM5D

DMBACK:	HLRZ AC2,AC3
	SOJL AC2,DMNOOP		;Can't back up past left margin
	HRLM AC2,QXY(TAC)
	JRST DMNOOP

DMBETW:	SOSGE QDMCNT(TAC)
	JRST DMBET2		;Oops, ran out of text
	ILDB CHR,QTAKR(TAC)	;Get next char
	CAIN CHR,11
	POPJ P,			;Found ending tab
	CAIN CHR,40
	JRST DMBETW		;Ignore this space
;	CAIE CHR,15	;Not needed for now since MAKECR doesn't actually put
;	CAIN CHR,12	; CRLFs in LE buffer for DMs.
;	JRST DMBETW		;Ignore CRLF for line editor (and anyone else)
	JUMPE CHR,DMBETW	;Ignore nulls too
	PUSHJ P,IGNFF		;Strange char, put it back
DMBET2:	MOVEI CHR,11		;Set up actual tab again
	POPJ P,

DMTAB:	TLNE DAT,BETWEE		;Want to skip spaces between tabs?
	PUSHJ P,DMBETW		;Yes
DMSPA9:	HLRZ AC1,AC3		;Get column position
	CAIL AC1,=72
	JRST DMTAB2		;Wrapping around, omit tab and put out CRLF
	MOVEI AC2,10(AC1)
	ANDI AC2,-10		;Make it multiple of 8
	HRLM AC2,QXY(TAC)	;Store new column position
;Note--If this tab is quoted, we will very probably screw up X-Y position--tough!
	TRNE DAT,TBSSET!DMQUOT	;Can we output actual tab?
	JRST DMNOOP		;Yes
	MOVEI CHR,40		;No, use spaces
	SUBI AC2,1(AC1)		;AC2 is number of spaces - 1
DMSPA8:	JUMPE AC2,DMNOOP	;If just one space, pretend normal space
	ADDM AC2,DMQKCT(J)	;Count all spaces but 1 as quickies
	PUSH P,AC2		;Save our count
	PUSHJ P,DMPREP		;Make sure cursor and modes are setup
	POP P,AC2
	IDPB CHR,DSER
	SOJG AC2,.-1		;Put out 0 to 7 spaces (save one for later)
	JRST DMNOO2

DMTABC:	TRZ DAT,TBSSET		;Someone is diddling our tabs--remember that
	JRST DMNOOP		;But it doesn't move the cursor

;We don't get here with quoted spaces.
DMSPAC:	TLNE DAT,NOEEOL		;Can we erase line and convert spaces to tabs?
	JRST DMXMT5		;Nope
	TLC AC3,7
	TLCE AC3,7		;Only one space to next tab stop?
	TRNN DAT,TBSSET		;Or tabs not set?
	JRST DMXMT5		;Yes to one of these
	HLRZ AC2,AC3		;Get previous X position
	ADDI AC2,1		;Update X position for first space
DMSPA4:	SOSGE QDMCNT(TAC)
	JRST DMSPA2		;Nothing left in queue entry--go put out spaces
	ILDB CHR,QTAKR(TAC)
	CAIN CHR,11		;If its a tab, just ignore preceding spaces
	JRST DMTAB
	CAIN CHR,40
	JRST DMSPA3		;Collect spaces until hit a tab stop
	PUSHJ P,IGNFF		;Back up byte pointer and count over this last char
	MOVEI CHR,40		;Now go put out number of spaces we have accumulated
DMSPA2:	HRLM AC2,QXY(TAC)	;Store new X position
	HLRZ AC2,AC2		;Number of "extra" spaces
	JRST DMSPA8		;Put out extras

DMSPA3:	AOBJN AC2,.+1
	TRNE AC2,7		;Have we reached a tab stop?
	JRST DMSPA4		;No
	MOVEI CHR,11		;Yes, simulate these spaces with a tab
	JRST DMSPA9

DMLEMV:	TLNN DAT,DMXLE		;Only valid for line editor xfer
	JRST DMNOOP		;No-op otherwise
	SOSGE QDMCNT(TAC)
    JRST 4,DMXDEQ		;Oops, this ain't supposed to happen
	ILDB AC1,QTAKR(TAC)	;Get low-order bits of X adjustment
	SOSGE QDMCNT(TAC)
    JRST 4,DMXDEQ
	ILDB AC2,QTAKR(TAC)	;Get high-order bits of X adjustment
	DPB AC2,[POINT 7,AC1,28];Combine bytes in AC1
	TRNE AC1,1B22		;Negative number?
	IOR AC1,[-1B22]		;Yes, extend sign bit
	HLRZ AC2,AC3		;Get starting X position
	ADD AC1,AC2		;Adjust it
DMLEM2:	JUMPGE AC1,DMLEM3	;Jump unless moved past left margin
	ADDI AC1,=80
	SOJA AC3,DMLEM2		;Back up a line

DMLEM3:	CAIGE AC1,=80		;Pass right margin?
	JRST DMLEM4		;No
	SUBI AC1,=80
	AOJA AC3,DMLEM3		;Move down a line

DMLEM4:	HRL AC3,AC1		;Combine new X and Y positions
	MOVEM AC3,DMLEXY(J)	;Store new X-Y position in dpy hdr
	JRST DMLEM5		;Now store X-Y in queue entry and get another char

DMLEDE:	TLNN DAT,DMXLE		;Only valid for line editor xfer
	JRST DMNOOP		;No-op otherwise
	TLO DAT,IDON		;This operation needs insert delete mode
	PUSHJ P,DMPREP		;Make sure X-Y position and flags set up
	SOSL DMQKCT(J)		;Did DMPREP have to put out anything?
	JRST DMLED2		;Yes, must come back later
	TLZ DAT,IDON		;Now flush ID mode
	SOSGE QDMCNT(TAC)
    JRST 4,DMXDEQ		;Oops, this ain't supposed to happen
	ILDB AC1,QTAKR(TAC)	;Get count of chars to delete
	SUBI AC1,1		;Count one char in CHR
	MOVEM AC1,DMQKCT(J)	;Set up output count
	MOVE AC1,[POINT 7,DELCS]
	MOVEM AC1,DMQKPT(J)	;Set up output byte pointer
	MOVEI CHR,IDDELC
	JRST DMXM5D

DMLED2:	MOVEI AC2,2
	ADDM AC2,QDMCNT(TAC)	;Back up over 177 and LEDELE char
	MOVSI AC2,160000
	ADDB AC2,QTAKR(TAC)	;Back up byte pointer two chars
	JUMPG AC2,DMLED3
	MOVN AC2,[430000,,1]	;Back into previous word
	ADDM AC2,QTAKR(TAC)
DMLED3:	LDB CHR,DSER		;Get back last character of quickies
	JRST DMXM5D		;Now put out some quickies

DMPROT:	TLNN DAT,USERGO		;"Protected field on" legal only from
	JRST DMXMT6		;  uninterruptible user program.  Flush otherwise.
	TLOA DAT,PROTON
DMBLNK:	TLO DAT,BLNKON
	JRST DMXMT6

DMROLL:	TRNN DAT,STUCK		;Any protected fields?
	TLO DAT,ROLLON		;No, then we can go into roll mode
	JRST DMXMT6

DMCANC:	TRNE DAT,STUCK		;Any protected fields?
	TRZ DAT,TBSSET		;Yes, no longer have tabs set
	TLZA DAT,PROTON!BLNKON!IDON!ROLLON	;Clear all kinds of modes
DMID:	TLO DAT,IDON
	JRST DMXMT6

DMUP:	HRRZ AC1,AC3
	SOJL AC1,DMNOOP		;Can't move up from top line
	HRRM AC1,QXY(TAC)
	TLO DAT,CHASTE		;New virgin output line waiting
	JRST DMNOOP

DMCR3:	HRRZS QXY(TAC)		;Back to column 0
DMLF2:	HRRZ AC2,AC3		;Get screen line number
	ADDI AC2,1
	CAMG AC2,DPYHGT(J)	;To bottom of screen?
	JRST DMLF3		;No
	TLNE DAT,ROLLON
	SKIPA AC2,DPYHGT(J)	;Rolling right along we stay on bottom
	MOVEI AC2,1		;Wrap around to top
DMLF3:	HRRM AC2,QXY(TAC)	;Save new line number
	TLO DAT,CHASTE		;Mark new line as untouched
	POPJ P,

DMCR4:	PUSHJ P,DMPREP		;Make sure cursor and modes are correct
	TLNE DAT,CHASTE		;Need to erase this line we are leaving?
	TLNE DAT,DMQUOT!NOEEOL!NOEEOB	;Here with CR ending blank line
	POPJ P,			;No
	MOVEI AC1,EEOL		;Yes, do it
	IDPB AC1,DSER
	AOS DMQKCT(J)		;Count a quicky
	POPJ P,

DMCR:	PUSHJ P,DMCR4		;Erase line we are leaving, if necessary
	JRST DMCR2

DMLF:	PUSHJ P,DMCR4		;Erase line we are leaving, if necessary
	PUSHJ P,DMLF2		;Adjust Y position down a line
	JRST DMLF4

DMCURS:	TRNN DAT,IDON		;Cannot position while in ID mode
	JRST DMCUR2
	TRZ DAT,BLNKON!PROTON!IDON!ROLLON
	MOVEI AC1,CANCEL
	IDPB AC1,DSER		;Turn 'em all off--it's the only way, sigh
	AOS DMQKCT(J)		;Count a quicky
DMCUR2:	JUMPE AC3,DMCUR3	;If positioning to upper left corner, use home char
	XOR AC3,[140,,140]	;No, convert X-Y position to char format
	HLRZ AC2,AC3
	MOVEI AC1,14
	IDPB AC1,DSER		;FF
	IDPB AC2,DSER		;X-Pos
	IDPB AC3,DSER		;Y-Pos
	XOR AC3,[140,,140]	;Restore position word
	MOVEI AC1,3
	ADDM AC1,DMQKCT(J)	;Count three quickies to be output
	POPJ P,

DMCUR3:	MOVEI AC2,HOME
	IDPB AC2,DSER		;Go Home
	AOS DMQKCT(J)		;Count a quicky
	POPJ P,

DMPREP:	CAME AC3,DMXY(J)	;Are we at correct initial cursor position?
	PUSHJ P,DMCURS		;No, position cursor
	HLRZ AC1,DAT		;See if modes are all set correctly
	XORI AC1,(DAT)
	ANDI AC1,BLNKON!PROTON!IDON!ROLLON
	JUMPE AC1,DMPRE6	;Any modes in wrong sense?
	TRNN AC1,(DAT)		;Yes, any on that should be off?
	JRST DMPRE3		;No
	TRZ DAT,BLNKON!PROTON!IDON!ROLLON
	MOVEI AC1,CANCEL
	IDPB AC1,DSER		;Turn 'em all off--it's the only way, sigh
	AOS DMQKCT(J)		;Count a quicky
DMPRE3:	TLNE DAT,PROTON
	TROE DAT,PROTON!STUCK	;PROTECTED FIELD MODE required, is it on?
	JRST DMPRE4
	MOVEI AC1,PROTEC	;No, turn it on
	IDPB AC1,DSER
	AOS DMQKCT(J)		;Count a quicky
DMPRE4:	TLNE DAT,ROLLON
	TROE DAT,ROLLON		;ROLL MODE required, is it on?
	JRST DMPRE5
	MOVEI AC1,ROLL		;No, turn it on
	IDPB AC1,DSER
	AOS DMQKCT(J)		;Count a quicky
DMPRE5:	TLNE DAT,IDON
	TROE DAT,IDON		;I/D MODE required, is it on?
	JRST DMPRE6
	MOVEI AC1,ID		;No, turn it on
	IDPB AC1,DSER
	AOS DMQKCT(J)		;Count a quicky
DMPRE6:	TRZN CHR,CTRLCH		;Is this a blinking control char,
	TLNE DAT,BLNKON		;or is blinking supposedly on for this xfer?
	TROE DAT,BLNKON		;BLINK MODE required, is it on?
	POPJ P,			;All ok
	MOVEI AC1,BLINK		;Get start-blink char
	IDPB AC1,DSER
	AOS DMQKCT(J)		;Count a quicky
 	POPJ P,
>;FTDM